configure.ac 60 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586878889909192939495969798991001011021031041051061071081091101111121131141151161171181191201211221231241251261271281291301311321331341351361371381391401411421431441451461471481491501511521531541551561571581591601611621631641651661671681691701711721731741751761771781791801811821831841851861871881891901911921931941951961971981992002012022032042052062072082092102112122132142152162172182192202212222232242252262272282292302312322332342352362372382392402412422432442452462472482492502512522532542552562572582592602612622632642652662672682692702712722732742752762772782792802812822832842852862872882892902912922932942952962972982993003013023033043053063073083093103113123133143153163173183193203213223233243253263273283293303313323333343353363373383393403413423433443453463473483493503513523533543553563573583593603613623633643653663673683693703713723733743753763773783793803813823833843853863873883893903913923933943953963973983994004014024034044054064074084094104114124134144154164174184194204214224234244254264274284294304314324334344354364374384394404414424434444454464474484494504514524534544554564574584594604614624634644654664674684694704714724734744754764774784794804814824834844854864874884894904914924934944954964974984995005015025035045055065075085095105115125135145155165175185195205215225235245255265275285295305315325335345355365375385395405415425435445455465475485495505515525535545555565575585595605615625635645655665675685695705715725735745755765775785795805815825835845855865875885895905915925935945955965975985996006016026036046056066076086096106116126136146156166176186196206216226236246256266276286296306316326336346356366376386396406416426436446456466476486496506516526536546556566576586596606616626636646656666676686696706716726736746756766776786796806816826836846856866876886896906916926936946956966976986997007017027037047057067077087097107117127137147157167177187197207217227237247257267277287297307317327337347357367377387397407417427437447457467477487497507517527537547557567577587597607617627637647657667677687697707717727737747757767777787797807817827837847857867877887897907917927937947957967977987998008018028038048058068078088098108118128138148158168178188198208218228238248258268278288298308318328338348358368378388398408418428438448458468478488498508518528538548558568578588598608618628638648658668678688698708718728738748758768778788798808818828838848858868878888898908918928938948958968978988999009019029039049059069079089099109119129139149159169179189199209219229239249259269279289299309319329339349359369379389399409419429439449459469479489499509519529539549559569579589599609619629639649659669679689699709719729739749759769779789799809819829839849859869879889899909919929939949959969979989991000100110021003100410051006100710081009101010111012101310141015101610171018101910201021102210231024102510261027102810291030103110321033103410351036103710381039104010411042104310441045104610471048104910501051105210531054105510561057105810591060106110621063106410651066106710681069107010711072107310741075107610771078107910801081108210831084108510861087108810891090109110921093109410951096109710981099110011011102110311041105110611071108110911101111111211131114111511161117111811191120112111221123112411251126112711281129113011311132113311341135113611371138113911401141114211431144114511461147114811491150115111521153115411551156115711581159116011611162116311641165116611671168116911701171117211731174117511761177117811791180118111821183118411851186118711881189119011911192119311941195119611971198119912001201120212031204120512061207120812091210121112121213121412151216121712181219122012211222122312241225122612271228122912301231123212331234123512361237123812391240124112421243124412451246124712481249125012511252125312541255125612571258125912601261126212631264126512661267126812691270127112721273127412751276127712781279128012811282128312841285128612871288128912901291129212931294129512961297129812991300130113021303130413051306130713081309131013111312131313141315131613171318131913201321132213231324132513261327132813291330133113321333133413351336133713381339134013411342134313441345134613471348134913501351135213531354135513561357135813591360136113621363136413651366136713681369137013711372137313741375137613771378137913801381138213831384138513861387138813891390139113921393139413951396139713981399140014011402140314041405140614071408140914101411141214131414141514161417141814191420142114221423142414251426142714281429143014311432143314341435143614371438143914401441144214431444144514461447144814491450145114521453145414551456145714581459146014611462146314641465146614671468146914701471147214731474147514761477147814791480148114821483148414851486148714881489149014911492149314941495149614971498149915001501150215031504150515061507150815091510151115121513151415151516151715181519152015211522152315241525152615271528152915301531153215331534153515361537153815391540154115421543154415451546154715481549155015511552155315541555155615571558155915601561156215631564156515661567156815691570157115721573157415751576157715781579158015811582158315841585158615871588158915901591159215931594159515961597159815991600160116021603160416051606160716081609161016111612161316141615161616171618161916201621162216231624162516261627162816291630163116321633163416351636163716381639164016411642164316441645164616471648164916501651165216531654165516561657165816591660166116621663166416651666166716681669167016711672167316741675167616771678167916801681168216831684168516861687168816891690169116921693169416951696169716981699170017011702170317041705170617071708170917101711171217131714171517161717171817191720172117221723172417251726172717281729173017311732173317341735173617371738173917401741174217431744174517461747174817491750175117521753175417551756175717581759176017611762176317641765176617671768176917701771177217731774177517761777177817791780178117821783178417851786178717881789179017911792179317941795179617971798179918001801180218031804180518061807180818091810181118121813181418151816181718181819182018211822182318241825182618271828182918301831183218331834183518361837183818391840184118421843184418451846184718481849185018511852185318541855185618571858185918601861186218631864186518661867186818691870187118721873187418751876187718781879188018811882188318841885188618871888188918901891189218931894189518961897189818991900190119021903190419051906190719081909191019111912191319141915191619171918191919201921192219231924192519261927192819291930193119321933193419351936193719381939194019411942194319441945194619471948194919501951
  1. dnl Copyright (c) 2001-2004, Roger Dingledine
  2. dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
  3. dnl Copyright (c) 2007-2015, The Tor Project, Inc.
  4. dnl See LICENSE for licensing information
  5. AC_PREREQ([2.63])
  6. AC_INIT([tor],[0.3.0.1-alpha-dev])
  7. AC_CONFIG_SRCDIR([src/or/main.c])
  8. AC_CONFIG_MACRO_DIR([m4])
  9. # "foreign" means we don't follow GNU package layout standards
  10. # "1.11" means we require automake version 1.11 or newer
  11. # "subdir-objects" means put .o files in the same directory as the .c files
  12. AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects])
  13. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  14. AC_CONFIG_HEADERS([orconfig.h])
  15. AC_USE_SYSTEM_EXTENSIONS
  16. AC_CANONICAL_HOST
  17. PKG_PROG_PKG_CONFIG
  18. if test -f "/etc/redhat-release"; then
  19. if test -f "/usr/kerberos/include"; then
  20. CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  21. fi
  22. fi
  23. # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  24. # the += operator on it in src/or/Makefile.am
  25. CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  26. AC_ARG_ENABLE(openbsd-malloc,
  27. AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD. Linux only]))
  28. AC_ARG_ENABLE(static-openssl,
  29. AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  30. AC_ARG_ENABLE(static-libevent,
  31. AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  32. AC_ARG_ENABLE(static-zlib,
  33. AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  34. AC_ARG_ENABLE(static-tor,
  35. AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  36. AC_ARG_ENABLE(unittests,
  37. AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  38. AC_ARG_ENABLE(coverage,
  39. AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  40. AC_ARG_ENABLE(asserts-in-tests,
  41. AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  42. AC_ARG_ENABLE(system-torrc,
  43. AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  44. if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  45. AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  46. fi
  47. AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  48. AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  49. AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  50. if test "$enable_static_tor" = "yes"; then
  51. enable_static_libevent="yes";
  52. enable_static_openssl="yes";
  53. enable_static_zlib="yes";
  54. CFLAGS="$CFLAGS -static"
  55. fi
  56. if test "$enable_system_torrc" = "no"; then
  57. AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  58. [Defined if we're not going to look for a torrc in SYSCONF])
  59. fi
  60. AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
  61. AC_ARG_ENABLE(asciidoc,
  62. AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  63. [case "${enableval}" in
  64. "yes") asciidoc=true ;;
  65. "no") asciidoc=false ;;
  66. *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  67. esac], [asciidoc=true])
  68. # systemd notify support
  69. AC_ARG_ENABLE(systemd,
  70. AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
  71. [case "${enableval}" in
  72. "yes") systemd=true ;;
  73. "no") systemd=false ;;
  74. * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
  75. esac], [systemd=auto])
  76. # systemd support
  77. if test "x$enable_systemd" = "xno"; then
  78. have_systemd=no;
  79. else
  80. PKG_CHECK_MODULES(SYSTEMD,
  81. [libsystemd-daemon],
  82. have_systemd=yes,
  83. have_systemd=no)
  84. if test "x$have_systemd" = "xno"; then
  85. AC_MSG_NOTICE([Okay, checking for systemd a different way...])
  86. PKG_CHECK_MODULES(SYSTEMD,
  87. [libsystemd],
  88. have_systemd=yes,
  89. have_systemd=no)
  90. fi
  91. fi
  92. if test "x$have_systemd" = "xyes"; then
  93. AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
  94. TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
  95. TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
  96. PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
  97. [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
  98. fi
  99. AC_SUBST(TOR_SYSTEMD_CFLAGS)
  100. AC_SUBST(TOR_SYSTEMD_LIBS)
  101. if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
  102. AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
  103. fi
  104. case "$host" in
  105. *-*-solaris* )
  106. AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  107. ;;
  108. esac
  109. AC_ARG_ENABLE(gcc-warnings,
  110. AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
  111. AC_ARG_ENABLE(fatal-warnings,
  112. AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
  113. AC_ARG_ENABLE(gcc-warnings-advisory,
  114. AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
  115. dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
  116. AC_ARG_ENABLE(gcc-hardening,
  117. AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
  118. AC_ARG_ENABLE(expensive-hardening,
  119. AS_HELP_STRING(--enable-expensive-hardening, [enable more expensive compiler hardening; makes Tor slower]))
  120. dnl Linker hardening options
  121. dnl Currently these options are ELF specific - you can't use this with MacOSX
  122. AC_ARG_ENABLE(linker-hardening,
  123. AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
  124. AC_ARG_ENABLE(local-appdata,
  125. AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
  126. if test "$enable_local_appdata" = "yes"; then
  127. AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
  128. [Defined if we default to host local appdata paths on Windows])
  129. fi
  130. # Tor2web mode flag
  131. AC_ARG_ENABLE(tor2web-mode,
  132. AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
  133. [if test "x$enableval" = "xyes"; then
  134. CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
  135. fi])
  136. AC_ARG_ENABLE(tool-name-check,
  137. AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
  138. AC_ARG_ENABLE(seccomp,
  139. AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
  140. AC_ARG_ENABLE(libscrypt,
  141. AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
  142. dnl check for the correct "ar" when cross-compiling
  143. AN_MAKEVAR([AR], [AC_PROG_AR])
  144. AN_PROGRAM([ar], [AC_PROG_AR])
  145. AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [ar])])
  146. AC_PROG_AR
  147. dnl Check whether the above macro has settled for a simply named tool even
  148. dnl though we're cross compiling. We must do this before running AC_PROG_CC,
  149. dnl because that will find any cc on the system, not only the cross-compiler,
  150. dnl and then verify that a binary built with this compiler runs on the
  151. dnl build system. It will then come to the false conclusion that we're not
  152. dnl cross-compiling.
  153. if test "x$enable_tool_name_check" != "xno"; then
  154. if test "x$ac_tool_warned" = "xyes"; then
  155. AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
  156. elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
  157. AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
  158. fi
  159. fi
  160. AC_PROG_CC
  161. AC_PROG_CPP
  162. AC_PROG_MAKE_SET
  163. AC_PROG_RANLIB
  164. AC_ARG_VAR([PERL], [path to Perl binary])
  165. AC_CHECK_PROGS([PERL], [perl])
  166. AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
  167. dnl autoconf 2.59 appears not to support AC_PROG_SED
  168. AC_CHECK_PROG([SED],[sed],[sed],[/bin/false])
  169. dnl check for asciidoc and a2x
  170. AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
  171. AC_PATH_PROGS([A2X], [a2x a2x.py], none)
  172. AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
  173. AM_CONDITIONAL(USE_FW_HELPER, test "x$natpmp" = "xtrue" || test "x$upnp" = "xtrue")
  174. AM_CONDITIONAL(NAT_PMP, test "x$natpmp" = "xtrue")
  175. AM_CONDITIONAL(MINIUPNPC, test "x$upnp" = "xtrue")
  176. AM_PROG_CC_C_O
  177. AC_PROG_CC_C99
  178. AC_ARG_VAR([PYTHON], [path to Python binary])
  179. AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
  180. if test "x$PYTHON" = "x"; then
  181. AC_MSG_WARN([Python unavailable; some tests will not be run.])
  182. fi
  183. AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
  184. ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
  185. AC_C_FLEXIBLE_ARRAY_MEMBER
  186. ], [
  187. dnl Maybe we've got an old autoconf...
  188. AC_CACHE_CHECK([for flexible array members],
  189. tor_cv_c_flexarray,
  190. [AC_COMPILE_IFELSE(
  191. AC_LANG_PROGRAM([
  192. struct abc { int a; char b[]; };
  193. ], [
  194. struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
  195. def->b[0] = 33;
  196. ]),
  197. [tor_cv_c_flexarray=yes],
  198. [tor_cv_c_flexarray=no])])
  199. if test "$tor_cv_flexarray" = "yes"; then
  200. AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
  201. else
  202. AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
  203. fi
  204. ])
  205. AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
  206. tor_cv_c_c99_decl,
  207. [AC_COMPILE_IFELSE(
  208. [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
  209. [tor_cv_c_c99_decl=yes],
  210. [tor_cv_c_c99_decl=no] )])
  211. if test "$tor_cv_c_c99_decl" != "yes"; then
  212. AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
  213. fi
  214. AC_CACHE_CHECK([for working C99 designated initializers],
  215. tor_cv_c_c99_designated_init,
  216. [AC_COMPILE_IFELSE(
  217. [AC_LANG_PROGRAM([struct s { int a; int b; };],
  218. [[ struct s ss = { .b = 5, .a = 6 }; ]])],
  219. [tor_cv_c_c99_designated_init=yes],
  220. [tor_cv_c_c99_designated_init=no] )])
  221. if test "$tor_cv_c_c99_designated_init" != "yes"; then
  222. AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
  223. fi
  224. TORUSER=_tor
  225. AC_ARG_WITH(tor-user,
  226. AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
  227. [
  228. TORUSER=$withval
  229. ]
  230. )
  231. AC_SUBST(TORUSER)
  232. TORGROUP=_tor
  233. AC_ARG_WITH(tor-group,
  234. AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
  235. [
  236. TORGROUP=$withval
  237. ]
  238. )
  239. AC_SUBST(TORGROUP)
  240. dnl If _WIN32 is defined and non-zero, we are building for win32
  241. AC_MSG_CHECKING([for win32])
  242. AC_RUN_IFELSE([AC_LANG_SOURCE([
  243. int main(int c, char **v) {
  244. #ifdef _WIN32
  245. #if _WIN32
  246. return 0;
  247. #else
  248. return 1;
  249. #endif
  250. #else
  251. return 2;
  252. #endif
  253. }])],
  254. bwin32=true; AC_MSG_RESULT([yes]),
  255. bwin32=false; AC_MSG_RESULT([no]),
  256. bwin32=cross; AC_MSG_RESULT([cross])
  257. )
  258. if test "$bwin32" = "cross"; then
  259. AC_MSG_CHECKING([for win32 (cross)])
  260. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  261. #ifdef _WIN32
  262. int main(int c, char **v) {return 0;}
  263. #else
  264. #error
  265. int main(int c, char **v) {return x(y);}
  266. #endif
  267. ])],
  268. bwin32=true; AC_MSG_RESULT([yes]),
  269. bwin32=false; AC_MSG_RESULT([no]))
  270. fi
  271. AH_BOTTOM([
  272. #ifdef _WIN32
  273. /* Defined to access windows functions and definitions for >=WinXP */
  274. # ifndef WINVER
  275. # define WINVER 0x0501
  276. # endif
  277. /* Defined to access _other_ windows functions and definitions for >=WinXP */
  278. # ifndef _WIN32_WINNT
  279. # define _WIN32_WINNT 0x0501
  280. # endif
  281. /* Defined to avoid including some windows headers as part of Windows.h */
  282. # ifndef WIN32_LEAN_AND_MEAN
  283. # define WIN32_LEAN_AND_MEAN 1
  284. # endif
  285. #endif
  286. ])
  287. AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
  288. dnl Enable C99 when compiling with MIPSpro
  289. AC_MSG_CHECKING([for MIPSpro compiler])
  290. AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
  291. #if (defined(__sgi) && defined(_COMPILER_VERSION))
  292. #error
  293. return x(y);
  294. #endif
  295. ])],
  296. bmipspro=false; AC_MSG_RESULT(no),
  297. bmipspro=true; AC_MSG_RESULT(yes))
  298. if test "$bmipspro" = "true"; then
  299. CFLAGS="$CFLAGS -c99"
  300. fi
  301. AC_C_BIGENDIAN
  302. AC_SEARCH_LIBS(socket, [socket network])
  303. AC_SEARCH_LIBS(gethostbyname, [nsl])
  304. AC_SEARCH_LIBS(dlopen, [dl])
  305. AC_SEARCH_LIBS(inet_aton, [resolv])
  306. AC_SEARCH_LIBS(backtrace, [execinfo])
  307. saved_LIBS="$LIBS"
  308. AC_SEARCH_LIBS([clock_gettime], [rt])
  309. if test "$LIBS" != "$saved_LIBS"; then
  310. # Looks like we need -lrt for clock_gettime().
  311. have_rt=yes
  312. fi
  313. AC_SEARCH_LIBS(pthread_create, [pthread])
  314. AC_SEARCH_LIBS(pthread_detach, [pthread])
  315. AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
  316. AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
  317. AC_CHECK_FUNCS(
  318. _NSGetEnviron \
  319. RtlSecureZeroMemory \
  320. SecureZeroMemory \
  321. accept4 \
  322. backtrace \
  323. backtrace_symbols_fd \
  324. eventfd \
  325. explicit_bzero \
  326. timingsafe_memcmp \
  327. flock \
  328. ftime \
  329. getaddrinfo \
  330. getifaddrs \
  331. getpass \
  332. getrlimit \
  333. gettimeofday \
  334. gmtime_r \
  335. htonll \
  336. inet_aton \
  337. ioctl \
  338. issetugid \
  339. llround \
  340. localtime_r \
  341. lround \
  342. memmem \
  343. memset_s \
  344. pipe \
  345. pipe2 \
  346. prctl \
  347. readpassphrase \
  348. rint \
  349. sigaction \
  350. socketpair \
  351. statvfs \
  352. strlcat \
  353. strlcpy \
  354. strnlen \
  355. strptime \
  356. strtok_r \
  357. strtoull \
  358. sysconf \
  359. sysctl \
  360. truncate \
  361. uname \
  362. usleep \
  363. vasprintf \
  364. _vscprintf
  365. )
  366. # Apple messed up when they added two functions functions in Sierra: they
  367. # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
  368. # checks. So we should only probe for those functions if we are sure that we
  369. # are not targetting OSX 10.11 or earlier.
  370. AC_MSG_CHECKING([for a pre-Sierra OSX build target])
  371. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  372. #ifdef __APPLE__
  373. # include <AvailabilityMacros.h>
  374. # ifndef MAC_OS_X_VERSION_10_12
  375. # define MAC_OS_X_VERSION_10_12 101200
  376. # endif
  377. # if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
  378. # if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
  379. # error "Running on Mac OSX 10.11 or earlier"
  380. # endif
  381. # endif
  382. #endif
  383. ]], [[]])],
  384. [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
  385. [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
  386. if test "$on_macos_pre_10_12" = "no"; then
  387. AC_CHECK_FUNCS(
  388. clock_gettime \
  389. getentropy \
  390. )
  391. fi
  392. if test "$bwin32" != "true"; then
  393. AC_CHECK_HEADERS(pthread.h)
  394. AC_CHECK_FUNCS(pthread_create)
  395. AC_CHECK_FUNCS(pthread_condattr_setclock)
  396. fi
  397. if test "$bwin32" = "true"; then
  398. AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
  399. #include <windows.h>
  400. #include <conio.h>
  401. #include <wchar.h>
  402. ])
  403. fi
  404. AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
  405. test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
  406. dnl ------------------------------------------------------
  407. dnl Where do you live, libevent? And how do we call you?
  408. if test "$bwin32" = "true"; then
  409. TOR_LIB_WS32=-lws2_32
  410. TOR_LIB_IPHLPAPI=-liphlpapi
  411. # Some of the cargo-cults recommend -lwsock32 as well, but I don't
  412. # think it's actually necessary.
  413. TOR_LIB_GDI=-lgdi32
  414. else
  415. TOR_LIB_WS32=
  416. TOR_LIB_GDI=
  417. fi
  418. AC_SUBST(TOR_LIB_WS32)
  419. AC_SUBST(TOR_LIB_GDI)
  420. AC_SUBST(TOR_LIB_IPHLPAPI)
  421. tor_libevent_pkg_redhat="libevent"
  422. tor_libevent_pkg_debian="libevent-dev"
  423. tor_libevent_devpkg_redhat="libevent-devel"
  424. tor_libevent_devpkg_debian="libevent-dev"
  425. dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
  426. dnl linking for static builds.
  427. STATIC_LIBEVENT_FLAGS=""
  428. if test "$enable_static_libevent" = "yes"; then
  429. if test "$have_rt" = "yes"; then
  430. STATIC_LIBEVENT_FLAGS=" -lrt "
  431. fi
  432. fi
  433. TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
  434. #ifdef _WIN32
  435. #include <winsock2.h>
  436. #endif
  437. #include <sys/time.h>
  438. #include <sys/types.h>
  439. #include <event2/event.h>], [
  440. #ifdef _WIN32
  441. #include <winsock2.h>
  442. #endif
  443. void *event_init(void);],
  444. [
  445. #ifdef _WIN32
  446. {WSADATA d; WSAStartup(0x101,&d); }
  447. #endif
  448. event_init();
  449. ], [--with-libevent-dir], [/opt/libevent])
  450. dnl Determine the incantation needed to link libevent.
  451. save_LIBS="$LIBS"
  452. save_LDFLAGS="$LDFLAGS"
  453. save_CPPFLAGS="$CPPFLAGS"
  454. LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
  455. LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
  456. CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
  457. AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
  458. if test "$enable_static_libevent" = "yes"; then
  459. if test "$tor_cv_library_libevent_dir" = "(system)"; then
  460. AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
  461. else
  462. TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
  463. fi
  464. else
  465. if test "x$ac_cv_header_event2_event_h" = "xyes"; then
  466. AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
  467. AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
  468. if test "$ac_cv_search_event_new" != "none required"; then
  469. TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
  470. fi
  471. if test "$ac_cv_search_evdns_base_new" != "none required"; then
  472. TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
  473. fi
  474. else
  475. AC_MSG_ERROR("libevent2 is required but the headers could not be found")
  476. fi
  477. fi
  478. dnl Now check for particular libevent functions.
  479. AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
  480. evutil_secure_rng_add_bytes \
  481. ])
  482. LIBS="$save_LIBS"
  483. LDFLAGS="$save_LDFLAGS"
  484. CPPFLAGS="$save_CPPFLAGS"
  485. dnl Check that libevent is at least at version 2.0.10, the first stable
  486. dnl release of its series
  487. CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
  488. AC_MSG_CHECKING([whether Libevent is new enough])
  489. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  490. #include <event2/event.h>
  491. #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
  492. #error
  493. int x = y(zz);
  494. #else
  495. int x = 1;
  496. #endif
  497. ])], [ AC_MSG_RESULT([yes]) ],
  498. [ AC_MSG_RESULT([no])
  499. AC_MSG_ERROR([Libevent is not new enough. We require 2.0.10-stable or later]) ] )
  500. LIBS="$save_LIBS"
  501. LDFLAGS="$save_LDFLAGS"
  502. CPPFLAGS="$save_CPPFLAGS"
  503. AC_SUBST(TOR_LIBEVENT_LIBS)
  504. dnl ------------------------------------------------------
  505. dnl Where do you live, libm?
  506. dnl On some platforms (Haiku/BeOS) the math library is
  507. dnl part of libroot. In which case don't link against lm
  508. TOR_LIB_MATH=""
  509. save_LIBS="$LIBS"
  510. AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
  511. if test "$ac_cv_search_pow" != "none required"; then
  512. TOR_LIB_MATH="$ac_cv_search_pow"
  513. fi
  514. LIBS="$save_LIBS"
  515. AC_SUBST(TOR_LIB_MATH)
  516. dnl ------------------------------------------------------
  517. dnl Where do you live, openssl? And how do we call you?
  518. tor_openssl_pkg_redhat="openssl"
  519. tor_openssl_pkg_debian="libssl-dev"
  520. tor_openssl_devpkg_redhat="openssl-devel"
  521. tor_openssl_devpkg_debian="libssl-dev"
  522. ALT_openssl_WITHVAL=""
  523. AC_ARG_WITH(ssl-dir,
  524. AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
  525. [
  526. if test "x$withval" != "xno" && test "x$withval" != "x"; then
  527. ALT_openssl_WITHVAL="$withval"
  528. fi
  529. ])
  530. TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI],
  531. [#include <openssl/rand.h>],
  532. [void RAND_add(const void *buf, int num, double entropy);],
  533. [RAND_add((void*)0,0,0);], [],
  534. [/usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /opt/openssl])
  535. dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
  536. if test "$enable_static_openssl" = "yes"; then
  537. if test "$tor_cv_library_openssl_dir" = "(system)"; then
  538. AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
  539. else
  540. TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
  541. fi
  542. else
  543. TOR_OPENSSL_LIBS="-lssl -lcrypto"
  544. fi
  545. AC_SUBST(TOR_OPENSSL_LIBS)
  546. dnl Now check for particular openssl functions.
  547. save_LIBS="$LIBS"
  548. save_LDFLAGS="$LDFLAGS"
  549. save_CPPFLAGS="$CPPFLAGS"
  550. LIBS="$TOR_OPENSSL_LIBS $LIBS"
  551. LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
  552. CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
  553. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  554. #include <openssl/opensslv.h>
  555. #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
  556. #error "too old"
  557. #endif
  558. ]], [[]])],
  559. [ : ],
  560. [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
  561. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  562. #include <openssl/opensslv.h>
  563. #include <openssl/evp.h>
  564. #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
  565. #error "no ECC"
  566. #endif
  567. #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
  568. #error "curves unavailable"
  569. #endif
  570. ]], [[]])],
  571. [ : ],
  572. [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
  573. AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
  574. [#include <openssl/ssl.h>
  575. ])
  576. AC_CHECK_FUNCS([ \
  577. SSL_SESSION_get_master_key \
  578. SSL_get_server_random \
  579. SSL_get_client_ciphers \
  580. SSL_get_client_random \
  581. SSL_CIPHER_find \
  582. TLS_method
  583. ])
  584. dnl Check if OpenSSL has scrypt implementation.
  585. AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
  586. LIBS="$save_LIBS"
  587. LDFLAGS="$save_LDFLAGS"
  588. CPPFLAGS="$save_CPPFLAGS"
  589. dnl ------------------------------------------------------
  590. dnl Where do you live, zlib? And how do we call you?
  591. tor_zlib_pkg_redhat="zlib"
  592. tor_zlib_pkg_debian="zlib1g"
  593. tor_zlib_devpkg_redhat="zlib-devel"
  594. tor_zlib_devpkg_debian="zlib1g-dev"
  595. TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
  596. [#include <zlib.h>],
  597. [const char * zlibVersion(void);],
  598. [zlibVersion();], [--with-zlib-dir],
  599. [/opt/zlib])
  600. if test "$enable_static_zlib" = "yes"; then
  601. if test "$tor_cv_library_zlib_dir" = "(system)"; then
  602. AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
  603. using --enable-static-zlib")
  604. else
  605. TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
  606. fi
  607. else
  608. TOR_ZLIB_LIBS="-lz"
  609. fi
  610. AC_SUBST(TOR_ZLIB_LIBS)
  611. dnl ----------------------------------------------------------------------
  612. dnl Check if libcap is available for capabilities.
  613. tor_cap_pkg_debian="libcap2"
  614. tor_cap_pkg_redhat="libcap"
  615. tor_cap_devpkg_debian="libcap-dev"
  616. tor_cap_devpkg_redhat="libcap-devel"
  617. AC_CHECK_LIB([cap], [cap_init], [],
  618. AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
  619. )
  620. AC_CHECK_FUNCS(cap_set_proc)
  621. dnl ---------------------------------------------------------------------
  622. dnl Now that we know about our major libraries, we can check for compiler
  623. dnl and linker hardening options. We need to do this with the libraries known,
  624. dnl since sometimes the linker will like an option but not be willing to
  625. dnl use it with a build of a library.
  626. all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
  627. all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_CAP_LIBS"
  628. CFLAGS_FTRAPV=
  629. CFLAGS_FWRAPV=
  630. CFLAGS_ASAN=
  631. CFLAGS_UBSAN=
  632. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
  633. #if !defined(__clang__)
  634. #error
  635. #endif])], have_clang=yes, have_clang=no)
  636. if test "x$enable_gcc_hardening" != "xno"; then
  637. CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
  638. if test "x$have_clang" = "xyes"; then
  639. TOR_CHECK_CFLAGS(-Qunused-arguments)
  640. fi
  641. TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
  642. AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
  643. AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
  644. m4_ifdef([AS_VAR_IF],[
  645. AS_VAR_IF(can_compile, [yes],
  646. AS_VAR_IF(can_link, [yes],
  647. [],
  648. AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
  649. )])
  650. AS_VAR_POPDEF([can_link])
  651. AS_VAR_POPDEF([can_compile])
  652. TOR_CHECK_CFLAGS(-Wstack-protector)
  653. TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
  654. if test "$bwin32" = "false"; then
  655. TOR_CHECK_CFLAGS(-fPIE)
  656. TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
  657. fi
  658. TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
  659. TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
  660. if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
  661. AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
  662. fi
  663. fi
  664. if test "x$enable_expensive_hardening" = "xyes"; then
  665. if test "$tor_cv_cflags__ftrapv" != "yes"; then
  666. AC_MSG_ERROR([You requested expensive hardening, but the compiler does not seem to support -ftrapv.])
  667. fi
  668. TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
  669. if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
  670. AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.so, and with Clang you need libclang_rt.ubsan*])
  671. fi
  672. TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
  673. if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
  674. AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.so, and with Clang you need libclang_rt.ubsan*])
  675. fi
  676. TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
  677. fi
  678. CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
  679. CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
  680. mulodi_fixes_ftrapv=no
  681. if test "$have_clang" = "yes"; then
  682. saved_CFLAGS="$CFLAGS"
  683. CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
  684. AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
  685. AC_LINK_IFELSE([
  686. AC_LANG_SOURCE([[
  687. #include <stdint.h>
  688. #include <stdlib.h>
  689. int main(int argc, char **argv)
  690. {
  691. int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
  692. * (int64_t)atoi(argv[3]);
  693. return x == 9;
  694. } ]])],
  695. [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
  696. [ftrapv_can_link=no; AC_MSG_RESULT([no])])
  697. if test "$ftrapv_can_link" = "no"; then
  698. AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
  699. AC_LINK_IFELSE([
  700. AC_LANG_SOURCE([[
  701. #include <stdint.h>
  702. #include <stdlib.h>
  703. int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
  704. *overflow=0;
  705. return a;
  706. }
  707. int main(int argc, char **argv)
  708. {
  709. int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
  710. * (int64_t)atoi(argv[3]);
  711. return x == 9;
  712. } ]])],
  713. [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
  714. [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
  715. fi
  716. CFLAGS="$saved_CFLAGS"
  717. fi
  718. AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
  719. dnl These cflags add bunches of branches, and we haven't been able to
  720. dnl persuade ourselves that they're suitable for code that needs to be
  721. dnl constant time.
  722. AC_SUBST(CFLAGS_BUGTRAP)
  723. dnl These cflags are variant ones sutable for code that needs to be
  724. dnl constant-time.
  725. AC_SUBST(CFLAGS_CONSTTIME)
  726. if test "x$enable_linker_hardening" != "xno"; then
  727. TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
  728. fi
  729. # For backtrace support
  730. TOR_CHECK_LDFLAGS(-rdynamic)
  731. dnl ------------------------------------------------------
  732. dnl Now see if we have a -fomit-frame-pointer compiler option.
  733. saved_CFLAGS="$CFLAGS"
  734. TOR_CHECK_CFLAGS(-fomit-frame-pointer)
  735. F_OMIT_FRAME_POINTER=''
  736. if test "$saved_CFLAGS" != "$CFLAGS"; then
  737. if test "x$enable_expensive_hardening" != "xyes"; then
  738. F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
  739. fi
  740. fi
  741. CFLAGS="$saved_CFLAGS"
  742. AC_SUBST(F_OMIT_FRAME_POINTER)
  743. dnl ------------------------------------------------------
  744. dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
  745. dnl for us, as GCC 4.6 and later do at many optimization levels), then
  746. dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
  747. dnl code will work.
  748. TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
  749. dnl ============================================================
  750. dnl Check for libseccomp
  751. if test "x$enable_seccomp" != "xno"; then
  752. AC_CHECK_HEADERS([seccomp.h])
  753. AC_SEARCH_LIBS(seccomp_init, [seccomp])
  754. fi
  755. dnl ============================================================
  756. dnl Check for libscrypt
  757. if test "x$enable_libscrypt" != "xno"; then
  758. AC_CHECK_HEADERS([libscrypt.h])
  759. AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
  760. AC_CHECK_FUNCS([libscrypt_scrypt])
  761. fi
  762. dnl ============================================================
  763. dnl We need an implementation of curve25519.
  764. dnl set these defaults.
  765. build_curve25519_donna=no
  766. build_curve25519_donna_c64=no
  767. use_curve25519_donna=no
  768. use_curve25519_nacl=no
  769. CURVE25519_LIBS=
  770. dnl The best choice is using curve25519-donna-c64, but that requires
  771. dnl that we
  772. AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
  773. tor_cv_can_use_curve25519_donna_c64,
  774. [AC_RUN_IFELSE(
  775. [AC_LANG_PROGRAM([dnl
  776. #include <stdint.h>
  777. typedef unsigned uint128_t __attribute__((mode(TI)));
  778. int func(uint64_t a, uint64_t b) {
  779. uint128_t c = ((uint128_t)a) * b;
  780. int ok = ((uint64_t)(c>>96)) == 522859 &&
  781. (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
  782. (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
  783. (((uint64_t)(c))&0xffffffffL) == 0;
  784. return ok;
  785. }
  786. ], [dnl
  787. int ok = func( ((uint64_t)2000000000) * 1000000000,
  788. ((uint64_t)1234567890) << 24);
  789. return !ok;
  790. ])],
  791. [tor_cv_can_use_curve25519_donna_c64=yes],
  792. [tor_cv_can_use_curve25519_donna_c64=no],
  793. [AC_LINK_IFELSE(
  794. [AC_LANG_PROGRAM([dnl
  795. #include <stdint.h>
  796. typedef unsigned uint128_t __attribute__((mode(TI)));
  797. int func(uint64_t a, uint64_t b) {
  798. uint128_t c = ((uint128_t)a) * b;
  799. int ok = ((uint64_t)(c>>96)) == 522859 &&
  800. (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
  801. (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
  802. (((uint64_t)(c))&0xffffffffL) == 0;
  803. return ok;
  804. }
  805. ], [dnl
  806. int ok = func( ((uint64_t)2000000000) * 1000000000,
  807. ((uint64_t)1234567890) << 24);
  808. return !ok;
  809. ])],
  810. [tor_cv_can_use_curve25519_donna_c64=cross],
  811. [tor_cv_can_use_curve25519_donna_c64=no])])])
  812. AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
  813. nacl/crypto_scalarmult_curve25519.h])
  814. AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
  815. tor_cv_can_use_curve25519_nacl,
  816. [tor_saved_LIBS="$LIBS"
  817. LIBS="$LIBS -lnacl"
  818. AC_LINK_IFELSE(
  819. [AC_LANG_PROGRAM([dnl
  820. #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
  821. #include <crypto_scalarmult_curve25519.h>
  822. #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
  823. #include <nacl/crypto_scalarmult_curve25519.h>
  824. #endif
  825. #ifdef crypto_scalarmult_curve25519_ref_BYTES
  826. #error Hey, this is the reference implementation! That's not fast.
  827. #endif
  828. ], [
  829. unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
  830. ])], [tor_cv_can_use_curve25519_nacl=yes],
  831. [tor_cv_can_use_curve25519_nacl=no])
  832. LIBS="$tor_saved_LIBS" ])
  833. dnl Okay, now we need to figure out which one to actually use. Fall back
  834. dnl to curve25519-donna.c
  835. if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
  836. build_curve25519_donna_c64=yes
  837. use_curve25519_donna=yes
  838. elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
  839. use_curve25519_nacl=yes
  840. CURVE25519_LIBS=-lnacl
  841. else
  842. build_curve25519_donna=yes
  843. use_curve25519_donna=yes
  844. fi
  845. if test "x$use_curve25519_donna" = "xyes"; then
  846. AC_DEFINE(USE_CURVE25519_DONNA, 1,
  847. [Defined if we should use an internal curve25519_donna{,_c64} implementation])
  848. fi
  849. if test "x$use_curve25519_nacl" = "xyes"; then
  850. AC_DEFINE(USE_CURVE25519_NACL, 1,
  851. [Defined if we should use a curve25519 from nacl])
  852. fi
  853. AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
  854. test "x$build_curve25519_donna" = "xyes")
  855. AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
  856. test "x$build_curve25519_donna_c64" = "xyes")
  857. AC_SUBST(CURVE25519_LIBS)
  858. dnl Make sure to enable support for large off_t if available.
  859. AC_SYS_LARGEFILE
  860. AC_CHECK_HEADERS([assert.h \
  861. errno.h \
  862. fcntl.h \
  863. signal.h \
  864. string.h \
  865. sys/capability.h \
  866. sys/fcntl.h \
  867. sys/stat.h \
  868. sys/time.h \
  869. sys/types.h \
  870. time.h \
  871. unistd.h \
  872. arpa/inet.h \
  873. crt_externs.h \
  874. execinfo.h \
  875. grp.h \
  876. ifaddrs.h \
  877. inttypes.h \
  878. limits.h \
  879. linux/types.h \
  880. machine/limits.h \
  881. malloc.h \
  882. malloc/malloc.h \
  883. malloc_np.h \
  884. netdb.h \
  885. netinet/in.h \
  886. netinet/in6.h \
  887. pwd.h \
  888. readpassphrase.h \
  889. stdint.h \
  890. sys/eventfd.h \
  891. sys/file.h \
  892. sys/ioctl.h \
  893. sys/limits.h \
  894. sys/mman.h \
  895. sys/param.h \
  896. sys/prctl.h \
  897. sys/random.h \
  898. sys/resource.h \
  899. sys/select.h \
  900. sys/socket.h \
  901. sys/statvfs.h \
  902. sys/syscall.h \
  903. sys/sysctl.h \
  904. sys/syslimits.h \
  905. sys/time.h \
  906. sys/types.h \
  907. sys/un.h \
  908. sys/utime.h \
  909. sys/wait.h \
  910. syslog.h \
  911. utime.h])
  912. AC_CHECK_HEADERS(sys/param.h)
  913. AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
  914. [#ifdef HAVE_SYS_TYPES_H
  915. #include <sys/types.h>
  916. #endif
  917. #ifdef HAVE_SYS_SOCKET_H
  918. #include <sys/socket.h>
  919. #endif])
  920. AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
  921. [#ifdef HAVE_SYS_TYPES_H
  922. #include <sys/types.h>
  923. #endif
  924. #ifdef HAVE_SYS_SOCKET_H
  925. #include <sys/socket.h>
  926. #endif
  927. #ifdef HAVE_NET_IF_H
  928. #include <net/if.h>
  929. #endif
  930. #ifdef HAVE_NETINET_IN_H
  931. #include <netinet/in.h>
  932. #endif])
  933. AC_CHECK_HEADERS(linux/if.h,[],[],
  934. [
  935. #ifdef HAVE_SYS_SOCKET_H
  936. #include <sys/socket.h>
  937. #endif
  938. ])
  939. AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
  940. linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
  941. [#ifdef HAVE_SYS_TYPES_H
  942. #include <sys/types.h>
  943. #endif
  944. #ifdef HAVE_SYS_SOCKET_H
  945. #include <sys/socket.h>
  946. #endif
  947. #ifdef HAVE_LIMITS_H
  948. #include <limits.h>
  949. #endif
  950. #ifdef HAVE_LINUX_TYPES_H
  951. #include <linux/types.h>
  952. #endif
  953. #ifdef HAVE_NETINET_IN6_H
  954. #include <netinet/in6.h>
  955. #endif
  956. #ifdef HAVE_NETINET_IN_H
  957. #include <netinet/in.h>
  958. #endif])
  959. AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
  960. linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
  961. [#ifdef HAVE_SYS_TYPES_H
  962. #include <sys/types.h>
  963. #endif
  964. #ifdef HAVE_SYS_SOCKET_H
  965. #include <sys/socket.h>
  966. #endif
  967. #ifdef HAVE_LIMITS_H
  968. #include <limits.h>
  969. #endif
  970. #ifdef HAVE_LINUX_TYPES_H
  971. #include <linux/types.h>
  972. #endif
  973. #ifdef HAVE_NETINET_IN6_H
  974. #include <netinet/in6.h>
  975. #endif
  976. #ifdef HAVE_NETINET_IN_H
  977. #include <netinet/in.h>
  978. #endif
  979. #ifdef HAVE_LINUX_IF_H
  980. #include <linux/if.h>
  981. #endif])
  982. transparent_ok=0
  983. if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
  984. transparent_ok=1
  985. fi
  986. if test "x$linux_netfilter_ipv4" = "x1"; then
  987. transparent_ok=1
  988. fi
  989. if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
  990. transparent_ok=1
  991. fi
  992. if test "x$transparent_ok" = "x1"; then
  993. AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
  994. case "$host" in
  995. *-*-openbsd* | *-*-bitrig*)
  996. AC_DEFINE(OPENBSD, 1, "Define to handle pf on OpenBSD properly") ;;
  997. esac
  998. else
  999. AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
  1000. fi
  1001. AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
  1002. [#ifdef HAVE_SYS_TYPES_H
  1003. #include <sys/types.h>
  1004. #endif
  1005. #ifdef HAVE_SYS_TIME_H
  1006. #include <sys/time.h>
  1007. #endif])
  1008. dnl In case we aren't given a working stdint.h, we'll need to grow our own.
  1009. dnl Watch out.
  1010. AC_CHECK_SIZEOF(int8_t)
  1011. AC_CHECK_SIZEOF(int16_t)
  1012. AC_CHECK_SIZEOF(int32_t)
  1013. AC_CHECK_SIZEOF(int64_t)
  1014. AC_CHECK_SIZEOF(uint8_t)
  1015. AC_CHECK_SIZEOF(uint16_t)
  1016. AC_CHECK_SIZEOF(uint32_t)
  1017. AC_CHECK_SIZEOF(uint64_t)
  1018. AC_CHECK_SIZEOF(intptr_t)
  1019. AC_CHECK_SIZEOF(uintptr_t)
  1020. dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
  1021. AC_CHECK_SIZEOF(char)
  1022. AC_CHECK_SIZEOF(short)
  1023. AC_CHECK_SIZEOF(int)
  1024. AC_CHECK_SIZEOF(long)
  1025. AC_CHECK_SIZEOF(long long)
  1026. AC_CHECK_SIZEOF(__int64)
  1027. AC_CHECK_SIZEOF(void *)
  1028. AC_CHECK_SIZEOF(time_t)
  1029. AC_CHECK_SIZEOF(size_t)
  1030. AC_CHECK_SIZEOF(pid_t)
  1031. AC_CHECK_TYPES([uint, u_char, ssize_t])
  1032. AC_PC_FROM_UCONTEXT([:])
  1033. dnl used to include sockaddr_storage, but everybody has that.
  1034. AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
  1035. [#ifdef HAVE_SYS_TYPES_H
  1036. #include <sys/types.h>
  1037. #endif
  1038. #ifdef HAVE_NETINET_IN_H
  1039. #include <netinet/in.h>
  1040. #endif
  1041. #ifdef HAVE_NETINET_IN6_H
  1042. #include <netinet/in6.h>
  1043. #endif
  1044. #ifdef HAVE_SYS_SOCKET_H
  1045. #include <sys/socket.h>
  1046. #endif
  1047. #ifdef _WIN32
  1048. #define _WIN32_WINNT 0x0501
  1049. #define WIN32_LEAN_AND_MEAN
  1050. #include <winsock2.h>
  1051. #include <ws2tcpip.h>
  1052. #endif
  1053. ])
  1054. AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
  1055. [#ifdef HAVE_SYS_TYPES_H
  1056. #include <sys/types.h>
  1057. #endif
  1058. #ifdef HAVE_NETINET_IN_H
  1059. #include <netinet/in.h>
  1060. #endif
  1061. #ifdef HAVE_NETINET_IN6_H
  1062. #include <netinet/in6.h>
  1063. #endif
  1064. #ifdef HAVE_SYS_SOCKET_H
  1065. #include <sys/socket.h>
  1066. #endif
  1067. #ifdef _WIN32
  1068. #define _WIN32_WINNT 0x0501
  1069. #define WIN32_LEAN_AND_MEAN
  1070. #include <winsock2.h>
  1071. #include <ws2tcpip.h>
  1072. #endif
  1073. ])
  1074. AC_CHECK_TYPES([rlim_t], , ,
  1075. [#ifdef HAVE_SYS_TYPES_H
  1076. #include <sys/types.h>
  1077. #endif
  1078. #ifdef HAVE_SYS_TIME_H
  1079. #include <sys/time.h>
  1080. #endif
  1081. #ifdef HAVE_SYS_RESOURCE_H
  1082. #include <sys/resource.h>
  1083. #endif
  1084. ])
  1085. AX_CHECK_SIGN([time_t],
  1086. [ : ],
  1087. [ : ], [
  1088. #ifdef HAVE_SYS_TYPES_H
  1089. #include <sys/types.h>
  1090. #endif
  1091. #ifdef HAVE_SYS_TIME_H
  1092. #include <sys/time.h>
  1093. #endif
  1094. #ifdef HAVE_TIME_H
  1095. #include <time.h>
  1096. #endif
  1097. ])
  1098. if test "$ax_cv_decl_time_t_signed" = "no"; then
  1099. AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
  1100. fi
  1101. AX_CHECK_SIGN([size_t],
  1102. [ tor_cv_size_t_signed=yes ],
  1103. [ tor_cv_size_t_signed=no ], [
  1104. #ifdef HAVE_SYS_TYPES_H
  1105. #include <sys/types.h>
  1106. #endif
  1107. ])
  1108. if test "$ax_cv_decl_size_t_signed" = "yes"; then
  1109. AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
  1110. fi
  1111. AX_CHECK_SIGN([enum always],
  1112. [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
  1113. [ : ], [
  1114. enum always { AAA, BBB, CCC };
  1115. ])
  1116. AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
  1117. #ifdef HAVE_SYS_SOCKET_H
  1118. #include <sys/socket.h>
  1119. #endif
  1120. ])
  1121. # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
  1122. AC_CHECK_SIZEOF(cell_t)
  1123. # Now make sure that NULL can be represented as zero bytes.
  1124. AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
  1125. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1126. [[#include <stdlib.h>
  1127. #include <string.h>
  1128. #include <stdio.h>
  1129. #ifdef HAVE_STDDEF_H
  1130. #include <stddef.h>
  1131. #endif
  1132. int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
  1133. return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
  1134. [tor_cv_null_is_zero=yes],
  1135. [tor_cv_null_is_zero=no],
  1136. [tor_cv_null_is_zero=cross])])
  1137. if test "$tor_cv_null_is_zero" = "cross"; then
  1138. # Cross-compiling; let's hope that the target isn't raving mad.
  1139. AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
  1140. fi
  1141. if test "$tor_cv_null_is_zero" != "no"; then
  1142. AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
  1143. [Define to 1 iff memset(0) sets pointers to NULL])
  1144. fi
  1145. AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
  1146. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1147. [[#include <stdlib.h>
  1148. #include <string.h>
  1149. #include <stdio.h>
  1150. #ifdef HAVE_STDDEF_H
  1151. #include <stddef.h>
  1152. #endif
  1153. int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
  1154. return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
  1155. [tor_cv_dbl0_is_zero=yes],
  1156. [tor_cv_dbl0_is_zero=no],
  1157. [tor_cv_dbl0_is_zero=cross])])
  1158. if test "$tor_cv_dbl0_is_zero" = "cross"; then
  1159. # Cross-compiling; let's hope that the target isn't raving mad.
  1160. AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
  1161. fi
  1162. if test "$tor_cv_dbl0_is_zero" != "no"; then
  1163. AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
  1164. [Define to 1 iff memset(0) sets doubles to 0.0])
  1165. fi
  1166. # And what happens when we malloc zero?
  1167. AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
  1168. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1169. [[#include <stdlib.h>
  1170. #include <string.h>
  1171. #include <stdio.h>
  1172. #ifdef HAVE_STDDEF_H
  1173. #include <stddef.h>
  1174. #endif
  1175. int main () { return malloc(0)?0:1; }]])],
  1176. [tor_cv_malloc_zero_works=yes],
  1177. [tor_cv_malloc_zero_works=no],
  1178. [tor_cv_malloc_zero_works=cross])])
  1179. if test "$tor_cv_malloc_zero_works" = "cross"; then
  1180. # Cross-compiling; let's hope that the target isn't raving mad.
  1181. AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
  1182. fi
  1183. if test "$tor_cv_malloc_zero_works" = "yes"; then
  1184. AC_DEFINE([MALLOC_ZERO_WORKS], 1,
  1185. [Define to 1 iff malloc(0) returns a pointer])
  1186. fi
  1187. # whether we seem to be in a 2s-complement world.
  1188. AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
  1189. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1190. [[int main () { int problem = ((-99) != (~99)+1);
  1191. return problem ? 1 : 0; }]])],
  1192. [tor_cv_twos_complement=yes],
  1193. [tor_cv_twos_complement=no],
  1194. [tor_cv_twos_complement=cross])])
  1195. if test "$tor_cv_twos_complement" = "cross"; then
  1196. # Cross-compiling; let's hope that the target isn't raving mad.
  1197. AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
  1198. fi
  1199. if test "$tor_cv_twos_complement" != "no"; then
  1200. AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
  1201. [Define to 1 iff we represent negative integers with
  1202. two's complement])
  1203. fi
  1204. # What does shifting a negative value do?
  1205. AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
  1206. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1207. [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
  1208. [tor_cv_sign_extend=yes],
  1209. [tor_cv_sign_extend=no],
  1210. [tor_cv_sign_extend=cross])])
  1211. if test "$tor_cv_sign_extend" = "cross"; then
  1212. # Cross-compiling; let's hope that the target isn't raving mad.
  1213. AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
  1214. fi
  1215. if test "$tor_cv_sign_extend" != "no"; then
  1216. AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
  1217. [Define to 1 iff right-shifting a negative value performs sign-extension])
  1218. fi
  1219. # Whether we should use the dmalloc memory allocation debugging library.
  1220. AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
  1221. AC_ARG_WITH(dmalloc,
  1222. AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
  1223. [if [[ "$withval" = "yes" ]]; then
  1224. dmalloc=1
  1225. AC_MSG_RESULT(yes)
  1226. else
  1227. dmalloc=1
  1228. AC_MSG_RESULT(no)
  1229. fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
  1230. )
  1231. if [[ $dmalloc -eq 1 ]]; then
  1232. AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
  1233. AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
  1234. AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
  1235. AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
  1236. fi
  1237. AC_ARG_WITH(tcmalloc,
  1238. AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
  1239. [ tcmalloc=yes ], [ tcmalloc=no ])
  1240. if test "x$tcmalloc" = "xyes"; then
  1241. LDFLAGS="-ltcmalloc $LDFLAGS"
  1242. fi
  1243. using_custom_malloc=no
  1244. if test "x$enable_openbsd_malloc" = "xyes"; then
  1245. using_custom_malloc=yes
  1246. fi
  1247. if test "x$tcmalloc" = "xyes"; then
  1248. using_custom_malloc=yes
  1249. fi
  1250. if test "$using_custom_malloc" = "no"; then
  1251. AC_CHECK_FUNCS(mallinfo)
  1252. fi
  1253. # By default, we're going to assume we don't have mlockall()
  1254. # bionic and other platforms have various broken mlockall subsystems.
  1255. # Some systems don't have a working mlockall, some aren't linkable,
  1256. # and some have it but don't declare it.
  1257. AC_CHECK_FUNCS(mlockall)
  1258. AC_CHECK_DECLS([mlockall], , , [
  1259. #ifdef HAVE_SYS_MMAN_H
  1260. #include <sys/mman.h>
  1261. #endif])
  1262. # Some MinGW environments don't have getpagesize in unistd.h. We don't use
  1263. # AC_CHECK_FUNCS(getpagesize), because other environments rename getpagesize
  1264. # using macros
  1265. AC_CHECK_DECLS([getpagesize], , , [
  1266. #ifdef HAVE_UNISTD_H
  1267. #include <unistd.h>
  1268. #endif])
  1269. # Allow user to specify an alternate syslog facility
  1270. AC_ARG_WITH(syslog-facility,
  1271. AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
  1272. syslog_facility="$withval", syslog_facility="LOG_DAEMON")
  1273. AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
  1274. AC_SUBST(LOGFACILITY)
  1275. # Check if we have getresuid and getresgid
  1276. AC_CHECK_FUNCS(getresuid getresgid)
  1277. # Check for gethostbyname_r in all its glorious incompatible versions.
  1278. # (This logic is based on that in Python's configure.in)
  1279. AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
  1280. [Define this if you have any gethostbyname_r()])
  1281. AC_CHECK_FUNC(gethostbyname_r, [
  1282. AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
  1283. OLD_CFLAGS=$CFLAGS
  1284. CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
  1285. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  1286. #include <netdb.h>
  1287. ]], [[
  1288. char *cp1, *cp2;
  1289. struct hostent *h1, *h2;
  1290. int i1, i2;
  1291. (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
  1292. ]])],[
  1293. AC_DEFINE(HAVE_GETHOSTBYNAME_R)
  1294. AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
  1295. [Define this if gethostbyname_r takes 6 arguments])
  1296. AC_MSG_RESULT(6)
  1297. ], [
  1298. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  1299. #include <netdb.h>
  1300. ]], [[
  1301. char *cp1, *cp2;
  1302. struct hostent *h1;
  1303. int i1, i2;
  1304. (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
  1305. ]])], [
  1306. AC_DEFINE(HAVE_GETHOSTBYNAME_R)
  1307. AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
  1308. [Define this if gethostbyname_r takes 5 arguments])
  1309. AC_MSG_RESULT(5)
  1310. ], [
  1311. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  1312. #include <netdb.h>
  1313. ]], [[
  1314. char *cp1;
  1315. struct hostent *h1;
  1316. struct hostent_data hd;
  1317. (void) gethostbyname_r(cp1,h1,&hd);
  1318. ]])], [
  1319. AC_DEFINE(HAVE_GETHOSTBYNAME_R)
  1320. AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
  1321. [Define this if gethostbyname_r takes 3 arguments])
  1322. AC_MSG_RESULT(3)
  1323. ], [
  1324. AC_MSG_RESULT(0)
  1325. ])
  1326. ])
  1327. ])
  1328. CFLAGS=$OLD_CFLAGS
  1329. ])
  1330. AC_CACHE_CHECK([whether the C compiler supports __func__],
  1331. tor_cv_have_func_macro,
  1332. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  1333. #include <stdio.h>
  1334. int main(int c, char **v) { puts(__func__); }])],
  1335. tor_cv_have_func_macro=yes,
  1336. tor_cv_have_func_macro=no))
  1337. AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
  1338. tor_cv_have_FUNC_macro,
  1339. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  1340. #include <stdio.h>
  1341. int main(int c, char **v) { puts(__FUNC__); }])],
  1342. tor_cv_have_FUNC_macro=yes,
  1343. tor_cv_have_FUNC_macro=no))
  1344. AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
  1345. tor_cv_have_FUNCTION_macro,
  1346. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  1347. #include <stdio.h>
  1348. int main(int c, char **v) { puts(__FUNCTION__); }])],
  1349. tor_cv_have_FUNCTION_macro=yes,
  1350. tor_cv_have_FUNCTION_macro=no))
  1351. AC_CACHE_CHECK([whether we have extern char **environ already declared],
  1352. tor_cv_have_environ_declared,
  1353. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  1354. #ifdef HAVE_UNISTD_H
  1355. #include <unistd.h>
  1356. #endif
  1357. #include <stdlib.h>
  1358. int main(int c, char **v) { char **t = environ; }])],
  1359. tor_cv_have_environ_declared=yes,
  1360. tor_cv_have_environ_declared=no))
  1361. if test "$tor_cv_have_func_macro" = "yes"; then
  1362. AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
  1363. fi
  1364. if test "$tor_cv_have_FUNC_macro" = "yes"; then
  1365. AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
  1366. fi
  1367. if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
  1368. AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
  1369. [Defined if the compiler supports __FUNCTION__])
  1370. fi
  1371. if test "$tor_cv_have_environ_declared" = "yes"; then
  1372. AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
  1373. [Defined if we have extern char **environ already declared])
  1374. fi
  1375. # $prefix stores the value of the --prefix command line option, or
  1376. # NONE if the option wasn't set. In the case that it wasn't set, make
  1377. # it be the default, so that we can use it to expand directories now.
  1378. if test "x$prefix" = "xNONE"; then
  1379. prefix=$ac_default_prefix
  1380. fi
  1381. # and similarly for $exec_prefix
  1382. if test "x$exec_prefix" = "xNONE"; then
  1383. exec_prefix=$prefix
  1384. fi
  1385. if test "x$BUILDDIR" = "x"; then
  1386. BUILDDIR=`pwd`
  1387. fi
  1388. AC_SUBST(BUILDDIR)
  1389. AH_TEMPLATE([BUILDDIR],[tor's build directory])
  1390. AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
  1391. if test "x$CONFDIR" = "x"; then
  1392. CONFDIR=`eval echo $sysconfdir/tor`
  1393. fi
  1394. AC_SUBST(CONFDIR)
  1395. AH_TEMPLATE([CONFDIR],[tor's configuration directory])
  1396. AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
  1397. BINDIR=`eval echo $bindir`
  1398. AC_SUBST(BINDIR)
  1399. LOCALSTATEDIR=`eval echo $localstatedir`
  1400. AC_SUBST(LOCALSTATEDIR)
  1401. if test "$bwin32" = "true"; then
  1402. # Test if the linker supports the --nxcompat and --dynamicbase options
  1403. # for Windows
  1404. save_LDFLAGS="$LDFLAGS"
  1405. LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
  1406. AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
  1407. AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
  1408. [AC_MSG_RESULT([yes])]
  1409. [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
  1410. [AC_MSG_RESULT([no])]
  1411. )
  1412. LDFLAGS="$save_LDFLAGS"
  1413. fi
  1414. # Set CFLAGS _after_ all the above checks, since our warnings are stricter
  1415. # than autoconf's macros like.
  1416. if test "$GCC" = "yes"; then
  1417. # Disable GCC's strict aliasing checks. They are an hours-to-debug
  1418. # accident waiting to happen.
  1419. CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
  1420. else
  1421. # Override optimization level for non-gcc compilers
  1422. CFLAGS="$CFLAGS -O"
  1423. enable_gcc_warnings=no
  1424. enable_gcc_warnings_advisory=no
  1425. fi
  1426. # Warnings implies advisory-warnings and -Werror.
  1427. if test "$enable_gcc_warnings" = "yes"; then
  1428. enable_gcc_warnings_advisory=yes
  1429. enable_fatal_warnings=yes
  1430. fi
  1431. # OS X Lion started deprecating the system openssl. Let's just disable
  1432. # all deprecation warnings on OS X. Also, to potentially make the binary
  1433. # a little smaller, let's enable dead_strip.
  1434. case "$host_os" in
  1435. darwin*)
  1436. CFLAGS="$CFLAGS -Wno-deprecated-declarations"
  1437. LDFLAGS="$LDFLAGS -dead_strip" ;;
  1438. esac
  1439. # Add some more warnings which we use in development but not in the
  1440. # released versions. (Some relevant gcc versions can't handle these.)
  1441. #
  1442. # Note that we have to do this near the end of the autoconf process, or
  1443. # else we may run into problems when these warnings hit on the testing C
  1444. # programs that autoconf wants to build.
  1445. if test "x$enable_gcc_warnings_advisory" != "xno"; then
  1446. case "$host" in
  1447. *-*-openbsd* | *-*-bitrig*)
  1448. # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
  1449. # That's fine, except that the headers don't pass -Wredundant-decls.
  1450. # Therefore, let's disable -Wsystem-headers when we're building
  1451. # with maximal warnings on OpenBSD.
  1452. CFLAGS="$CFLAGS -Wno-system-headers" ;;
  1453. esac
  1454. # GCC4.3 users once report trouble with -Wstrict-overflow=5. GCC5 users
  1455. # have it work better.
  1456. # CFLAGS="$CFLAGS -Wstrict-overflow=1"
  1457. # This warning was added in gcc 4.3, but it appears to generate
  1458. # spurious warnings in gcc 4.4. I don't know if it works in 4.5.
  1459. #CFLAGS="$CFLAGS -Wlogical-op"
  1460. m4_foreach_w([warning_flag], [
  1461. -Waddress
  1462. -Waddress-of-array-temporary
  1463. -Waddress-of-temporary
  1464. -Wambiguous-macro
  1465. -Wanonymous-pack-parens
  1466. -Warc
  1467. -Warc-abi
  1468. -Warc-bridge-casts-disallowed-in-nonarc
  1469. -Warc-maybe-repeated-use-of-weak
  1470. -Warc-performSelector-leaks
  1471. -Warc-repeated-use-of-weak
  1472. -Warray-bounds
  1473. -Warray-bounds-pointer-arithmetic
  1474. -Wasm
  1475. -Wasm-operand-widths
  1476. -Watomic-properties
  1477. -Watomic-property-with-user-defined-accessor
  1478. -Wauto-import
  1479. -Wauto-storage-class
  1480. -Wauto-var-id
  1481. -Wavailability
  1482. -Wbackslash-newline-escape
  1483. -Wbad-array-new-length
  1484. -Wbind-to-temporary-copy
  1485. -Wbitfield-constant-conversion
  1486. -Wbool-conversion
  1487. -Wbool-conversions
  1488. -Wbuiltin-requires-header
  1489. -Wchar-align
  1490. -Wcompare-distinct-pointer-types
  1491. -Wcomplex-component-init
  1492. -Wconditional-type-mismatch
  1493. -Wconfig-macros
  1494. -Wconstant-conversion
  1495. -Wconstant-logical-operand
  1496. -Wconstexpr-not-const
  1497. -Wcustom-atomic-properties
  1498. -Wdangling-field
  1499. -Wdangling-initializer-list
  1500. -Wdate-time
  1501. -Wdelegating-ctor-cycles
  1502. -Wdeprecated-implementations
  1503. -Wdeprecated-register
  1504. -Wdirect-ivar-access
  1505. -Wdiscard-qual
  1506. -Wdistributed-object-modifiers
  1507. -Wdivision-by-zero
  1508. -Wdollar-in-identifier-extension
  1509. -Wdouble-promotion
  1510. -Wduplicate-decl-specifier
  1511. -Wduplicate-enum
  1512. -Wduplicate-method-arg
  1513. -Wduplicate-method-match
  1514. -Wduplicated-cond
  1515. -Wdynamic-class-memaccess
  1516. -Wembedded-directive
  1517. -Wempty-translation-unit
  1518. -Wenum-conversion
  1519. -Wexit-time-destructors
  1520. -Wexplicit-ownership-type
  1521. -Wextern-initializer
  1522. -Wextra
  1523. -Wextra-semi
  1524. -Wextra-tokens
  1525. -Wflexible-array-extensions
  1526. -Wfloat-conversion
  1527. -Wformat-non-iso
  1528. -Wfour-char-constants
  1529. -Wgcc-compat
  1530. -Wglobal-constructors
  1531. -Wgnu-array-member-paren-init
  1532. -Wgnu-designator
  1533. -Wgnu-static-float-init
  1534. -Wheader-guard
  1535. -Wheader-hygiene
  1536. -Widiomatic-parentheses
  1537. -Wignored-attributes
  1538. -Wimplicit-atomic-properties
  1539. -Wimplicit-conversion-floating-point-to-bool
  1540. -Wimplicit-exception-spec-mismatch
  1541. -Wimplicit-fallthrough
  1542. -Wimplicit-fallthrough-per-function
  1543. -Wimplicit-retain-self
  1544. -Wimport-preprocessor-directive-pedantic
  1545. -Wincompatible-library-redeclaration
  1546. -Wincompatible-pointer-types-discards-qualifiers
  1547. -Wincomplete-implementation
  1548. -Wincomplete-module
  1549. -Wincomplete-umbrella
  1550. -Winit-self
  1551. -Wint-conversions
  1552. -Wint-to-void-pointer-cast
  1553. -Winteger-overflow
  1554. -Winvalid-constexpr
  1555. -Winvalid-iboutlet
  1556. -Winvalid-noreturn
  1557. -Winvalid-pp-token
  1558. -Winvalid-source-encoding
  1559. -Winvalid-token-paste
  1560. -Wknr-promoted-parameter
  1561. -Wlanguage-extension-token
  1562. -Wlarge-by-value-copy
  1563. -Wliteral-conversion
  1564. -Wliteral-range
  1565. -Wlocal-type-template-args
  1566. -Wlogical-op
  1567. -Wloop-analysis
  1568. -Wmain-return-type
  1569. -Wmalformed-warning-check
  1570. -Wmethod-signatures
  1571. -Wmicrosoft
  1572. -Wmicrosoft-exists
  1573. -Wmismatched-parameter-types
  1574. -Wmismatched-return-types
  1575. -Wmissing-field-initializers
  1576. -Wmissing-format-attribute
  1577. -Wmissing-noreturn
  1578. -Wmissing-selector-name
  1579. -Wmissing-sysroot
  1580. -Wmissing-variable-declarations
  1581. -Wmodule-conflict
  1582. -Wnested-anon-types
  1583. -Wnewline-eof
  1584. -Wnon-literal-null-conversion
  1585. -Wnon-pod-varargs
  1586. -Wnonportable-cfstrings
  1587. -Wnormalized=id
  1588. -Wnull-arithmetic
  1589. -Wnull-character
  1590. -Wnull-conversion
  1591. -Wnull-dereference
  1592. -Wout-of-line-declaration
  1593. -Wover-aligned
  1594. -Woverlength-strings
  1595. -Woverride-init
  1596. -Woverriding-method-mismatch
  1597. -Wpointer-type-mismatch
  1598. -Wpredefined-identifier-outside-function
  1599. -Wprotocol-property-synthesis-ambiguity
  1600. -Wreadonly-iboutlet-property
  1601. -Wreadonly-setter-attrs
  1602. -Wreceiver-expr
  1603. -Wreceiver-forward-class
  1604. -Wreceiver-is-weak
  1605. -Wreinterpret-base-class
  1606. -Wrequires-super-attribute
  1607. -Wreserved-user-defined-literal
  1608. -Wreturn-stack-address
  1609. -Wsection
  1610. -Wselector-type-mismatch
  1611. -Wsentinel
  1612. -Wserialized-diagnostics
  1613. -Wshadow
  1614. -Wshift-count-negative
  1615. -Wshift-count-overflow
  1616. -Wshift-negative-value
  1617. -Wshift-overflow=2
  1618. -Wshift-sign-overflow
  1619. -Wshorten-64-to-32
  1620. -Wsizeof-array-argument
  1621. -Wsource-uses-openmp
  1622. -Wstatic-float-init
  1623. -Wstatic-in-inline
  1624. -Wstatic-local-in-inline
  1625. -Wstrict-overflow=2
  1626. -Wstring-compare
  1627. -Wstring-conversion
  1628. -Wstrlcpy-strlcat-size
  1629. -Wstrncat-size
  1630. -Wsuggest-attribute=format
  1631. -Wsuggest-attribute=noreturn
  1632. -Wsuper-class-method-mismatch
  1633. -Wswitch-bool
  1634. -Wsync-nand
  1635. -Wtautological-constant-out-of-range-compare
  1636. -Wtentative-definition-incomplete-type
  1637. -Wtrampolines
  1638. -Wtype-safety
  1639. -Wtypedef-redefinition
  1640. -Wtypename-missing
  1641. -Wundefined-inline
  1642. -Wundefined-internal
  1643. -Wundefined-reinterpret-cast
  1644. -Wunicode
  1645. -Wunicode-whitespace
  1646. -Wunknown-warning-option
  1647. -Wunnamed-type-template-args
  1648. -Wunneeded-member-function
  1649. -Wunsequenced
  1650. -Wunsupported-visibility
  1651. -Wunused-but-set-parameter
  1652. -Wunused-but-set-variable
  1653. -Wunused-command-line-argument
  1654. -Wunused-const-variable=2
  1655. -Wunused-exception-parameter
  1656. -Wunused-local-typedefs
  1657. -Wunused-member-function
  1658. -Wunused-sanitize-argument
  1659. -Wunused-volatile-lvalue
  1660. -Wuser-defined-literals
  1661. -Wvariadic-macros
  1662. -Wvector-conversion
  1663. -Wvector-conversions
  1664. -Wvexing-parse
  1665. -Wvisibility
  1666. -Wvla-extension
  1667. -Wzero-length-array
  1668. ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
  1669. dnl These seem to require annotations that we don't currently use,
  1670. dnl and they give false positives in our pthreads wrappers. (Clang 4)
  1671. dnl -Wthread-safety
  1672. dnl -Wthread-safety-analysis
  1673. dnl -Wthread-safety-attributes
  1674. dnl -Wthread-safety-beta
  1675. dnl -Wthread-safety-precise
  1676. CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
  1677. CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
  1678. CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
  1679. CFLAGS="$CFLAGS -Wwrite-strings"
  1680. CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
  1681. CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
  1682. CFLAGS="$CFLAGS -Wunused-parameter "
  1683. # These interfere with building main() { return 0; }, which autoconf
  1684. # likes to use as its default program.
  1685. CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
  1686. if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
  1687. AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
  1688. fi
  1689. if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
  1690. AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
  1691. fi
  1692. if test "x$enable_fatal_warnings" = "xyes"; then
  1693. # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
  1694. # default autoconf programs are full of errors.
  1695. CFLAGS="$CFLAGS -Werror"
  1696. fi
  1697. fi
  1698. if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
  1699. case "$host_os" in
  1700. darwin*)
  1701. AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
  1702. esac
  1703. fi
  1704. CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
  1705. AC_CONFIG_FILES([
  1706. Doxyfile
  1707. Makefile
  1708. contrib/dist/suse/tor.sh
  1709. contrib/operator-tools/tor.logrotate
  1710. contrib/dist/tor.sh
  1711. contrib/dist/torctl
  1712. contrib/dist/tor.service
  1713. src/config/torrc.sample
  1714. src/config/torrc.minimal
  1715. scripts/maint/checkOptionDocs.pl
  1716. scripts/maint/updateVersions.pl
  1717. ])
  1718. if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
  1719. regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
  1720. for file in $regular_mans ; do
  1721. if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
  1722. echo "==================================";
  1723. echo;
  1724. echo "Building Tor has failed since manpages cannot be built.";
  1725. echo;
  1726. echo "You need asciidoc installed to be able to build the manpages.";
  1727. echo "To build without manpages, use the --disable-asciidoc argument";
  1728. echo "when calling configure.";
  1729. echo;
  1730. echo "==================================";
  1731. exit 1;
  1732. fi
  1733. done
  1734. fi
  1735. AC_OUTPUT