configure.ac 60 KB

12345678910111213141516171819202122232425262728293031323334353637383940414243444546474849505152535455565758596061626364656667686970717273747576777879808182838485868788899091929394959697989910010110210310410510610710810911011111211311411511611711811912012112212312412512612712812913013113213313413513613713813914014114214314414514614714814915015115215315415515615715815916016116216316416516616716816917017117217317417517617717817918018118218318418518618718818919019119219319419519619719819920020120220320420520620720820921021121221321421521621721821922022122222322422522622722822923023123223323423523623723823924024124224324424524624724824925025125225325425525625725825926026126226326426526626726826927027127227327427527627727827928028128228328428528628728828929029129229329429529629729829930030130230330430530630730830931031131231331431531631731831932032132232332432532632732832933033133233333433533633733833934034134234334434534634734834935035135235335435535635735835936036136236336436536636736836937037137237337437537637737837938038138238338438538638738838939039139239339439539639739839940040140240340440540640740840941041141241341441541641741841942042142242342442542642742842943043143243343443543643743843944044144244344444544644744844945045145245345445545645745845946046146246346446546646746846947047147247347447547647747847948048148248348448548648748848949049149249349449549649749849950050150250350450550650750850951051151251351451551651751851952052152252352452552652752852953053153253353453553653753853954054154254354454554654754854955055155255355455555655755855956056156256356456556656756856957057157257357457557657757857958058158258358458558658758858959059159259359459559659759859960060160260360460560660760860961061161261361461561661761861962062162262362462562662762862963063163263363463563663763863964064164264364464564664764864965065165265365465565665765865966066166266366466566666766866967067167267367467567667767867968068168268368468568668768868969069169269369469569669769869970070170270370470570670770870971071171271371471571671771871972072172272372472572672772872973073173273373473573673773873974074174274374474574674774874975075175275375475575675775875976076176276376476576676776876977077177277377477577677777877978078178278378478578678778878979079179279379479579679779879980080180280380480580680780880981081181281381481581681781881982082182282382482582682782882983083183283383483583683783883984084184284384484584684784884985085185285385485585685785885986086186286386486586686786886987087187287387487587687787887988088188288388488588688788888989089189289389489589689789889990090190290390490590690790890991091191291391491591691791891992092192292392492592692792892993093193293393493593693793893994094194294394494594694794894995095195295395495595695795895996096196296396496596696796896997097197297397497597697797897998098198298398498598698798898999099199299399499599699799899910001001100210031004100510061007100810091010101110121013101410151016101710181019102010211022102310241025102610271028102910301031103210331034103510361037103810391040104110421043104410451046104710481049105010511052105310541055105610571058105910601061106210631064106510661067106810691070107110721073107410751076107710781079108010811082108310841085108610871088108910901091109210931094109510961097109810991100110111021103110411051106110711081109111011111112111311141115111611171118111911201121112211231124112511261127112811291130113111321133113411351136113711381139114011411142114311441145114611471148114911501151115211531154115511561157115811591160116111621163116411651166116711681169117011711172117311741175117611771178117911801181118211831184118511861187118811891190119111921193119411951196119711981199120012011202120312041205120612071208120912101211121212131214121512161217121812191220122112221223122412251226122712281229123012311232123312341235123612371238123912401241124212431244124512461247124812491250125112521253125412551256125712581259126012611262126312641265126612671268126912701271127212731274127512761277127812791280128112821283128412851286128712881289129012911292129312941295129612971298129913001301130213031304130513061307130813091310131113121313131413151316131713181319132013211322132313241325132613271328132913301331133213331334133513361337133813391340134113421343134413451346134713481349135013511352135313541355135613571358135913601361136213631364136513661367136813691370137113721373137413751376137713781379138013811382138313841385138613871388138913901391139213931394139513961397139813991400140114021403140414051406140714081409141014111412141314141415141614171418141914201421142214231424142514261427142814291430143114321433143414351436143714381439144014411442144314441445144614471448144914501451145214531454145514561457145814591460146114621463146414651466146714681469147014711472147314741475147614771478147914801481148214831484148514861487148814891490149114921493149414951496149714981499150015011502150315041505150615071508150915101511151215131514151515161517151815191520152115221523152415251526152715281529153015311532153315341535153615371538153915401541154215431544154515461547154815491550155115521553155415551556155715581559156015611562156315641565156615671568156915701571157215731574157515761577157815791580158115821583158415851586158715881589159015911592159315941595159615971598159916001601160216031604160516061607160816091610161116121613161416151616161716181619162016211622162316241625162616271628162916301631163216331634163516361637163816391640164116421643164416451646164716481649165016511652165316541655165616571658165916601661166216631664166516661667166816691670167116721673167416751676167716781679168016811682168316841685168616871688168916901691169216931694169516961697169816991700170117021703170417051706170717081709171017111712171317141715171617171718171917201721172217231724172517261727172817291730173117321733173417351736173717381739174017411742174317441745174617471748174917501751175217531754175517561757175817591760176117621763176417651766176717681769177017711772177317741775177617771778177917801781178217831784178517861787178817891790179117921793179417951796179717981799180018011802180318041805180618071808180918101811181218131814181518161817181818191820182118221823182418251826182718281829183018311832183318341835183618371838183918401841184218431844184518461847184818491850185118521853185418551856185718581859186018611862186318641865186618671868186918701871187218731874187518761877187818791880188118821883188418851886188718881889189018911892189318941895189618971898189919001901190219031904190519061907190819091910191119121913191419151916191719181919192019211922192319241925192619271928192919301931193219331934193519361937193819391940194119421943194419451946
  1. dnl Copyright (c) 2001-2004, Roger Dingledine
  2. dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
  3. dnl Copyright (c) 2007-2015, The Tor Project, Inc.
  4. dnl See LICENSE for licensing information
  5. AC_PREREQ([2.63])
  6. AC_INIT([tor],[0.3.0.1-alpha-dev])
  7. AC_CONFIG_SRCDIR([src/or/main.c])
  8. AC_CONFIG_MACRO_DIR([m4])
  9. # "foreign" means we don't follow GNU package layout standards
  10. # "1.11" means we require automake version 1.11 or newer
  11. # "subdir-objects" means put .o files in the same directory as the .c files
  12. AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  13. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  14. AC_CONFIG_HEADERS([orconfig.h])
  15. AC_USE_SYSTEM_EXTENSIONS
  16. AC_CANONICAL_HOST
  17. PKG_PROG_PKG_CONFIG
  18. if test -f "/etc/redhat-release"; then
  19. if test -f "/usr/kerberos/include"; then
  20. CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  21. fi
  22. fi
  23. # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  24. # the += operator on it in src/or/Makefile.am
  25. CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  26. AC_ARG_ENABLE(openbsd-malloc,
  27. AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD. Linux only]))
  28. AC_ARG_ENABLE(static-openssl,
  29. AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  30. AC_ARG_ENABLE(static-libevent,
  31. AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  32. AC_ARG_ENABLE(static-zlib,
  33. AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  34. AC_ARG_ENABLE(static-tor,
  35. AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  36. AC_ARG_ENABLE(unittests,
  37. AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  38. AC_ARG_ENABLE(coverage,
  39. AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  40. AC_ARG_ENABLE(asserts-in-tests,
  41. AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  42. AC_ARG_ENABLE(system-torrc,
  43. AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  44. if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  45. AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  46. fi
  47. AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  48. AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  49. AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  50. if test "$enable_static_tor" = "yes"; then
  51. enable_static_libevent="yes";
  52. enable_static_openssl="yes";
  53. enable_static_zlib="yes";
  54. CFLAGS="$CFLAGS -static"
  55. fi
  56. if test "$enable_system_torrc" = "no"; then
  57. AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  58. [Defined if we're not going to look for a torrc in SYSCONF])
  59. fi
  60. AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
  61. AC_ARG_ENABLE(asciidoc,
  62. AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  63. [case "${enableval}" in
  64. "yes") asciidoc=true ;;
  65. "no") asciidoc=false ;;
  66. *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  67. esac], [asciidoc=true])
  68. # systemd notify support
  69. AC_ARG_ENABLE(systemd,
  70. AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
  71. [case "${enableval}" in
  72. "yes") systemd=true ;;
  73. "no") systemd=false ;;
  74. * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
  75. esac], [systemd=auto])
  76. # systemd support
  77. if test "x$enable_systemd" = "xno"; then
  78. have_systemd=no;
  79. else
  80. PKG_CHECK_MODULES(SYSTEMD,
  81. [libsystemd-daemon],
  82. have_systemd=yes,
  83. have_systemd=no)
  84. if test "x$have_systemd" = "xno"; then
  85. AC_MSG_NOTICE([Okay, checking for systemd a different way...])
  86. PKG_CHECK_MODULES(SYSTEMD,
  87. [libsystemd],
  88. have_systemd=yes,
  89. have_systemd=no)
  90. fi
  91. fi
  92. if test "x$have_systemd" = "xyes"; then
  93. AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
  94. TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
  95. TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
  96. PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
  97. [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
  98. fi
  99. AC_SUBST(TOR_SYSTEMD_CFLAGS)
  100. AC_SUBST(TOR_SYSTEMD_LIBS)
  101. if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
  102. AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
  103. fi
  104. case "$host" in
  105. *-*-solaris* )
  106. AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  107. ;;
  108. esac
  109. AC_ARG_ENABLE(gcc-warnings,
  110. AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
  111. AC_ARG_ENABLE(fatal-warnings,
  112. AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
  113. AC_ARG_ENABLE(gcc-warnings-advisory,
  114. AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
  115. dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
  116. AC_ARG_ENABLE(gcc-hardening,
  117. AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
  118. AC_ARG_ENABLE(expensive-hardening,
  119. AS_HELP_STRING(--enable-expensive-hardening, [enable more expensive compiler hardening; makes Tor slower]))
  120. dnl Linker hardening options
  121. dnl Currently these options are ELF specific - you can't use this with MacOSX
  122. AC_ARG_ENABLE(linker-hardening,
  123. AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
  124. AC_ARG_ENABLE(local-appdata,
  125. AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
  126. if test "$enable_local_appdata" = "yes"; then
  127. AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
  128. [Defined if we default to host local appdata paths on Windows])
  129. fi
  130. # Tor2web mode flag
  131. AC_ARG_ENABLE(tor2web-mode,
  132. AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
  133. [if test "x$enableval" = "xyes"; then
  134. CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
  135. fi])
  136. AC_ARG_ENABLE(tool-name-check,
  137. AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
  138. AC_ARG_ENABLE(seccomp,
  139. AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
  140. AC_ARG_ENABLE(libscrypt,
  141. AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
  142. dnl check for the correct "ar" when cross-compiling
  143. AM_PROG_AR
  144. dnl Check whether the above macro has settled for a simply named tool even
  145. dnl though we're cross compiling. We must do this before running AC_PROG_CC,
  146. dnl because that will find any cc on the system, not only the cross-compiler,
  147. dnl and then verify that a binary built with this compiler runs on the
  148. dnl build system. It will then come to the false conclusion that we're not
  149. dnl cross-compiling.
  150. if test "x$enable_tool_name_check" != "xno"; then
  151. if test "x$ac_tool_warned" = "xyes"; then
  152. AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
  153. elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
  154. AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
  155. fi
  156. fi
  157. AC_PROG_CC
  158. AC_PROG_CPP
  159. AC_PROG_MAKE_SET
  160. AC_PROG_RANLIB
  161. AC_PROG_SED
  162. AC_ARG_VAR([PERL], [path to Perl binary])
  163. AC_CHECK_PROGS([PERL], [perl])
  164. AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
  165. dnl check for asciidoc and a2x
  166. AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
  167. AC_PATH_PROGS([A2X], [a2x a2x.py], none)
  168. AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
  169. AM_CONDITIONAL(USE_FW_HELPER, test "x$natpmp" = "xtrue" || test "x$upnp" = "xtrue")
  170. AM_CONDITIONAL(NAT_PMP, test "x$natpmp" = "xtrue")
  171. AM_CONDITIONAL(MINIUPNPC, test "x$upnp" = "xtrue")
  172. AM_PROG_CC_C_O
  173. AC_PROG_CC_C99
  174. AC_ARG_VAR([PYTHON], [path to Python binary])
  175. AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
  176. if test "x$PYTHON" = "x"; then
  177. AC_MSG_WARN([Python unavailable; some tests will not be run.])
  178. fi
  179. AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
  180. ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
  181. AC_C_FLEXIBLE_ARRAY_MEMBER
  182. ], [
  183. dnl Maybe we've got an old autoconf...
  184. AC_CACHE_CHECK([for flexible array members],
  185. tor_cv_c_flexarray,
  186. [AC_COMPILE_IFELSE(
  187. AC_LANG_PROGRAM([
  188. struct abc { int a; char b[]; };
  189. ], [
  190. struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
  191. def->b[0] = 33;
  192. ]),
  193. [tor_cv_c_flexarray=yes],
  194. [tor_cv_c_flexarray=no])])
  195. if test "$tor_cv_flexarray" = "yes"; then
  196. AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
  197. else
  198. AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
  199. fi
  200. ])
  201. AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
  202. tor_cv_c_c99_decl,
  203. [AC_COMPILE_IFELSE(
  204. [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
  205. [tor_cv_c_c99_decl=yes],
  206. [tor_cv_c_c99_decl=no] )])
  207. if test "$tor_cv_c_c99_decl" != "yes"; then
  208. AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
  209. fi
  210. AC_CACHE_CHECK([for working C99 designated initializers],
  211. tor_cv_c_c99_designated_init,
  212. [AC_COMPILE_IFELSE(
  213. [AC_LANG_PROGRAM([struct s { int a; int b; };],
  214. [[ struct s ss = { .b = 5, .a = 6 }; ]])],
  215. [tor_cv_c_c99_designated_init=yes],
  216. [tor_cv_c_c99_designated_init=no] )])
  217. if test "$tor_cv_c_c99_designated_init" != "yes"; then
  218. AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
  219. fi
  220. TORUSER=_tor
  221. AC_ARG_WITH(tor-user,
  222. AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
  223. [
  224. TORUSER=$withval
  225. ]
  226. )
  227. AC_SUBST(TORUSER)
  228. TORGROUP=_tor
  229. AC_ARG_WITH(tor-group,
  230. AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
  231. [
  232. TORGROUP=$withval
  233. ]
  234. )
  235. AC_SUBST(TORGROUP)
  236. dnl If _WIN32 is defined and non-zero, we are building for win32
  237. AC_MSG_CHECKING([for win32])
  238. AC_RUN_IFELSE([AC_LANG_SOURCE([
  239. int main(int c, char **v) {
  240. #ifdef _WIN32
  241. #if _WIN32
  242. return 0;
  243. #else
  244. return 1;
  245. #endif
  246. #else
  247. return 2;
  248. #endif
  249. }])],
  250. bwin32=true; AC_MSG_RESULT([yes]),
  251. bwin32=false; AC_MSG_RESULT([no]),
  252. bwin32=cross; AC_MSG_RESULT([cross])
  253. )
  254. if test "$bwin32" = "cross"; then
  255. AC_MSG_CHECKING([for win32 (cross)])
  256. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  257. #ifdef _WIN32
  258. int main(int c, char **v) {return 0;}
  259. #else
  260. #error
  261. int main(int c, char **v) {return x(y);}
  262. #endif
  263. ])],
  264. bwin32=true; AC_MSG_RESULT([yes]),
  265. bwin32=false; AC_MSG_RESULT([no]))
  266. fi
  267. AH_BOTTOM([
  268. #ifdef _WIN32
  269. /* Defined to access windows functions and definitions for >=WinXP */
  270. # ifndef WINVER
  271. # define WINVER 0x0501
  272. # endif
  273. /* Defined to access _other_ windows functions and definitions for >=WinXP */
  274. # ifndef _WIN32_WINNT
  275. # define _WIN32_WINNT 0x0501
  276. # endif
  277. /* Defined to avoid including some windows headers as part of Windows.h */
  278. # ifndef WIN32_LEAN_AND_MEAN
  279. # define WIN32_LEAN_AND_MEAN 1
  280. # endif
  281. #endif
  282. ])
  283. AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
  284. dnl Enable C99 when compiling with MIPSpro
  285. AC_MSG_CHECKING([for MIPSpro compiler])
  286. AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
  287. #if (defined(__sgi) && defined(_COMPILER_VERSION))
  288. #error
  289. return x(y);
  290. #endif
  291. ])],
  292. bmipspro=false; AC_MSG_RESULT(no),
  293. bmipspro=true; AC_MSG_RESULT(yes))
  294. if test "$bmipspro" = "true"; then
  295. CFLAGS="$CFLAGS -c99"
  296. fi
  297. AC_C_BIGENDIAN
  298. AC_SEARCH_LIBS(socket, [socket network])
  299. AC_SEARCH_LIBS(gethostbyname, [nsl])
  300. AC_SEARCH_LIBS(dlopen, [dl])
  301. AC_SEARCH_LIBS(inet_aton, [resolv])
  302. AC_SEARCH_LIBS(backtrace, [execinfo])
  303. saved_LIBS="$LIBS"
  304. AC_SEARCH_LIBS([clock_gettime], [rt])
  305. if test "$LIBS" != "$saved_LIBS"; then
  306. # Looks like we need -lrt for clock_gettime().
  307. have_rt=yes
  308. fi
  309. AC_SEARCH_LIBS(pthread_create, [pthread])
  310. AC_SEARCH_LIBS(pthread_detach, [pthread])
  311. AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
  312. AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
  313. AC_CHECK_FUNCS(
  314. _NSGetEnviron \
  315. RtlSecureZeroMemory \
  316. SecureZeroMemory \
  317. accept4 \
  318. backtrace \
  319. backtrace_symbols_fd \
  320. eventfd \
  321. explicit_bzero \
  322. timingsafe_memcmp \
  323. flock \
  324. ftime \
  325. getaddrinfo \
  326. getifaddrs \
  327. getpass \
  328. getrlimit \
  329. gettimeofday \
  330. gmtime_r \
  331. htonll \
  332. inet_aton \
  333. ioctl \
  334. issetugid \
  335. llround \
  336. localtime_r \
  337. lround \
  338. memmem \
  339. memset_s \
  340. pipe \
  341. pipe2 \
  342. prctl \
  343. readpassphrase \
  344. rint \
  345. sigaction \
  346. socketpair \
  347. statvfs \
  348. strlcat \
  349. strlcpy \
  350. strnlen \
  351. strptime \
  352. strtok_r \
  353. strtoull \
  354. sysconf \
  355. sysctl \
  356. truncate \
  357. uname \
  358. usleep \
  359. vasprintf \
  360. _vscprintf
  361. )
  362. # Apple messed up when they added two functions functions in Sierra: they
  363. # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
  364. # checks. So we should only probe for those functions if we are sure that we
  365. # are not targetting OSX 10.11 or earlier.
  366. AC_MSG_CHECKING([for a pre-Sierra OSX build target])
  367. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  368. #ifdef __APPLE__
  369. # include <AvailabilityMacros.h>
  370. # ifndef MAC_OS_X_VERSION_10_12
  371. # define MAC_OS_X_VERSION_10_12 101200
  372. # endif
  373. # if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
  374. # if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
  375. # error "Running on Mac OSX 10.11 or earlier"
  376. # endif
  377. # endif
  378. #endif
  379. ]], [[]])],
  380. [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
  381. [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
  382. if test "$on_macos_pre_10_12" = "no"; then
  383. AC_CHECK_FUNCS(
  384. clock_gettime \
  385. getentropy \
  386. )
  387. fi
  388. if test "$bwin32" != "true"; then
  389. AC_CHECK_HEADERS(pthread.h)
  390. AC_CHECK_FUNCS(pthread_create)
  391. AC_CHECK_FUNCS(pthread_condattr_setclock)
  392. fi
  393. if test "$bwin32" = "true"; then
  394. AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
  395. #include <windows.h>
  396. #include <conio.h>
  397. #include <wchar.h>
  398. ])
  399. fi
  400. AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
  401. test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
  402. dnl ------------------------------------------------------
  403. dnl Where do you live, libevent? And how do we call you?
  404. if test "$bwin32" = "true"; then
  405. TOR_LIB_WS32=-lws2_32
  406. TOR_LIB_IPHLPAPI=-liphlpapi
  407. # Some of the cargo-cults recommend -lwsock32 as well, but I don't
  408. # think it's actually necessary.
  409. TOR_LIB_GDI=-lgdi32
  410. else
  411. TOR_LIB_WS32=
  412. TOR_LIB_GDI=
  413. fi
  414. AC_SUBST(TOR_LIB_WS32)
  415. AC_SUBST(TOR_LIB_GDI)
  416. AC_SUBST(TOR_LIB_IPHLPAPI)
  417. tor_libevent_pkg_redhat="libevent"
  418. tor_libevent_pkg_debian="libevent-dev"
  419. tor_libevent_devpkg_redhat="libevent-devel"
  420. tor_libevent_devpkg_debian="libevent-dev"
  421. dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
  422. dnl linking for static builds.
  423. STATIC_LIBEVENT_FLAGS=""
  424. if test "$enable_static_libevent" = "yes"; then
  425. if test "$have_rt" = "yes"; then
  426. STATIC_LIBEVENT_FLAGS=" -lrt "
  427. fi
  428. fi
  429. TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
  430. #ifdef _WIN32
  431. #include <winsock2.h>
  432. #endif
  433. #include <sys/time.h>
  434. #include <sys/types.h>
  435. #include <event2/event.h>], [
  436. #ifdef _WIN32
  437. #include <winsock2.h>
  438. #endif
  439. void *event_init(void);],
  440. [
  441. #ifdef _WIN32
  442. {WSADATA d; WSAStartup(0x101,&d); }
  443. #endif
  444. event_init();
  445. ], [--with-libevent-dir], [/opt/libevent])
  446. dnl Determine the incantation needed to link libevent.
  447. save_LIBS="$LIBS"
  448. save_LDFLAGS="$LDFLAGS"
  449. save_CPPFLAGS="$CPPFLAGS"
  450. LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
  451. LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
  452. CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
  453. AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
  454. if test "$enable_static_libevent" = "yes"; then
  455. if test "$tor_cv_library_libevent_dir" = "(system)"; then
  456. AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
  457. else
  458. TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
  459. fi
  460. else
  461. if test "x$ac_cv_header_event2_event_h" = "xyes"; then
  462. AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
  463. AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
  464. if test "$ac_cv_search_event_new" != "none required"; then
  465. TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
  466. fi
  467. if test "$ac_cv_search_evdns_base_new" != "none required"; then
  468. TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
  469. fi
  470. else
  471. AC_MSG_ERROR("libevent2 is required but the headers could not be found")
  472. fi
  473. fi
  474. dnl Now check for particular libevent functions.
  475. AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
  476. evutil_secure_rng_add_bytes \
  477. ])
  478. LIBS="$save_LIBS"
  479. LDFLAGS="$save_LDFLAGS"
  480. CPPFLAGS="$save_CPPFLAGS"
  481. dnl Check that libevent is at least at version 2.0.10, the first stable
  482. dnl release of its series
  483. CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
  484. AC_MSG_CHECKING([whether Libevent is new enough])
  485. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  486. #include <event2/event.h>
  487. #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
  488. #error
  489. int x = y(zz);
  490. #else
  491. int x = 1;
  492. #endif
  493. ])], [ AC_MSG_RESULT([yes]) ],
  494. [ AC_MSG_RESULT([no])
  495. AC_MSG_ERROR([Libevent is not new enough. We require 2.0.10-stable or later]) ] )
  496. LIBS="$save_LIBS"
  497. LDFLAGS="$save_LDFLAGS"
  498. CPPFLAGS="$save_CPPFLAGS"
  499. AC_SUBST(TOR_LIBEVENT_LIBS)
  500. dnl ------------------------------------------------------
  501. dnl Where do you live, libm?
  502. dnl On some platforms (Haiku/BeOS) the math library is
  503. dnl part of libroot. In which case don't link against lm
  504. TOR_LIB_MATH=""
  505. save_LIBS="$LIBS"
  506. AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
  507. if test "$ac_cv_search_pow" != "none required"; then
  508. TOR_LIB_MATH="$ac_cv_search_pow"
  509. fi
  510. LIBS="$save_LIBS"
  511. AC_SUBST(TOR_LIB_MATH)
  512. dnl ------------------------------------------------------
  513. dnl Where do you live, openssl? And how do we call you?
  514. tor_openssl_pkg_redhat="openssl"
  515. tor_openssl_pkg_debian="libssl-dev"
  516. tor_openssl_devpkg_redhat="openssl-devel"
  517. tor_openssl_devpkg_debian="libssl-dev"
  518. ALT_openssl_WITHVAL=""
  519. AC_ARG_WITH(ssl-dir,
  520. AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
  521. [
  522. if test "x$withval" != "xno" && test "x$withval" != "x"; then
  523. ALT_openssl_WITHVAL="$withval"
  524. fi
  525. ])
  526. TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
  527. [#include <openssl/rand.h>],
  528. [void RAND_add(const void *buf, int num, double entropy);],
  529. [RAND_add((void*)0,0,0);], [],
  530. [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
  531. dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
  532. if test "$enable_static_openssl" = "yes"; then
  533. if test "$tor_cv_library_openssl_dir" = "(system)"; then
  534. AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
  535. else
  536. TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
  537. fi
  538. else
  539. TOR_OPENSSL_LIBS="-lssl -lcrypto"
  540. fi
  541. AC_SUBST(TOR_OPENSSL_LIBS)
  542. dnl Now check for particular openssl functions.
  543. save_LIBS="$LIBS"
  544. save_LDFLAGS="$LDFLAGS"
  545. save_CPPFLAGS="$CPPFLAGS"
  546. LIBS="$TOR_OPENSSL_LIBS $LIBS"
  547. LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
  548. CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
  549. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  550. #include <openssl/opensslv.h>
  551. #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
  552. #error "too old"
  553. #endif
  554. ]], [[]])],
  555. [ : ],
  556. [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
  557. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  558. #include <openssl/opensslv.h>
  559. #include <openssl/evp.h>
  560. #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
  561. #error "no ECC"
  562. #endif
  563. #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
  564. #error "curves unavailable"
  565. #endif
  566. ]], [[]])],
  567. [ : ],
  568. [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
  569. AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
  570. [#include <openssl/ssl.h>
  571. ])
  572. AC_CHECK_FUNCS([ \
  573. SSL_SESSION_get_master_key \
  574. SSL_get_server_random \
  575. SSL_get_client_ciphers \
  576. SSL_get_client_random \
  577. SSL_CIPHER_find \
  578. TLS_method
  579. ])
  580. dnl Check if OpenSSL has scrypt implementation.
  581. AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
  582. LIBS="$save_LIBS"
  583. LDFLAGS="$save_LDFLAGS"
  584. CPPFLAGS="$save_CPPFLAGS"
  585. dnl ------------------------------------------------------
  586. dnl Where do you live, zlib? And how do we call you?
  587. tor_zlib_pkg_redhat="zlib"
  588. tor_zlib_pkg_debian="zlib1g"
  589. tor_zlib_devpkg_redhat="zlib-devel"
  590. tor_zlib_devpkg_debian="zlib1g-dev"
  591. TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
  592. [#include <zlib.h>],
  593. [const char * zlibVersion(void);],
  594. [zlibVersion();], [--with-zlib-dir],
  595. [/opt/zlib])
  596. if test "$enable_static_zlib" = "yes"; then
  597. if test "$tor_cv_library_zlib_dir" = "(system)"; then
  598. AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
  599. using --enable-static-zlib")
  600. else
  601. TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
  602. fi
  603. else
  604. TOR_ZLIB_LIBS="-lz"
  605. fi
  606. AC_SUBST(TOR_ZLIB_LIBS)
  607. dnl ----------------------------------------------------------------------
  608. dnl Check if libcap is available for capabilities.
  609. tor_cap_pkg_debian="libcap2"
  610. tor_cap_pkg_redhat="libcap"
  611. tor_cap_devpkg_debian="libcap-dev"
  612. tor_cap_devpkg_redhat="libcap-devel"
  613. AC_CHECK_LIB([cap], [cap_init], [],
  614. AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
  615. )
  616. AC_CHECK_FUNCS(cap_set_proc)
  617. dnl ---------------------------------------------------------------------
  618. dnl Now that we know about our major libraries, we can check for compiler
  619. dnl and linker hardening options. We need to do this with the libraries known,
  620. dnl since sometimes the linker will like an option but not be willing to
  621. dnl use it with a build of a library.
  622. all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
  623. all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_CAP_LIBS"
  624. CFLAGS_FTRAPV=
  625. CFLAGS_FWRAPV=
  626. CFLAGS_ASAN=
  627. CFLAGS_UBSAN=
  628. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
  629. #if !defined(__clang__)
  630. #error
  631. #endif])], have_clang=yes, have_clang=no)
  632. if test "x$enable_gcc_hardening" != "xno"; then
  633. CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
  634. if test "x$have_clang" = "xyes"; then
  635. TOR_CHECK_CFLAGS(-Qunused-arguments)
  636. fi
  637. TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
  638. AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
  639. AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
  640. m4_ifdef([AS_VAR_IF],[
  641. AS_VAR_IF(can_compile, [yes],
  642. AS_VAR_IF(can_link, [yes],
  643. [],
  644. AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
  645. )])
  646. AS_VAR_POPDEF([can_link])
  647. AS_VAR_POPDEF([can_compile])
  648. TOR_CHECK_CFLAGS(-Wstack-protector)
  649. TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
  650. if test "$bwin32" = "false"; then
  651. TOR_CHECK_CFLAGS(-fPIE)
  652. TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
  653. fi
  654. TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
  655. TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
  656. if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
  657. AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
  658. fi
  659. fi
  660. if test "x$enable_expensive_hardening" = "xyes"; then
  661. if test "$tor_cv_cflags__ftrapv" != "yes"; then
  662. AC_MSG_ERROR([You requested expensive hardening, but the compiler does not seem to support -ftrapv.])
  663. fi
  664. TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
  665. if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
  666. AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.so, and with Clang you need libclang_rt.ubsan*])
  667. fi
  668. TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
  669. if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
  670. AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.so, and with Clang you need libclang_rt.ubsan*])
  671. fi
  672. TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
  673. fi
  674. CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
  675. CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
  676. mulodi_fixes_ftrapv=no
  677. if test "$have_clang" = "yes"; then
  678. saved_CFLAGS="$CFLAGS"
  679. CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
  680. AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
  681. AC_LINK_IFELSE([
  682. AC_LANG_SOURCE([[
  683. #include <stdint.h>
  684. #include <stdlib.h>
  685. int main(int argc, char **argv)
  686. {
  687. int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
  688. * (int64_t)atoi(argv[3]);
  689. return x == 9;
  690. } ]])],
  691. [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
  692. [ftrapv_can_link=no; AC_MSG_RESULT([no])])
  693. if test "$ftrapv_can_link" = "no"; then
  694. AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
  695. AC_LINK_IFELSE([
  696. AC_LANG_SOURCE([[
  697. #include <stdint.h>
  698. #include <stdlib.h>
  699. int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
  700. *overflow=0;
  701. return a;
  702. }
  703. int main(int argc, char **argv)
  704. {
  705. int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
  706. * (int64_t)atoi(argv[3]);
  707. return x == 9;
  708. } ]])],
  709. [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
  710. [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
  711. fi
  712. CFLAGS="$saved_CFLAGS"
  713. fi
  714. AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
  715. dnl These cflags add bunches of branches, and we haven't been able to
  716. dnl persuade ourselves that they're suitable for code that needs to be
  717. dnl constant time.
  718. AC_SUBST(CFLAGS_BUGTRAP)
  719. dnl These cflags are variant ones sutable for code that needs to be
  720. dnl constant-time.
  721. AC_SUBST(CFLAGS_CONSTTIME)
  722. if test "x$enable_linker_hardening" != "xno"; then
  723. TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
  724. fi
  725. # For backtrace support
  726. TOR_CHECK_LDFLAGS(-rdynamic)
  727. dnl ------------------------------------------------------
  728. dnl Now see if we have a -fomit-frame-pointer compiler option.
  729. saved_CFLAGS="$CFLAGS"
  730. TOR_CHECK_CFLAGS(-fomit-frame-pointer)
  731. F_OMIT_FRAME_POINTER=''
  732. if test "$saved_CFLAGS" != "$CFLAGS"; then
  733. if test "x$enable_expensive_hardening" != "xyes"; then
  734. F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
  735. fi
  736. fi
  737. CFLAGS="$saved_CFLAGS"
  738. AC_SUBST(F_OMIT_FRAME_POINTER)
  739. dnl ------------------------------------------------------
  740. dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
  741. dnl for us, as GCC 4.6 and later do at many optimization levels), then
  742. dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
  743. dnl code will work.
  744. TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
  745. dnl ============================================================
  746. dnl Check for libseccomp
  747. if test "x$enable_seccomp" != "xno"; then
  748. AC_CHECK_HEADERS([seccomp.h])
  749. AC_SEARCH_LIBS(seccomp_init, [seccomp])
  750. fi
  751. dnl ============================================================
  752. dnl Check for libscrypt
  753. if test "x$enable_libscrypt" != "xno"; then
  754. AC_CHECK_HEADERS([libscrypt.h])
  755. AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
  756. AC_CHECK_FUNCS([libscrypt_scrypt])
  757. fi
  758. dnl ============================================================
  759. dnl We need an implementation of curve25519.
  760. dnl set these defaults.
  761. build_curve25519_donna=no
  762. build_curve25519_donna_c64=no
  763. use_curve25519_donna=no
  764. use_curve25519_nacl=no
  765. CURVE25519_LIBS=
  766. dnl The best choice is using curve25519-donna-c64, but that requires
  767. dnl that we
  768. AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
  769. tor_cv_can_use_curve25519_donna_c64,
  770. [AC_RUN_IFELSE(
  771. [AC_LANG_PROGRAM([dnl
  772. #include <stdint.h>
  773. typedef unsigned uint128_t __attribute__((mode(TI)));
  774. int func(uint64_t a, uint64_t b) {
  775. uint128_t c = ((uint128_t)a) * b;
  776. int ok = ((uint64_t)(c>>96)) == 522859 &&
  777. (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
  778. (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
  779. (((uint64_t)(c))&0xffffffffL) == 0;
  780. return ok;
  781. }
  782. ], [dnl
  783. int ok = func( ((uint64_t)2000000000) * 1000000000,
  784. ((uint64_t)1234567890) << 24);
  785. return !ok;
  786. ])],
  787. [tor_cv_can_use_curve25519_donna_c64=yes],
  788. [tor_cv_can_use_curve25519_donna_c64=no],
  789. [AC_LINK_IFELSE(
  790. [AC_LANG_PROGRAM([dnl
  791. #include <stdint.h>
  792. typedef unsigned uint128_t __attribute__((mode(TI)));
  793. int func(uint64_t a, uint64_t b) {
  794. uint128_t c = ((uint128_t)a) * b;
  795. int ok = ((uint64_t)(c>>96)) == 522859 &&
  796. (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
  797. (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
  798. (((uint64_t)(c))&0xffffffffL) == 0;
  799. return ok;
  800. }
  801. ], [dnl
  802. int ok = func( ((uint64_t)2000000000) * 1000000000,
  803. ((uint64_t)1234567890) << 24);
  804. return !ok;
  805. ])],
  806. [tor_cv_can_use_curve25519_donna_c64=cross],
  807. [tor_cv_can_use_curve25519_donna_c64=no])])])
  808. AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
  809. nacl/crypto_scalarmult_curve25519.h])
  810. AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
  811. tor_cv_can_use_curve25519_nacl,
  812. [tor_saved_LIBS="$LIBS"
  813. LIBS="$LIBS -lnacl"
  814. AC_LINK_IFELSE(
  815. [AC_LANG_PROGRAM([dnl
  816. #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
  817. #include <crypto_scalarmult_curve25519.h>
  818. #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
  819. #include <nacl/crypto_scalarmult_curve25519.h>
  820. #endif
  821. #ifdef crypto_scalarmult_curve25519_ref_BYTES
  822. #error Hey, this is the reference implementation! That's not fast.
  823. #endif
  824. ], [
  825. unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
  826. ])], [tor_cv_can_use_curve25519_nacl=yes],
  827. [tor_cv_can_use_curve25519_nacl=no])
  828. LIBS="$tor_saved_LIBS" ])
  829. dnl Okay, now we need to figure out which one to actually use. Fall back
  830. dnl to curve25519-donna.c
  831. if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
  832. build_curve25519_donna_c64=yes
  833. use_curve25519_donna=yes
  834. elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
  835. use_curve25519_nacl=yes
  836. CURVE25519_LIBS=-lnacl
  837. else
  838. build_curve25519_donna=yes
  839. use_curve25519_donna=yes
  840. fi
  841. if test "x$use_curve25519_donna" = "xyes"; then
  842. AC_DEFINE(USE_CURVE25519_DONNA, 1,
  843. [Defined if we should use an internal curve25519_donna{,_c64} implementation])
  844. fi
  845. if test "x$use_curve25519_nacl" = "xyes"; then
  846. AC_DEFINE(USE_CURVE25519_NACL, 1,
  847. [Defined if we should use a curve25519 from nacl])
  848. fi
  849. AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
  850. test "x$build_curve25519_donna" = "xyes")
  851. AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
  852. test "x$build_curve25519_donna_c64" = "xyes")
  853. AC_SUBST(CURVE25519_LIBS)
  854. dnl Make sure to enable support for large off_t if available.
  855. AC_SYS_LARGEFILE
  856. AC_CHECK_HEADERS([assert.h \
  857. errno.h \
  858. fcntl.h \
  859. signal.h \
  860. string.h \
  861. sys/capability.h \
  862. sys/fcntl.h \
  863. sys/stat.h \
  864. sys/time.h \
  865. sys/types.h \
  866. time.h \
  867. unistd.h \
  868. arpa/inet.h \
  869. crt_externs.h \
  870. execinfo.h \
  871. grp.h \
  872. ifaddrs.h \
  873. inttypes.h \
  874. limits.h \
  875. linux/types.h \
  876. machine/limits.h \
  877. malloc.h \
  878. malloc/malloc.h \
  879. malloc_np.h \
  880. netdb.h \
  881. netinet/in.h \
  882. netinet/in6.h \
  883. pwd.h \
  884. readpassphrase.h \
  885. stdint.h \
  886. sys/eventfd.h \
  887. sys/file.h \
  888. sys/ioctl.h \
  889. sys/limits.h \
  890. sys/mman.h \
  891. sys/param.h \
  892. sys/prctl.h \
  893. sys/random.h \
  894. sys/resource.h \
  895. sys/select.h \
  896. sys/socket.h \
  897. sys/statvfs.h \
  898. sys/syscall.h \
  899. sys/sysctl.h \
  900. sys/syslimits.h \
  901. sys/time.h \
  902. sys/types.h \
  903. sys/un.h \
  904. sys/utime.h \
  905. sys/wait.h \
  906. syslog.h \
  907. utime.h])
  908. AC_CHECK_HEADERS(sys/param.h)
  909. AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
  910. [#ifdef HAVE_SYS_TYPES_H
  911. #include <sys/types.h>
  912. #endif
  913. #ifdef HAVE_SYS_SOCKET_H
  914. #include <sys/socket.h>
  915. #endif])
  916. AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
  917. [#ifdef HAVE_SYS_TYPES_H
  918. #include <sys/types.h>
  919. #endif
  920. #ifdef HAVE_SYS_SOCKET_H
  921. #include <sys/socket.h>
  922. #endif
  923. #ifdef HAVE_NET_IF_H
  924. #include <net/if.h>
  925. #endif
  926. #ifdef HAVE_NETINET_IN_H
  927. #include <netinet/in.h>
  928. #endif])
  929. AC_CHECK_HEADERS(linux/if.h,[],[],
  930. [
  931. #ifdef HAVE_SYS_SOCKET_H
  932. #include <sys/socket.h>
  933. #endif
  934. ])
  935. AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
  936. linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
  937. [#ifdef HAVE_SYS_TYPES_H
  938. #include <sys/types.h>
  939. #endif
  940. #ifdef HAVE_SYS_SOCKET_H
  941. #include <sys/socket.h>
  942. #endif
  943. #ifdef HAVE_LIMITS_H
  944. #include <limits.h>
  945. #endif
  946. #ifdef HAVE_LINUX_TYPES_H
  947. #include <linux/types.h>
  948. #endif
  949. #ifdef HAVE_NETINET_IN6_H
  950. #include <netinet/in6.h>
  951. #endif
  952. #ifdef HAVE_NETINET_IN_H
  953. #include <netinet/in.h>
  954. #endif])
  955. AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
  956. linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
  957. [#ifdef HAVE_SYS_TYPES_H
  958. #include <sys/types.h>
  959. #endif
  960. #ifdef HAVE_SYS_SOCKET_H
  961. #include <sys/socket.h>
  962. #endif
  963. #ifdef HAVE_LIMITS_H
  964. #include <limits.h>
  965. #endif
  966. #ifdef HAVE_LINUX_TYPES_H
  967. #include <linux/types.h>
  968. #endif
  969. #ifdef HAVE_NETINET_IN6_H
  970. #include <netinet/in6.h>
  971. #endif
  972. #ifdef HAVE_NETINET_IN_H
  973. #include <netinet/in.h>
  974. #endif
  975. #ifdef HAVE_LINUX_IF_H
  976. #include <linux/if.h>
  977. #endif])
  978. transparent_ok=0
  979. if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
  980. transparent_ok=1
  981. fi
  982. if test "x$linux_netfilter_ipv4" = "x1"; then
  983. transparent_ok=1
  984. fi
  985. if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
  986. transparent_ok=1
  987. fi
  988. if test "x$transparent_ok" = "x1"; then
  989. AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
  990. case "$host" in
  991. *-*-openbsd* | *-*-bitrig*)
  992. AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
  993. esac
  994. else
  995. AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
  996. fi
  997. AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
  998. [#ifdef HAVE_SYS_TYPES_H
  999. #include <sys/types.h>
  1000. #endif
  1001. #ifdef HAVE_SYS_TIME_H
  1002. #include <sys/time.h>
  1003. #endif])
  1004. dnl In case we aren't given a working stdint.h, we'll need to grow our own.
  1005. dnl Watch out.
  1006. AC_CHECK_SIZEOF(int8_t)
  1007. AC_CHECK_SIZEOF(int16_t)
  1008. AC_CHECK_SIZEOF(int32_t)
  1009. AC_CHECK_SIZEOF(int64_t)
  1010. AC_CHECK_SIZEOF(uint8_t)
  1011. AC_CHECK_SIZEOF(uint16_t)
  1012. AC_CHECK_SIZEOF(uint32_t)
  1013. AC_CHECK_SIZEOF(uint64_t)
  1014. AC_CHECK_SIZEOF(intptr_t)
  1015. AC_CHECK_SIZEOF(uintptr_t)
  1016. dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
  1017. AC_CHECK_SIZEOF(char)
  1018. AC_CHECK_SIZEOF(short)
  1019. AC_CHECK_SIZEOF(int)
  1020. AC_CHECK_SIZEOF(long)
  1021. AC_CHECK_SIZEOF(long long)
  1022. AC_CHECK_SIZEOF(__int64)
  1023. AC_CHECK_SIZEOF(void *)
  1024. AC_CHECK_SIZEOF(time_t)
  1025. AC_CHECK_SIZEOF(size_t)
  1026. AC_CHECK_SIZEOF(pid_t)
  1027. AC_CHECK_TYPES([uint, u_char, ssize_t])
  1028. AC_PC_FROM_UCONTEXT([:])
  1029. dnl used to include sockaddr_storage, but everybody has that.
  1030. AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
  1031. [#ifdef HAVE_SYS_TYPES_H
  1032. #include <sys/types.h>
  1033. #endif
  1034. #ifdef HAVE_NETINET_IN_H
  1035. #include <netinet/in.h>
  1036. #endif
  1037. #ifdef HAVE_NETINET_IN6_H
  1038. #include <netinet/in6.h>
  1039. #endif
  1040. #ifdef HAVE_SYS_SOCKET_H
  1041. #include <sys/socket.h>
  1042. #endif
  1043. #ifdef _WIN32
  1044. #define _WIN32_WINNT 0x0501
  1045. #define WIN32_LEAN_AND_MEAN
  1046. #include <winsock2.h>
  1047. #include <ws2tcpip.h>
  1048. #endif
  1049. ])
  1050. AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
  1051. [#ifdef HAVE_SYS_TYPES_H
  1052. #include <sys/types.h>
  1053. #endif
  1054. #ifdef HAVE_NETINET_IN_H
  1055. #include <netinet/in.h>
  1056. #endif
  1057. #ifdef HAVE_NETINET_IN6_H
  1058. #include <netinet/in6.h>
  1059. #endif
  1060. #ifdef HAVE_SYS_SOCKET_H
  1061. #include <sys/socket.h>
  1062. #endif
  1063. #ifdef _WIN32
  1064. #define _WIN32_WINNT 0x0501
  1065. #define WIN32_LEAN_AND_MEAN
  1066. #include <winsock2.h>
  1067. #include <ws2tcpip.h>
  1068. #endif
  1069. ])
  1070. AC_CHECK_TYPES([rlim_t], , ,
  1071. [#ifdef HAVE_SYS_TYPES_H
  1072. #include <sys/types.h>
  1073. #endif
  1074. #ifdef HAVE_SYS_TIME_H
  1075. #include <sys/time.h>
  1076. #endif
  1077. #ifdef HAVE_SYS_RESOURCE_H
  1078. #include <sys/resource.h>
  1079. #endif
  1080. ])
  1081. AX_CHECK_SIGN([time_t],
  1082. [ : ],
  1083. [ : ], [
  1084. #ifdef HAVE_SYS_TYPES_H
  1085. #include <sys/types.h>
  1086. #endif
  1087. #ifdef HAVE_SYS_TIME_H
  1088. #include <sys/time.h>
  1089. #endif
  1090. #ifdef HAVE_TIME_H
  1091. #include <time.h>
  1092. #endif
  1093. ])
  1094. if test "$ax_cv_decl_time_t_signed" = "no"; then
  1095. AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
  1096. fi
  1097. AX_CHECK_SIGN([size_t],
  1098. [ tor_cv_size_t_signed=yes ],
  1099. [ tor_cv_size_t_signed=no ], [
  1100. #ifdef HAVE_SYS_TYPES_H
  1101. #include <sys/types.h>
  1102. #endif
  1103. ])
  1104. if test "$ax_cv_decl_size_t_signed" = "yes"; then
  1105. AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
  1106. fi
  1107. AX_CHECK_SIGN([enum always],
  1108. [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
  1109. [ : ], [
  1110. enum always { AAA, BBB, CCC };
  1111. ])
  1112. AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
  1113. #ifdef HAVE_SYS_SOCKET_H
  1114. #include <sys/socket.h>
  1115. #endif
  1116. ])
  1117. # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
  1118. AC_CHECK_SIZEOF(cell_t)
  1119. # Now make sure that NULL can be represented as zero bytes.
  1120. AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
  1121. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1122. [[#include <stdlib.h>
  1123. #include <string.h>
  1124. #include <stdio.h>
  1125. #ifdef HAVE_STDDEF_H
  1126. #include <stddef.h>
  1127. #endif
  1128. int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
  1129. return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
  1130. [tor_cv_null_is_zero=yes],
  1131. [tor_cv_null_is_zero=no],
  1132. [tor_cv_null_is_zero=cross])])
  1133. if test "$tor_cv_null_is_zero" = "cross"; then
  1134. # Cross-compiling; let's hope that the target isn't raving mad.
  1135. AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
  1136. fi
  1137. if test "$tor_cv_null_is_zero" != "no"; then
  1138. AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
  1139. [Define to 1 iff memset(0) sets pointers to NULL])
  1140. fi
  1141. AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
  1142. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1143. [[#include <stdlib.h>
  1144. #include <string.h>
  1145. #include <stdio.h>
  1146. #ifdef HAVE_STDDEF_H
  1147. #include <stddef.h>
  1148. #endif
  1149. int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
  1150. return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
  1151. [tor_cv_dbl0_is_zero=yes],
  1152. [tor_cv_dbl0_is_zero=no],
  1153. [tor_cv_dbl0_is_zero=cross])])
  1154. if test "$tor_cv_dbl0_is_zero" = "cross"; then
  1155. # Cross-compiling; let's hope that the target isn't raving mad.
  1156. AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
  1157. fi
  1158. if test "$tor_cv_dbl0_is_zero" != "no"; then
  1159. AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
  1160. [Define to 1 iff memset(0) sets doubles to 0.0])
  1161. fi
  1162. # And what happens when we malloc zero?
  1163. AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
  1164. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1165. [[#include <stdlib.h>
  1166. #include <string.h>
  1167. #include <stdio.h>
  1168. #ifdef HAVE_STDDEF_H
  1169. #include <stddef.h>
  1170. #endif
  1171. int main () { return malloc(0)?0:1; }]])],
  1172. [tor_cv_malloc_zero_works=yes],
  1173. [tor_cv_malloc_zero_works=no],
  1174. [tor_cv_malloc_zero_works=cross])])
  1175. if test "$tor_cv_malloc_zero_works" = "cross"; then
  1176. # Cross-compiling; let's hope that the target isn't raving mad.
  1177. AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
  1178. fi
  1179. if test "$tor_cv_malloc_zero_works" = "yes"; then
  1180. AC_DEFINE([MALLOC_ZERO_WORKS], 1,
  1181. [Define to 1 iff malloc(0) returns a pointer])
  1182. fi
  1183. # whether we seem to be in a 2s-complement world.
  1184. AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
  1185. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1186. [[int main () { int problem = ((-99) != (~99)+1);
  1187. return problem ? 1 : 0; }]])],
  1188. [tor_cv_twos_complement=yes],
  1189. [tor_cv_twos_complement=no],
  1190. [tor_cv_twos_complement=cross])])
  1191. if test "$tor_cv_twos_complement" = "cross"; then
  1192. # Cross-compiling; let's hope that the target isn't raving mad.
  1193. AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
  1194. fi
  1195. if test "$tor_cv_twos_complement" != "no"; then
  1196. AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
  1197. [Define to 1 iff we represent negative integers with
  1198. two's complement])
  1199. fi
  1200. # What does shifting a negative value do?
  1201. AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
  1202. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1203. [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
  1204. [tor_cv_sign_extend=yes],
  1205. [tor_cv_sign_extend=no],
  1206. [tor_cv_sign_extend=cross])])
  1207. if test "$tor_cv_sign_extend" = "cross"; then
  1208. # Cross-compiling; let's hope that the target isn't raving mad.
  1209. AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
  1210. fi
  1211. if test "$tor_cv_sign_extend" != "no"; then
  1212. AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
  1213. [Define to 1 iff right-shifting a negative value performs sign-extension])
  1214. fi
  1215. # Whether we should use the dmalloc memory allocation debugging library.
  1216. AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
  1217. AC_ARG_WITH(dmalloc,
  1218. AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
  1219. [if [[ "$withval" = "yes" ]]; then
  1220. dmalloc=1
  1221. AC_MSG_RESULT(yes)
  1222. else
  1223. dmalloc=1
  1224. AC_MSG_RESULT(no)
  1225. fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
  1226. )
  1227. if [[ $dmalloc -eq 1 ]]; then
  1228. AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
  1229. AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
  1230. AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
  1231. AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
  1232. fi
  1233. AC_ARG_WITH(tcmalloc,
  1234. AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
  1235. [ tcmalloc=yes ], [ tcmalloc=no ])
  1236. if test "x$tcmalloc" = "xyes"; then
  1237. LDFLAGS="-ltcmalloc $LDFLAGS"
  1238. fi
  1239. using_custom_malloc=no
  1240. if test "x$enable_openbsd_malloc" = "xyes"; then
  1241. using_custom_malloc=yes
  1242. fi
  1243. if test "x$tcmalloc" = "xyes"; then
  1244. using_custom_malloc=yes
  1245. fi
  1246. if test "$using_custom_malloc" = "no"; then
  1247. AC_CHECK_FUNCS(mallinfo)
  1248. fi
  1249. # By default, we're going to assume we don't have mlockall()
  1250. # bionic and other platforms have various broken mlockall subsystems.
  1251. # Some systems don't have a working mlockall, some aren't linkable,
  1252. # and some have it but don't declare it.
  1253. AC_CHECK_FUNCS(mlockall)
  1254. AC_CHECK_DECLS([mlockall], , , [
  1255. #ifdef HAVE_SYS_MMAN_H
  1256. #include <sys/mman.h>
  1257. #endif])
  1258. # Some MinGW environments don't have getpagesize in unistd.h. We don't use
  1259. # AC_CHECK_FUNCS(getpagesize), because other environments rename getpagesize
  1260. # using macros
  1261. AC_CHECK_DECLS([getpagesize], , , [
  1262. #ifdef HAVE_UNISTD_H
  1263. #include <unistd.h>
  1264. #endif])
  1265. # Allow user to specify an alternate syslog facility
  1266. AC_ARG_WITH(syslog-facility,
  1267. AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
  1268. syslog_facility="$withval", syslog_facility="LOG_DAEMON")
  1269. AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
  1270. AC_SUBST(LOGFACILITY)
  1271. # Check if we have getresuid and getresgid
  1272. AC_CHECK_FUNCS(getresuid getresgid)
  1273. # Check for gethostbyname_r in all its glorious incompatible versions.
  1274. # (This logic is based on that in Python's configure.in)
  1275. AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
  1276. [Define this if you have any gethostbyname_r()])
  1277. AC_CHECK_FUNC(gethostbyname_r, [
  1278. AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
  1279. OLD_CFLAGS=$CFLAGS
  1280. CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
  1281. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  1282. #include <netdb.h>
  1283. ]], [[
  1284. char *cp1, *cp2;
  1285. struct hostent *h1, *h2;
  1286. int i1, i2;
  1287. (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
  1288. ]])],[
  1289. AC_DEFINE(HAVE_GETHOSTBYNAME_R)
  1290. AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
  1291. [Define this if gethostbyname_r takes 6 arguments])
  1292. AC_MSG_RESULT(6)
  1293. ], [
  1294. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  1295. #include <netdb.h>
  1296. ]], [[
  1297. char *cp1, *cp2;
  1298. struct hostent *h1;
  1299. int i1, i2;
  1300. (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
  1301. ]])], [
  1302. AC_DEFINE(HAVE_GETHOSTBYNAME_R)
  1303. AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
  1304. [Define this if gethostbyname_r takes 5 arguments])
  1305. AC_MSG_RESULT(5)
  1306. ], [
  1307. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  1308. #include <netdb.h>
  1309. ]], [[
  1310. char *cp1;
  1311. struct hostent *h1;
  1312. struct hostent_data hd;
  1313. (void) gethostbyname_r(cp1,h1,&hd);
  1314. ]])], [
  1315. AC_DEFINE(HAVE_GETHOSTBYNAME_R)
  1316. AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
  1317. [Define this if gethostbyname_r takes 3 arguments])
  1318. AC_MSG_RESULT(3)
  1319. ], [
  1320. AC_MSG_RESULT(0)
  1321. ])
  1322. ])
  1323. ])
  1324. CFLAGS=$OLD_CFLAGS
  1325. ])
  1326. AC_CACHE_CHECK([whether the C compiler supports __func__],
  1327. tor_cv_have_func_macro,
  1328. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  1329. #include <stdio.h>
  1330. int main(int c, char **v) { puts(__func__); }])],
  1331. tor_cv_have_func_macro=yes,
  1332. tor_cv_have_func_macro=no))
  1333. AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
  1334. tor_cv_have_FUNC_macro,
  1335. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  1336. #include <stdio.h>
  1337. int main(int c, char **v) { puts(__FUNC__); }])],
  1338. tor_cv_have_FUNC_macro=yes,
  1339. tor_cv_have_FUNC_macro=no))
  1340. AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
  1341. tor_cv_have_FUNCTION_macro,
  1342. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  1343. #include <stdio.h>
  1344. int main(int c, char **v) { puts(__FUNCTION__); }])],
  1345. tor_cv_have_FUNCTION_macro=yes,
  1346. tor_cv_have_FUNCTION_macro=no))
  1347. AC_CACHE_CHECK([whether we have extern char **environ already declared],
  1348. tor_cv_have_environ_declared,
  1349. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  1350. #ifdef HAVE_UNISTD_H
  1351. #include <unistd.h>
  1352. #endif
  1353. #include <stdlib.h>
  1354. int main(int c, char **v) { char **t = environ; }])],
  1355. tor_cv_have_environ_declared=yes,
  1356. tor_cv_have_environ_declared=no))
  1357. if test "$tor_cv_have_func_macro" = "yes"; then
  1358. AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
  1359. fi
  1360. if test "$tor_cv_have_FUNC_macro" = "yes"; then
  1361. AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
  1362. fi
  1363. if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
  1364. AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
  1365. [Defined if the compiler supports __FUNCTION__])
  1366. fi
  1367. if test "$tor_cv_have_environ_declared" = "yes"; then
  1368. AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
  1369. [Defined if we have extern char **environ already declared])
  1370. fi
  1371. # $prefix stores the value of the --prefix command line option, or
  1372. # NONE if the option wasn't set. In the case that it wasn't set, make
  1373. # it be the default, so that we can use it to expand directories now.
  1374. if test "x$prefix" = "xNONE"; then
  1375. prefix=$ac_default_prefix
  1376. fi
  1377. # and similarly for $exec_prefix
  1378. if test "x$exec_prefix" = "xNONE"; then
  1379. exec_prefix=$prefix
  1380. fi
  1381. if test "x$BUILDDIR" = "x"; then
  1382. BUILDDIR=`pwd`
  1383. fi
  1384. AC_SUBST(BUILDDIR)
  1385. AH_TEMPLATE([BUILDDIR],[tor's build directory])
  1386. AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
  1387. if test "x$CONFDIR" = "x"; then
  1388. CONFDIR=`eval echo $sysconfdir/tor`
  1389. fi
  1390. AC_SUBST(CONFDIR)
  1391. AH_TEMPLATE([CONFDIR],[tor's configuration directory])
  1392. AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
  1393. BINDIR=`eval echo $bindir`
  1394. AC_SUBST(BINDIR)
  1395. LOCALSTATEDIR=`eval echo $localstatedir`
  1396. AC_SUBST(LOCALSTATEDIR)
  1397. if test "$bwin32" = "true"; then
  1398. # Test if the linker supports the --nxcompat and --dynamicbase options
  1399. # for Windows
  1400. save_LDFLAGS="$LDFLAGS"
  1401. LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
  1402. AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
  1403. AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
  1404. [AC_MSG_RESULT([yes])]
  1405. [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
  1406. [AC_MSG_RESULT([no])]
  1407. )
  1408. LDFLAGS="$save_LDFLAGS"
  1409. fi
  1410. # Set CFLAGS _after_ all the above checks, since our warnings are stricter
  1411. # than autoconf's macros like.
  1412. if test "$GCC" = "yes"; then
  1413. # Disable GCC's strict aliasing checks. They are an hours-to-debug
  1414. # accident waiting to happen.
  1415. CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
  1416. else
  1417. # Override optimization level for non-gcc compilers
  1418. CFLAGS="$CFLAGS -O"
  1419. enable_gcc_warnings=no
  1420. enable_gcc_warnings_advisory=no
  1421. fi
  1422. # Warnings implies advisory-warnings and -Werror.
  1423. if test "$enable_gcc_warnings" = "yes"; then
  1424. enable_gcc_warnings_advisory=yes
  1425. enable_fatal_warnings=yes
  1426. fi
  1427. # OS X Lion started deprecating the system openssl. Let's just disable
  1428. # all deprecation warnings on OS X. Also, to potentially make the binary
  1429. # a little smaller, let's enable dead_strip.
  1430. case "$host_os" in
  1431. darwin*)
  1432. CFLAGS="$CFLAGS -Wno-deprecated-declarations"
  1433. LDFLAGS="$LDFLAGS -dead_strip" ;;
  1434. esac
  1435. # Add some more warnings which we use in development but not in the
  1436. # released versions. (Some relevant gcc versions can't handle these.)
  1437. #
  1438. # Note that we have to do this near the end of the autoconf process, or
  1439. # else we may run into problems when these warnings hit on the testing C
  1440. # programs that autoconf wants to build.
  1441. if test "x$enable_gcc_warnings_advisory" != "xno"; then
  1442. case "$host" in
  1443. *-*-openbsd* | *-*-bitrig*)
  1444. # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
  1445. # That's fine, except that the headers don't pass -Wredundant-decls.
  1446. # Therefore, let's disable -Wsystem-headers when we're building
  1447. # with maximal warnings on OpenBSD.
  1448. CFLAGS="$CFLAGS -Wno-system-headers" ;;
  1449. esac
  1450. # GCC4.3 users once report trouble with -Wstrict-overflow=5. GCC5 users
  1451. # have it work better.
  1452. # CFLAGS="$CFLAGS -Wstrict-overflow=1"
  1453. # This warning was added in gcc 4.3, but it appears to generate
  1454. # spurious warnings in gcc 4.4. I don't know if it works in 4.5.
  1455. #CFLAGS="$CFLAGS -Wlogical-op"
  1456. m4_foreach_w([warning_flag], [
  1457. -Waddress
  1458. -Waddress-of-array-temporary
  1459. -Waddress-of-temporary
  1460. -Wambiguous-macro
  1461. -Wanonymous-pack-parens
  1462. -Warc
  1463. -Warc-abi
  1464. -Warc-bridge-casts-disallowed-in-nonarc
  1465. -Warc-maybe-repeated-use-of-weak
  1466. -Warc-performSelector-leaks
  1467. -Warc-repeated-use-of-weak
  1468. -Warray-bounds
  1469. -Warray-bounds-pointer-arithmetic
  1470. -Wasm
  1471. -Wasm-operand-widths
  1472. -Watomic-properties
  1473. -Watomic-property-with-user-defined-accessor
  1474. -Wauto-import
  1475. -Wauto-storage-class
  1476. -Wauto-var-id
  1477. -Wavailability
  1478. -Wbackslash-newline-escape
  1479. -Wbad-array-new-length
  1480. -Wbind-to-temporary-copy
  1481. -Wbitfield-constant-conversion
  1482. -Wbool-conversion
  1483. -Wbool-conversions
  1484. -Wbuiltin-requires-header
  1485. -Wchar-align
  1486. -Wcompare-distinct-pointer-types
  1487. -Wcomplex-component-init
  1488. -Wconditional-type-mismatch
  1489. -Wconfig-macros
  1490. -Wconstant-conversion
  1491. -Wconstant-logical-operand
  1492. -Wconstexpr-not-const
  1493. -Wcustom-atomic-properties
  1494. -Wdangling-field
  1495. -Wdangling-initializer-list
  1496. -Wdate-time
  1497. -Wdelegating-ctor-cycles
  1498. -Wdeprecated-implementations
  1499. -Wdeprecated-register
  1500. -Wdirect-ivar-access
  1501. -Wdiscard-qual
  1502. -Wdistributed-object-modifiers
  1503. -Wdivision-by-zero
  1504. -Wdollar-in-identifier-extension
  1505. -Wdouble-promotion
  1506. -Wduplicate-decl-specifier
  1507. -Wduplicate-enum
  1508. -Wduplicate-method-arg
  1509. -Wduplicate-method-match
  1510. -Wduplicated-cond
  1511. -Wdynamic-class-memaccess
  1512. -Wembedded-directive
  1513. -Wempty-translation-unit
  1514. -Wenum-conversion
  1515. -Wexit-time-destructors
  1516. -Wexplicit-ownership-type
  1517. -Wextern-initializer
  1518. -Wextra
  1519. -Wextra-semi
  1520. -Wextra-tokens
  1521. -Wflexible-array-extensions
  1522. -Wfloat-conversion
  1523. -Wformat-non-iso
  1524. -Wfour-char-constants
  1525. -Wgcc-compat
  1526. -Wglobal-constructors
  1527. -Wgnu-array-member-paren-init
  1528. -Wgnu-designator
  1529. -Wgnu-static-float-init
  1530. -Wheader-guard
  1531. -Wheader-hygiene
  1532. -Widiomatic-parentheses
  1533. -Wignored-attributes
  1534. -Wimplicit-atomic-properties
  1535. -Wimplicit-conversion-floating-point-to-bool
  1536. -Wimplicit-exception-spec-mismatch
  1537. -Wimplicit-fallthrough
  1538. -Wimplicit-fallthrough-per-function
  1539. -Wimplicit-retain-self
  1540. -Wimport-preprocessor-directive-pedantic
  1541. -Wincompatible-library-redeclaration
  1542. -Wincompatible-pointer-types-discards-qualifiers
  1543. -Wincomplete-implementation
  1544. -Wincomplete-module
  1545. -Wincomplete-umbrella
  1546. -Winit-self
  1547. -Wint-conversions
  1548. -Wint-to-void-pointer-cast
  1549. -Winteger-overflow
  1550. -Winvalid-constexpr
  1551. -Winvalid-iboutlet
  1552. -Winvalid-noreturn
  1553. -Winvalid-pp-token
  1554. -Winvalid-source-encoding
  1555. -Winvalid-token-paste
  1556. -Wknr-promoted-parameter
  1557. -Wlanguage-extension-token
  1558. -Wlarge-by-value-copy
  1559. -Wliteral-conversion
  1560. -Wliteral-range
  1561. -Wlocal-type-template-args
  1562. -Wlogical-op
  1563. -Wloop-analysis
  1564. -Wmain-return-type
  1565. -Wmalformed-warning-check
  1566. -Wmethod-signatures
  1567. -Wmicrosoft
  1568. -Wmicrosoft-exists
  1569. -Wmismatched-parameter-types
  1570. -Wmismatched-return-types
  1571. -Wmissing-field-initializers
  1572. -Wmissing-format-attribute
  1573. -Wmissing-noreturn
  1574. -Wmissing-selector-name
  1575. -Wmissing-sysroot
  1576. -Wmissing-variable-declarations
  1577. -Wmodule-conflict
  1578. -Wnested-anon-types
  1579. -Wnewline-eof
  1580. -Wnon-literal-null-conversion
  1581. -Wnon-pod-varargs
  1582. -Wnonportable-cfstrings
  1583. -Wnormalized=id
  1584. -Wnull-arithmetic
  1585. -Wnull-character
  1586. -Wnull-conversion
  1587. -Wnull-dereference
  1588. -Wout-of-line-declaration
  1589. -Wover-aligned
  1590. -Woverlength-strings
  1591. -Woverride-init
  1592. -Woverriding-method-mismatch
  1593. -Wpointer-type-mismatch
  1594. -Wpredefined-identifier-outside-function
  1595. -Wprotocol-property-synthesis-ambiguity
  1596. -Wreadonly-iboutlet-property
  1597. -Wreadonly-setter-attrs
  1598. -Wreceiver-expr
  1599. -Wreceiver-forward-class
  1600. -Wreceiver-is-weak
  1601. -Wreinterpret-base-class
  1602. -Wrequires-super-attribute
  1603. -Wreserved-user-defined-literal
  1604. -Wreturn-stack-address
  1605. -Wsection
  1606. -Wselector-type-mismatch
  1607. -Wsentinel
  1608. -Wserialized-diagnostics
  1609. -Wshadow
  1610. -Wshift-count-negative
  1611. -Wshift-count-overflow
  1612. -Wshift-negative-value
  1613. -Wshift-overflow=2
  1614. -Wshift-sign-overflow
  1615. -Wshorten-64-to-32
  1616. -Wsizeof-array-argument
  1617. -Wsource-uses-openmp
  1618. -Wstatic-float-init
  1619. -Wstatic-in-inline
  1620. -Wstatic-local-in-inline
  1621. -Wstrict-overflow=2
  1622. -Wstring-compare
  1623. -Wstring-conversion
  1624. -Wstrlcpy-strlcat-size
  1625. -Wstrncat-size
  1626. -Wsuggest-attribute=format
  1627. -Wsuggest-attribute=noreturn
  1628. -Wsuper-class-method-mismatch
  1629. -Wswitch-bool
  1630. -Wsync-nand
  1631. -Wtautological-constant-out-of-range-compare
  1632. -Wtentative-definition-incomplete-type
  1633. -Wtrampolines
  1634. -Wtype-safety
  1635. -Wtypedef-redefinition
  1636. -Wtypename-missing
  1637. -Wundefined-inline
  1638. -Wundefined-internal
  1639. -Wundefined-reinterpret-cast
  1640. -Wunicode
  1641. -Wunicode-whitespace
  1642. -Wunknown-warning-option
  1643. -Wunnamed-type-template-args
  1644. -Wunneeded-member-function
  1645. -Wunsequenced
  1646. -Wunsupported-visibility
  1647. -Wunused-but-set-parameter
  1648. -Wunused-but-set-variable
  1649. -Wunused-command-line-argument
  1650. -Wunused-const-variable=2
  1651. -Wunused-exception-parameter
  1652. -Wunused-local-typedefs
  1653. -Wunused-member-function
  1654. -Wunused-sanitize-argument
  1655. -Wunused-volatile-lvalue
  1656. -Wuser-defined-literals
  1657. -Wvariadic-macros
  1658. -Wvector-conversion
  1659. -Wvector-conversions
  1660. -Wvexing-parse
  1661. -Wvisibility
  1662. -Wvla-extension
  1663. -Wzero-length-array
  1664. ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
  1665. dnl These seem to require annotations that we don't currently use,
  1666. dnl and they give false positives in our pthreads wrappers. (Clang 4)
  1667. dnl -Wthread-safety
  1668. dnl -Wthread-safety-analysis
  1669. dnl -Wthread-safety-attributes
  1670. dnl -Wthread-safety-beta
  1671. dnl -Wthread-safety-precise
  1672. CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
  1673. CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
  1674. CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
  1675. CFLAGS="$CFLAGS -Wwrite-strings"
  1676. CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
  1677. CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
  1678. CFLAGS="$CFLAGS -Wunused-parameter "
  1679. # These interfere with building main() { return 0; }, which autoconf
  1680. # likes to use as its default program.
  1681. CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
  1682. if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
  1683. AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
  1684. fi
  1685. if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
  1686. AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
  1687. fi
  1688. if test "x$enable_fatal_warnings" = "xyes"; then
  1689. # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
  1690. # default autoconf programs are full of errors.
  1691. CFLAGS="$CFLAGS -Werror"
  1692. fi
  1693. fi
  1694. if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
  1695. case "$host_os" in
  1696. darwin*)
  1697. AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
  1698. esac
  1699. fi
  1700. CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
  1701. AC_CONFIG_FILES([
  1702. Doxyfile
  1703. Makefile
  1704. contrib/dist/suse/tor.sh
  1705. contrib/operator-tools/tor.logrotate
  1706. contrib/dist/tor.sh
  1707. contrib/dist/torctl
  1708. contrib/dist/tor.service
  1709. src/config/torrc.sample
  1710. src/config/torrc.minimal
  1711. scripts/maint/checkOptionDocs.pl
  1712. scripts/maint/updateVersions.pl
  1713. ])
  1714. if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
  1715. regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
  1716. for file in $regular_mans ; do
  1717. if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
  1718. echo "==================================";
  1719. echo;
  1720. echo "Building Tor has failed since manpages cannot be built.";
  1721. echo;
  1722. echo "You need asciidoc installed to be able to build the manpages.";
  1723. echo "To build without manpages, use the --disable-asciidoc argument";
  1724. echo "when calling configure.";
  1725. echo;
  1726. echo "==================================";
  1727. exit 1;
  1728. fi
  1729. done
  1730. fi
  1731. AC_OUTPUT