configure.ac 70 KB

1234567891011121314151617181920212223242526272829303132333435363738394041424344454647484950515253545556575859606162636465666768697071727374757677787980818283848586878889909192939495969798991001011021031041051061071081091101111121131141151161171181191201211221231241251261271281291301311321331341351361371381391401411421431441451461471481491501511521531541551561571581591601611621631641651661671681691701711721731741751761771781791801811821831841851861871881891901911921931941951961971981992002012022032042052062072082092102112122132142152162172182192202212222232242252262272282292302312322332342352362372382392402412422432442452462472482492502512522532542552562572582592602612622632642652662672682692702712722732742752762772782792802812822832842852862872882892902912922932942952962972982993003013023033043053063073083093103113123133143153163173183193203213223233243253263273283293303313323333343353363373383393403413423433443453463473483493503513523533543553563573583593603613623633643653663673683693703713723733743753763773783793803813823833843853863873883893903913923933943953963973983994004014024034044054064074084094104114124134144154164174184194204214224234244254264274284294304314324334344354364374384394404414424434444454464474484494504514524534544554564574584594604614624634644654664674684694704714724734744754764774784794804814824834844854864874884894904914924934944954964974984995005015025035045055065075085095105115125135145155165175185195205215225235245255265275285295305315325335345355365375385395405415425435445455465475485495505515525535545555565575585595605615625635645655665675685695705715725735745755765775785795805815825835845855865875885895905915925935945955965975985996006016026036046056066076086096106116126136146156166176186196206216226236246256266276286296306316326336346356366376386396406416426436446456466476486496506516526536546556566576586596606616626636646656666676686696706716726736746756766776786796806816826836846856866876886896906916926936946956966976986997007017027037047057067077087097107117127137147157167177187197207217227237247257267277287297307317327337347357367377387397407417427437447457467477487497507517527537547557567577587597607617627637647657667677687697707717727737747757767777787797807817827837847857867877887897907917927937947957967977987998008018028038048058068078088098108118128138148158168178188198208218228238248258268278288298308318328338348358368378388398408418428438448458468478488498508518528538548558568578588598608618628638648658668678688698708718728738748758768778788798808818828838848858868878888898908918928938948958968978988999009019029039049059069079089099109119129139149159169179189199209219229239249259269279289299309319329339349359369379389399409419429439449459469479489499509519529539549559569579589599609619629639649659669679689699709719729739749759769779789799809819829839849859869879889899909919929939949959969979989991000100110021003100410051006100710081009101010111012101310141015101610171018101910201021102210231024102510261027102810291030103110321033103410351036103710381039104010411042104310441045104610471048104910501051105210531054105510561057105810591060106110621063106410651066106710681069107010711072107310741075107610771078107910801081108210831084108510861087108810891090109110921093109410951096109710981099110011011102110311041105110611071108110911101111111211131114111511161117111811191120112111221123112411251126112711281129113011311132113311341135113611371138113911401141114211431144114511461147114811491150115111521153115411551156115711581159116011611162116311641165116611671168116911701171117211731174117511761177117811791180118111821183118411851186118711881189119011911192119311941195119611971198119912001201120212031204120512061207120812091210121112121213121412151216121712181219122012211222122312241225122612271228122912301231123212331234123512361237123812391240124112421243124412451246124712481249125012511252125312541255125612571258125912601261126212631264126512661267126812691270127112721273127412751276127712781279128012811282128312841285128612871288128912901291129212931294129512961297129812991300130113021303130413051306130713081309131013111312131313141315131613171318131913201321132213231324132513261327132813291330133113321333133413351336133713381339134013411342134313441345134613471348134913501351135213531354135513561357135813591360136113621363136413651366136713681369137013711372137313741375137613771378137913801381138213831384138513861387138813891390139113921393139413951396139713981399140014011402140314041405140614071408140914101411141214131414141514161417141814191420142114221423142414251426142714281429143014311432143314341435143614371438143914401441144214431444144514461447144814491450145114521453145414551456145714581459146014611462146314641465146614671468146914701471147214731474147514761477147814791480148114821483148414851486148714881489149014911492149314941495149614971498149915001501150215031504150515061507150815091510151115121513151415151516151715181519152015211522152315241525152615271528152915301531153215331534153515361537153815391540154115421543154415451546154715481549155015511552155315541555155615571558155915601561156215631564156515661567156815691570157115721573157415751576157715781579158015811582158315841585158615871588158915901591159215931594159515961597159815991600160116021603160416051606160716081609161016111612161316141615161616171618161916201621162216231624162516261627162816291630163116321633163416351636163716381639164016411642164316441645164616471648164916501651165216531654165516561657165816591660166116621663166416651666166716681669167016711672167316741675167616771678167916801681168216831684168516861687168816891690169116921693169416951696169716981699170017011702170317041705170617071708170917101711171217131714171517161717171817191720172117221723172417251726172717281729173017311732173317341735173617371738173917401741174217431744174517461747174817491750175117521753175417551756175717581759176017611762176317641765176617671768176917701771177217731774177517761777177817791780178117821783178417851786178717881789179017911792179317941795179617971798179918001801180218031804180518061807180818091810181118121813181418151816181718181819182018211822182318241825182618271828182918301831183218331834183518361837183818391840184118421843184418451846184718481849185018511852185318541855185618571858185918601861186218631864186518661867186818691870187118721873187418751876187718781879188018811882188318841885188618871888188918901891189218931894189518961897189818991900190119021903190419051906190719081909191019111912191319141915191619171918191919201921192219231924192519261927192819291930193119321933193419351936193719381939194019411942194319441945194619471948194919501951195219531954195519561957195819591960196119621963196419651966196719681969197019711972197319741975197619771978197919801981198219831984198519861987198819891990199119921993199419951996199719981999200020012002200320042005200620072008200920102011201220132014201520162017201820192020202120222023202420252026202720282029203020312032203320342035203620372038203920402041204220432044204520462047204820492050205120522053205420552056205720582059206020612062206320642065206620672068206920702071207220732074207520762077207820792080208120822083208420852086208720882089209020912092209320942095209620972098209921002101210221032104210521062107210821092110211121122113211421152116211721182119212021212122212321242125212621272128212921302131213221332134213521362137213821392140214121422143214421452146214721482149215021512152215321542155215621572158215921602161216221632164216521662167216821692170217121722173217421752176217721782179218021812182218321842185218621872188218921902191219221932194219521962197219821992200220122022203220422052206220722082209221022112212221322142215221622172218221922202221222222232224222522262227222822292230223122322233223422352236
  1. dnl Copyright (c) 2001-2004, Roger Dingledine
  2. dnl Copyright (c) 2004-2006, Roger Dingledine, Nick Mathewson
  3. dnl Copyright (c) 2007-2017, The Tor Project, Inc.
  4. dnl See LICENSE for licensing information
  5. AC_PREREQ([2.63])
  6. AC_INIT([tor],[0.3.3.1-alpha-dev])
  7. AC_CONFIG_SRCDIR([src/or/main.c])
  8. AC_CONFIG_MACRO_DIR([m4])
  9. # "foreign" means we don't follow GNU package layout standards
  10. # "1.11" means we require automake version 1.11 or newer
  11. # "subdir-objects" means put .o files in the same directory as the .c files
  12. AM_INIT_AUTOMAKE([foreign 1.11 subdir-objects -Wall -Werror])
  13. m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  14. AC_CONFIG_HEADERS([orconfig.h])
  15. AC_USE_SYSTEM_EXTENSIONS
  16. AC_CANONICAL_HOST
  17. PKG_PROG_PKG_CONFIG
  18. if test -f "/etc/redhat-release"; then
  19. if test -f "/usr/kerberos/include"; then
  20. CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
  21. fi
  22. fi
  23. # Not a no-op; we want to make sure that CPPFLAGS is set before we use
  24. # the += operator on it in src/or/Makefile.am
  25. CPPFLAGS="$CPPFLAGS -I\${top_srcdir}/src/common"
  26. AC_ARG_ENABLE(openbsd-malloc,
  27. AS_HELP_STRING(--enable-openbsd-malloc, [use malloc code from OpenBSD. Linux only]))
  28. AC_ARG_ENABLE(static-openssl,
  29. AS_HELP_STRING(--enable-static-openssl, [link against a static openssl library. Requires --with-openssl-dir]))
  30. AC_ARG_ENABLE(static-libevent,
  31. AS_HELP_STRING(--enable-static-libevent, [link against a static libevent library. Requires --with-libevent-dir]))
  32. AC_ARG_ENABLE(static-zlib,
  33. AS_HELP_STRING(--enable-static-zlib, [link against a static zlib library. Requires --with-zlib-dir]))
  34. AC_ARG_ENABLE(static-tor,
  35. AS_HELP_STRING(--enable-static-tor, [create an entirely static Tor binary. Requires --with-openssl-dir and --with-libevent-dir and --with-zlib-dir]))
  36. AC_ARG_ENABLE(unittests,
  37. AS_HELP_STRING(--disable-unittests, [don't build unit tests for Tor. Risky!]))
  38. AC_ARG_ENABLE(coverage,
  39. AS_HELP_STRING(--enable-coverage, [enable coverage support in the unit-test build]))
  40. AC_ARG_ENABLE(asserts-in-tests,
  41. AS_HELP_STRING(--disable-asserts-in-tests, [disable tor_assert() calls in the unit tests, for branch coverage]))
  42. AC_ARG_ENABLE(system-torrc,
  43. AS_HELP_STRING(--disable-system-torrc, [don't look for a system-wide torrc file]))
  44. AC_ARG_ENABLE(libfuzzer,
  45. AS_HELP_STRING(--enable-libfuzzer, [build extra fuzzers based on 'libfuzzer']))
  46. AC_ARG_ENABLE(oss-fuzz,
  47. AS_HELP_STRING(--enable-oss-fuzz, [build extra fuzzers based on 'oss-fuzz' environment]))
  48. AC_ARG_ENABLE(memory-sentinels,
  49. AS_HELP_STRING(--disable-memory-sentinels, [disable code that tries to prevent some kinds of memory access bugs. For fuzzing only.]))
  50. AC_ARG_ENABLE(rust,
  51. AS_HELP_STRING(--enable-rust, [enable rust integration]))
  52. AC_ARG_ENABLE(cargo-online-mode,
  53. AS_HELP_STRING(--enable-cargo-online-mode, [Allow cargo to make network requests to fetch crates. For builds with rust only.]))
  54. AC_ARG_ENABLE(restart-debugging,
  55. AS_HELP_STRING(--enable-restart-debugging, [Build Tor with support for debugging in-process restart. Developers only.]))
  56. if test "x$enable_coverage" != "xyes" -a "x$enable_asserts_in_tests" = "xno" ; then
  57. AC_MSG_ERROR([Can't disable assertions outside of coverage build])
  58. fi
  59. AM_CONDITIONAL(UNITTESTS_ENABLED, test "x$enable_unittests" != "xno")
  60. AM_CONDITIONAL(COVERAGE_ENABLED, test "x$enable_coverage" = "xyes")
  61. AM_CONDITIONAL(DISABLE_ASSERTS_IN_UNIT_TESTS, test "x$enable_asserts_in_tests" = "xno")
  62. AM_CONDITIONAL(LIBFUZZER_ENABLED, test "x$enable_libfuzzer" = "xyes")
  63. AM_CONDITIONAL(OSS_FUZZ_ENABLED, test "x$enable_oss_fuzz" = "xyes")
  64. AM_CONDITIONAL(USE_RUST, test "x$enable_rust" = "xyes")
  65. if test "$enable_static_tor" = "yes"; then
  66. enable_static_libevent="yes";
  67. enable_static_openssl="yes";
  68. enable_static_zlib="yes";
  69. CFLAGS="$CFLAGS -static"
  70. fi
  71. if test "$enable_system_torrc" = "no"; then
  72. AC_DEFINE(DISABLE_SYSTEM_TORRC, 1,
  73. [Defined if we're not going to look for a torrc in SYSCONF])
  74. fi
  75. if test "$enable_memory_sentinels" = "no"; then
  76. AC_DEFINE(DISABLE_MEMORY_SENTINELS, 1,
  77. [Defined if we're turning off memory safety code to look for bugs])
  78. fi
  79. AM_CONDITIONAL(USE_OPENBSD_MALLOC, test "x$enable_openbsd_malloc" = "xyes")
  80. AC_ARG_ENABLE(asciidoc,
  81. AS_HELP_STRING(--disable-asciidoc, [don't use asciidoc (disables building of manpages)]),
  82. [case "${enableval}" in
  83. "yes") asciidoc=true ;;
  84. "no") asciidoc=false ;;
  85. *) AC_MSG_ERROR(bad value for --disable-asciidoc) ;;
  86. esac], [asciidoc=true])
  87. # systemd notify support
  88. AC_ARG_ENABLE(systemd,
  89. AS_HELP_STRING(--enable-systemd, [enable systemd notification support]),
  90. [case "${enableval}" in
  91. "yes") systemd=true ;;
  92. "no") systemd=false ;;
  93. * ) AC_MSG_ERROR(bad value for --enable-systemd) ;;
  94. esac], [systemd=auto])
  95. if test "$enable_restart_debugging" = "yes"; then
  96. AC_DEFINE(ENABLE_RESTART_DEBUGGING, 1,
  97. [Defined if we're building with support for in-process restart debugging.])
  98. fi
  99. # systemd support
  100. if test "x$enable_systemd" = "xno"; then
  101. have_systemd=no;
  102. else
  103. PKG_CHECK_MODULES(SYSTEMD,
  104. [libsystemd-daemon],
  105. have_systemd=yes,
  106. have_systemd=no)
  107. if test "x$have_systemd" = "xno"; then
  108. AC_MSG_NOTICE([Okay, checking for systemd a different way...])
  109. PKG_CHECK_MODULES(SYSTEMD,
  110. [libsystemd],
  111. have_systemd=yes,
  112. have_systemd=no)
  113. fi
  114. fi
  115. if test "x$have_systemd" = "xyes"; then
  116. AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
  117. TOR_SYSTEMD_CFLAGS="${SYSTEMD_CFLAGS}"
  118. TOR_SYSTEMD_LIBS="${SYSTEMD_LIBS}"
  119. PKG_CHECK_MODULES(LIBSYSTEMD209, [libsystemd >= 209],
  120. [AC_DEFINE(HAVE_SYSTEMD_209,1,[Have systemd v209 or more])], [])
  121. fi
  122. AC_SUBST(TOR_SYSTEMD_CFLAGS)
  123. AC_SUBST(TOR_SYSTEMD_LIBS)
  124. if test "x$enable_systemd" = "xyes" -a "x$have_systemd" != "xyes" ; then
  125. AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
  126. fi
  127. case "$host" in
  128. *-*-solaris* )
  129. AC_DEFINE(_REENTRANT, 1, [Define on some platforms to activate x_r() functions in time.h])
  130. ;;
  131. esac
  132. AC_ARG_ENABLE(gcc-warnings,
  133. AS_HELP_STRING(--enable-gcc-warnings, [deprecated alias for enable-fatal-warnings]))
  134. AC_ARG_ENABLE(fatal-warnings,
  135. AS_HELP_STRING(--enable-fatal-warnings, [tell the compiler to treat all warnings as errors.]))
  136. AC_ARG_ENABLE(gcc-warnings-advisory,
  137. AS_HELP_STRING(--disable-gcc-warnings-advisory, [disable the regular verbose warnings]))
  138. dnl Others suggest '/gs /safeseh /nxcompat /dynamicbase' for non-gcc on Windows
  139. AC_ARG_ENABLE(gcc-hardening,
  140. AS_HELP_STRING(--disable-gcc-hardening, [disable compiler security checks]))
  141. dnl Deprecated --enable-expensive-hardening but keep it for now for backward compat.
  142. AC_ARG_ENABLE(expensive-hardening,
  143. AS_HELP_STRING(--enable-expensive-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
  144. AC_ARG_ENABLE(fragile-hardening,
  145. AS_HELP_STRING(--enable-fragile-hardening, [enable more fragile and expensive compiler hardening; makes Tor slower]))
  146. if test "x$enable_expensive_hardening" = "xyes" || test "x$enable_fragile_hardening" = "xyes"; then
  147. fragile_hardening="yes"
  148. fi
  149. dnl Linker hardening options
  150. dnl Currently these options are ELF specific - you can't use this with MacOSX
  151. AC_ARG_ENABLE(linker-hardening,
  152. AS_HELP_STRING(--disable-linker-hardening, [disable linker security fixups]))
  153. AC_ARG_ENABLE(local-appdata,
  154. AS_HELP_STRING(--enable-local-appdata, [default to host local application data paths on Windows]))
  155. if test "$enable_local_appdata" = "yes"; then
  156. AC_DEFINE(ENABLE_LOCAL_APPDATA, 1,
  157. [Defined if we default to host local appdata paths on Windows])
  158. fi
  159. # Tor2web mode flag
  160. AC_ARG_ENABLE(tor2web-mode,
  161. AS_HELP_STRING(--enable-tor2web-mode, [support tor2web non-anonymous mode]),
  162. [if test "x$enableval" = "xyes"; then
  163. CFLAGS="$CFLAGS -D ENABLE_TOR2WEB_MODE=1"
  164. fi])
  165. AC_ARG_ENABLE(tool-name-check,
  166. AS_HELP_STRING(--disable-tool-name-check, [check for sanely named toolchain when cross-compiling]))
  167. AC_ARG_ENABLE(seccomp,
  168. AS_HELP_STRING(--disable-seccomp, [do not attempt to use libseccomp]))
  169. AC_ARG_ENABLE(libscrypt,
  170. AS_HELP_STRING(--disable-libscrypt, [do not attempt to use libscrypt]))
  171. dnl Enable event tracing which are transformed to debug log statement.
  172. AC_ARG_ENABLE(event-tracing-debug,
  173. AS_HELP_STRING(--enable-event-tracing-debug, [build with event tracing to debug log]))
  174. AM_CONDITIONAL([USE_EVENT_TRACING_DEBUG], [test "x$enable_event_tracing_debug" = "xyes"])
  175. if test x$enable_event_tracing_debug = xyes; then
  176. AC_DEFINE([USE_EVENT_TRACING_DEBUG], [1], [Tracing framework to log debug])
  177. AC_DEFINE([TOR_EVENT_TRACING_ENABLED], [1], [Compile the event tracing instrumentation])
  178. fi
  179. dnl Enable Android only features.
  180. AC_ARG_ENABLE(android,
  181. AS_HELP_STRING(--enable-android, [build with Android features enabled]))
  182. AM_CONDITIONAL([USE_ANDROID], [test "x$enable_android" = "xyes"])
  183. if test "x$enable_android" = "xyes"; then
  184. AC_DEFINE([USE_ANDROID], [1], [Compile with Android specific features enabled])
  185. dnl Check if the Android log library is available.
  186. AC_CHECK_HEADERS([android/log.h])
  187. AC_SEARCH_LIBS(__android_log_write, [log])
  188. fi
  189. dnl check for the correct "ar" when cross-compiling.
  190. dnl (AM_PROG_AR was new in automake 1.11.2, which we do not yet require,
  191. dnl so kludge up a replacement for the case where it isn't there yet.)
  192. m4_ifdef([AM_PROG_AR],
  193. [AM_PROG_AR],
  194. [AN_MAKEVAR([AR], [AC_PROG_AR])
  195. AN_PROGRAM([ar], [AC_PROG_AR])
  196. AC_DEFUN([AC_PROG_AR], [AC_CHECK_TOOL([AR], [ar], [:])])
  197. AC_PROG_AR])
  198. dnl Check whether the above macro has settled for a simply named tool even
  199. dnl though we're cross compiling. We must do this before running AC_PROG_CC,
  200. dnl because that will find any cc on the system, not only the cross-compiler,
  201. dnl and then verify that a binary built with this compiler runs on the
  202. dnl build system. It will then come to the false conclusion that we're not
  203. dnl cross-compiling.
  204. if test "x$enable_tool_name_check" != "xno"; then
  205. if test "x$ac_tool_warned" = "xyes"; then
  206. AC_MSG_ERROR([We are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
  207. elif test "x$ac_ct_AR" != "x" -a "x$cross_compiling" = "xmaybe"; then
  208. AC_MSG_ERROR([We think we are cross compiling but could not find a properly named toolchain. Do you have your cross-compiling toolchain in PATH? (You can --disable-tool-name-check to ignore this.)])
  209. fi
  210. fi
  211. AC_PROG_CC
  212. AC_PROG_CPP
  213. AC_PROG_MAKE_SET
  214. AC_PROG_RANLIB
  215. AC_PROG_SED
  216. AC_ARG_VAR([PERL], [path to Perl binary])
  217. AC_CHECK_PROGS([PERL], [perl])
  218. AM_CONDITIONAL(USE_PERL, [test "x$ac_cv_prog_PERL" != "x"])
  219. dnl check for asciidoc and a2x
  220. AC_PATH_PROG([ASCIIDOC], [asciidoc], none)
  221. AC_PATH_PROGS([A2X], [a2x a2x.py], none)
  222. AM_CONDITIONAL(USE_ASCIIDOC, test "x$asciidoc" = "xtrue")
  223. AM_PROG_CC_C_O
  224. AC_PROG_CC_C99
  225. AC_ARG_VAR([PYTHON], [path to Python binary])
  226. AC_CHECK_PROGS(PYTHON, [python python2 python2.7 python3 python3.3])
  227. if test "x$PYTHON" = "x"; then
  228. AC_MSG_WARN([Python unavailable; some tests will not be run.])
  229. fi
  230. AM_CONDITIONAL(USEPYTHON, [test "x$PYTHON" != "x"])
  231. dnl List all external rust crates we depend on here. Include the version
  232. rust_crates="libc-0.2.22"
  233. AC_SUBST(rust_crates)
  234. ifdef([AC_C_FLEXIBLE_ARRAY_MEMBER], [
  235. AC_C_FLEXIBLE_ARRAY_MEMBER
  236. ], [
  237. dnl Maybe we've got an old autoconf...
  238. AC_CACHE_CHECK([for flexible array members],
  239. tor_cv_c_flexarray,
  240. [AC_COMPILE_IFELSE(
  241. AC_LANG_PROGRAM([
  242. struct abc { int a; char b[]; };
  243. ], [
  244. struct abc *def = malloc(sizeof(struct abc)+sizeof(char));
  245. def->b[0] = 33;
  246. ]),
  247. [tor_cv_c_flexarray=yes],
  248. [tor_cv_c_flexarray=no])])
  249. if test "$tor_cv_flexarray" = "yes"; then
  250. AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
  251. else
  252. AC_DEFINE([FLEXIBLE_ARRAY_MEMBER], [1], [Define to nothing if C supports flexible array members, and to 1 if it does not.])
  253. fi
  254. ])
  255. AC_CACHE_CHECK([for working C99 mid-block declaration syntax],
  256. tor_cv_c_c99_decl,
  257. [AC_COMPILE_IFELSE(
  258. [AC_LANG_PROGRAM([], [int x; x = 3; int y; y = 4 + x;])],
  259. [tor_cv_c_c99_decl=yes],
  260. [tor_cv_c_c99_decl=no] )])
  261. if test "$tor_cv_c_c99_decl" != "yes"; then
  262. AC_MSG_ERROR([Your compiler doesn't support c99 mid-block declarations. This is required as of Tor 0.2.6.x])
  263. fi
  264. AC_CACHE_CHECK([for working C99 designated initializers],
  265. tor_cv_c_c99_designated_init,
  266. [AC_COMPILE_IFELSE(
  267. [AC_LANG_PROGRAM([struct s { int a; int b; };],
  268. [[ struct s ss = { .b = 5, .a = 6 }; ]])],
  269. [tor_cv_c_c99_designated_init=yes],
  270. [tor_cv_c_c99_designated_init=no] )])
  271. if test "$tor_cv_c_c99_designated_init" != "yes"; then
  272. AC_MSG_ERROR([Your compiler doesn't support c99 designated initializers. This is required as of Tor 0.2.6.x])
  273. fi
  274. TORUSER=_tor
  275. AC_ARG_WITH(tor-user,
  276. AS_HELP_STRING(--with-tor-user=NAME, [specify username for tor daemon]),
  277. [
  278. TORUSER=$withval
  279. ]
  280. )
  281. AC_SUBST(TORUSER)
  282. TORGROUP=_tor
  283. AC_ARG_WITH(tor-group,
  284. AS_HELP_STRING(--with-tor-group=NAME, [specify group name for tor daemon]),
  285. [
  286. TORGROUP=$withval
  287. ]
  288. )
  289. AC_SUBST(TORGROUP)
  290. dnl If _WIN32 is defined and non-zero, we are building for win32
  291. AC_MSG_CHECKING([for win32])
  292. AC_RUN_IFELSE([AC_LANG_SOURCE([
  293. int main(int c, char **v) {
  294. #ifdef _WIN32
  295. #if _WIN32
  296. return 0;
  297. #else
  298. return 1;
  299. #endif
  300. #else
  301. return 2;
  302. #endif
  303. }])],
  304. bwin32=true; AC_MSG_RESULT([yes]),
  305. bwin32=false; AC_MSG_RESULT([no]),
  306. bwin32=cross; AC_MSG_RESULT([cross])
  307. )
  308. if test "$bwin32" = "cross"; then
  309. AC_MSG_CHECKING([for win32 (cross)])
  310. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  311. #ifdef _WIN32
  312. int main(int c, char **v) {return 0;}
  313. #else
  314. #error
  315. int main(int c, char **v) {return x(y);}
  316. #endif
  317. ])],
  318. bwin32=true; AC_MSG_RESULT([yes]),
  319. bwin32=false; AC_MSG_RESULT([no]))
  320. fi
  321. AH_BOTTOM([
  322. #ifdef _WIN32
  323. /* Defined to access windows functions and definitions for >=WinXP */
  324. # ifndef WINVER
  325. # define WINVER 0x0501
  326. # endif
  327. /* Defined to access _other_ windows functions and definitions for >=WinXP */
  328. # ifndef _WIN32_WINNT
  329. # define _WIN32_WINNT 0x0501
  330. # endif
  331. /* Defined to avoid including some windows headers as part of Windows.h */
  332. # ifndef WIN32_LEAN_AND_MEAN
  333. # define WIN32_LEAN_AND_MEAN 1
  334. # endif
  335. #endif
  336. ])
  337. AM_CONDITIONAL(BUILD_NT_SERVICES, test "x$bwin32" = "xtrue")
  338. AM_CONDITIONAL(BUILD_LIBTORRUNNER, test "x$bwin32" != "xtrue")
  339. dnl Enable C99 when compiling with MIPSpro
  340. AC_MSG_CHECKING([for MIPSpro compiler])
  341. AC_COMPILE_IFELSE([AC_LANG_PROGRAM(, [
  342. #if (defined(__sgi) && defined(_COMPILER_VERSION))
  343. #error
  344. return x(y);
  345. #endif
  346. ])],
  347. bmipspro=false; AC_MSG_RESULT(no),
  348. bmipspro=true; AC_MSG_RESULT(yes))
  349. if test "$bmipspro" = "true"; then
  350. CFLAGS="$CFLAGS -c99"
  351. fi
  352. AC_C_BIGENDIAN
  353. if test "x$enable_rust" = "xyes"; then
  354. AC_ARG_VAR([RUSTC], [path to the rustc binary])
  355. AC_CHECK_PROG([RUSTC], [rustc], [rustc],[no])
  356. if test "x$RUSTC" = "xno"; then
  357. AC_MSG_ERROR([rustc unavailable but rust integration requested.])
  358. fi
  359. AC_ARG_VAR([CARGO], [path to the cargo binary])
  360. AC_CHECK_PROG([CARGO], [cargo], [cargo],[no])
  361. if test "x$CARGO" = "xno"; then
  362. AC_MSG_ERROR([cargo unavailable but rust integration requested.])
  363. fi
  364. AC_DEFINE([HAVE_RUST], 1, [have Rust])
  365. if test "x$enable_cargo_online_mode" = "xyes"; then
  366. CARGO_ONLINE=
  367. RUST_DL=#
  368. else
  369. CARGO_ONLINE=--frozen
  370. RUST_DL=
  371. dnl When we're not allowed to touch the network, we need crate dependencies
  372. dnl locally available.
  373. AC_MSG_CHECKING([rust crate dependencies])
  374. AC_ARG_VAR([TOR_RUST_DEPENDENCIES], [path to directory with local crate mirror])
  375. if test "x$TOR_RUST_DEPENDENCIES" = "x"; then
  376. TOR_RUST_DEPENDENCIES="$srcdir/src/ext/rust/"
  377. NEED_MOD=1
  378. fi
  379. if test ! -d "$TOR_RUST_DEPENDENCIES"; then
  380. AC_MSG_ERROR([Rust dependency directory $TOR_RUST_DEPENDENCIES does not exist. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
  381. ERRORED=1
  382. fi
  383. for dep in $rust_crates; do
  384. if test ! -d "$TOR_RUST_DEPENDENCIES"/"$dep"; then
  385. AC_MSG_ERROR([Failure to find rust dependency $TOR_RUST_DEPENDENCIES/$dep. Specify a dependency directory using the TOR_RUST_DEPENDENCIES variable or allow cargo to fetch crates using --enable-cargo-online-mode.])
  386. ERRORED=1
  387. fi
  388. done
  389. if test "x$NEED_MOD" = "x1"; then
  390. dnl When looking for dependencies from cargo, pick right directory
  391. TOR_RUST_DEPENDENCIES="../../src/ext/rust"
  392. fi
  393. if test "x$ERRORED" = "x"; then
  394. AC_MSG_RESULT([yes])
  395. fi
  396. fi
  397. dnl This is a workaround for #46797
  398. dnl (a.k.a https://github.com/rust-lang/rust/issues/46797 ). Once the
  399. dnl upstream bug is fixed, we can remove this workaround.
  400. case "$host_os" in
  401. darwin*)
  402. TOR_RUST_EXTRA_LIBS="-lresolv"
  403. ;;
  404. esac
  405. dnl For now both MSVC and MinGW rust libraries will output static libs with
  406. dnl the MSVC naming convention.
  407. if test "$bwin32" = "true"; then
  408. TOR_RUST_STATIC_NAME=tor_rust.lib
  409. else
  410. TOR_RUST_STATIC_NAME=libtor_rust.a
  411. fi
  412. AC_SUBST(TOR_RUST_STATIC_NAME)
  413. AC_SUBST(CARGO_ONLINE)
  414. AC_SUBST(RUST_DL)
  415. dnl Let's check the rustc version, too
  416. AC_MSG_CHECKING([rust version])
  417. RUSTC_VERSION=`$RUSTC --version`
  418. RUSTC_VERSION_MAJOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 1`
  419. RUSTC_VERSION_MINOR=`$RUSTC --version | cut -d ' ' -f 2 | cut -d '.' -f 2`
  420. if test "x$RUSTC_VERSION_MAJOR" = "x" -o "x$RUSTC_VERSION_MINOR" = "x"; then
  421. AC_MSG_ERROR([rustc version couldn't be identified])
  422. fi
  423. if test "$RUSTC_VERSION_MAJOR" -lt 2 -a "$RUSTC_VERSION_MINOR" -lt 14; then
  424. AC_MSG_ERROR([rustc must be at least version 1.14])
  425. fi
  426. AC_MSG_RESULT([$RUSTC_VERSION])
  427. fi
  428. AC_SUBST(TOR_RUST_EXTRA_LIBS)
  429. AC_SEARCH_LIBS(socket, [socket network])
  430. AC_SEARCH_LIBS(gethostbyname, [nsl])
  431. AC_SEARCH_LIBS(dlopen, [dl])
  432. AC_SEARCH_LIBS(inet_aton, [resolv])
  433. AC_SEARCH_LIBS(backtrace, [execinfo])
  434. saved_LIBS="$LIBS"
  435. AC_SEARCH_LIBS([clock_gettime], [rt])
  436. if test "$LIBS" != "$saved_LIBS"; then
  437. # Looks like we need -lrt for clock_gettime().
  438. have_rt=yes
  439. fi
  440. AC_SEARCH_LIBS(pthread_create, [pthread])
  441. AC_SEARCH_LIBS(pthread_detach, [pthread])
  442. AM_CONDITIONAL(THREADS_WIN32, test "$bwin32" = "true")
  443. AM_CONDITIONAL(THREADS_PTHREADS, test "$bwin32" = "false")
  444. AC_CHECK_FUNCS(
  445. _NSGetEnviron \
  446. RtlSecureZeroMemory \
  447. SecureZeroMemory \
  448. accept4 \
  449. backtrace \
  450. backtrace_symbols_fd \
  451. eventfd \
  452. explicit_bzero \
  453. timingsafe_memcmp \
  454. flock \
  455. ftime \
  456. get_current_dir_name \
  457. getaddrinfo \
  458. getifaddrs \
  459. getpass \
  460. getrlimit \
  461. gettimeofday \
  462. gmtime_r \
  463. gnu_get_libc_version \
  464. htonll \
  465. inet_aton \
  466. ioctl \
  467. issetugid \
  468. llround \
  469. localtime_r \
  470. lround \
  471. mach_approximate_time \
  472. memmem \
  473. memset_s \
  474. pipe \
  475. pipe2 \
  476. prctl \
  477. readpassphrase \
  478. rint \
  479. sigaction \
  480. socketpair \
  481. statvfs \
  482. strlcat \
  483. strlcpy \
  484. strnlen \
  485. strptime \
  486. strtok_r \
  487. strtoull \
  488. sysconf \
  489. sysctl \
  490. truncate \
  491. uname \
  492. usleep \
  493. vasprintf \
  494. _vscprintf
  495. )
  496. # Apple messed up when they added two functions functions in Sierra: they
  497. # forgot to decorate them with appropriate AVAILABLE_MAC_OS_VERSION
  498. # checks. So we should only probe for those functions if we are sure that we
  499. # are not targeting OSX 10.11 or earlier.
  500. AC_MSG_CHECKING([for a pre-Sierra OSX build target])
  501. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  502. #ifdef __APPLE__
  503. # include <AvailabilityMacros.h>
  504. # ifndef MAC_OS_X_VERSION_10_12
  505. # define MAC_OS_X_VERSION_10_12 101200
  506. # endif
  507. # if defined(MAC_OS_X_VERSION_MIN_REQUIRED)
  508. # if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
  509. # error "Running on Mac OSX 10.11 or earlier"
  510. # endif
  511. # endif
  512. #endif
  513. ]], [[]])],
  514. [on_macos_pre_10_12=no ; AC_MSG_RESULT([no])],
  515. [on_macos_pre_10_12=yes; AC_MSG_RESULT([yes])])
  516. if test "$on_macos_pre_10_12" = "no"; then
  517. AC_CHECK_FUNCS(
  518. clock_gettime \
  519. getentropy \
  520. )
  521. fi
  522. if test "$bwin32" != "true"; then
  523. AC_CHECK_HEADERS(pthread.h)
  524. AC_CHECK_FUNCS(pthread_create)
  525. AC_CHECK_FUNCS(pthread_condattr_setclock)
  526. fi
  527. if test "$bwin32" = "true"; then
  528. AC_CHECK_DECLS([SecureZeroMemory, _getwch], , , [
  529. #include <windows.h>
  530. #include <conio.h>
  531. #include <wchar.h>
  532. ])
  533. fi
  534. AM_CONDITIONAL(BUILD_READPASSPHRASE_C,
  535. test "x$ac_cv_func_readpassphrase" = "xno" && test "$bwin32" = "false")
  536. dnl ------------------------------------------------------
  537. dnl Where do you live, libevent? And how do we call you?
  538. if test "$bwin32" = "true"; then
  539. TOR_LIB_WS32=-lws2_32
  540. TOR_LIB_IPHLPAPI=-liphlpapi
  541. # Some of the cargo-cults recommend -lwsock32 as well, but I don't
  542. # think it's actually necessary.
  543. TOR_LIB_GDI=-lgdi32
  544. TOR_LIB_USERENV=-luserenv
  545. else
  546. TOR_LIB_WS32=
  547. TOR_LIB_GDI=
  548. TOR_LIB_USERENV=
  549. fi
  550. AC_SUBST(TOR_LIB_WS32)
  551. AC_SUBST(TOR_LIB_GDI)
  552. AC_SUBST(TOR_LIB_IPHLPAPI)
  553. AC_SUBST(TOR_LIB_USERENV)
  554. tor_libevent_pkg_redhat="libevent"
  555. tor_libevent_pkg_debian="libevent-dev"
  556. tor_libevent_devpkg_redhat="libevent-devel"
  557. tor_libevent_devpkg_debian="libevent-dev"
  558. dnl On Gnu/Linux or any place we require it, we'll add librt to the Libevent
  559. dnl linking for static builds.
  560. STATIC_LIBEVENT_FLAGS=""
  561. if test "$enable_static_libevent" = "yes"; then
  562. if test "$have_rt" = "yes"; then
  563. STATIC_LIBEVENT_FLAGS=" -lrt "
  564. fi
  565. fi
  566. TOR_SEARCH_LIBRARY(libevent, $trylibeventdir, [-levent $STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32], [
  567. #ifdef _WIN32
  568. #include <winsock2.h>
  569. #endif
  570. #include <sys/time.h>
  571. #include <sys/types.h>
  572. #include <event2/event.h>], [
  573. #ifdef _WIN32
  574. #include <winsock2.h>
  575. #endif
  576. struct event_base;
  577. struct event_base *event_base_new(void);],
  578. [
  579. #ifdef _WIN32
  580. {WSADATA d; WSAStartup(0x101,&d); }
  581. #endif
  582. event_base_free(event_base_new());
  583. ], [--with-libevent-dir], [/opt/libevent])
  584. dnl Determine the incantation needed to link libevent.
  585. save_LIBS="$LIBS"
  586. save_LDFLAGS="$LDFLAGS"
  587. save_CPPFLAGS="$CPPFLAGS"
  588. LIBS="$STATIC_LIBEVENT_FLAGS $TOR_LIB_WS32 $save_LIBS"
  589. LDFLAGS="$TOR_LDFLAGS_libevent $LDFLAGS"
  590. CPPFLAGS="$TOR_CPPFLAGS_libevent $CPPFLAGS"
  591. AC_CHECK_HEADERS(event2/event.h event2/dns.h event2/bufferevent_ssl.h)
  592. if test "$enable_static_libevent" = "yes"; then
  593. if test "$tor_cv_library_libevent_dir" = "(system)"; then
  594. AC_MSG_ERROR("You must specify an explicit --with-libevent-dir=x option when using --enable-static-libevent")
  595. else
  596. TOR_LIBEVENT_LIBS="$TOR_LIBDIR_libevent/libevent.a $STATIC_LIBEVENT_FLAGS"
  597. fi
  598. else
  599. if test "x$ac_cv_header_event2_event_h" = "xyes"; then
  600. AC_SEARCH_LIBS(event_new, [event event_core], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for event_new"))
  601. AC_SEARCH_LIBS(evdns_base_new, [event event_extra], , AC_MSG_ERROR("libevent2 is installed but linking it failed while searching for evdns_base_new"))
  602. if test "$ac_cv_search_event_new" != "none required"; then
  603. TOR_LIBEVENT_LIBS="$ac_cv_search_event_new"
  604. fi
  605. if test "$ac_cv_search_evdns_base_new" != "none required"; then
  606. TOR_LIBEVENT_LIBS="$ac_cv_search_evdns_base_new $TOR_LIBEVENT_LIBS"
  607. fi
  608. else
  609. AC_MSG_ERROR("libevent2 is required but the headers could not be found")
  610. fi
  611. fi
  612. dnl Now check for particular libevent functions.
  613. AC_CHECK_FUNCS([evutil_secure_rng_set_urandom_device_file \
  614. evutil_secure_rng_add_bytes \
  615. ])
  616. LIBS="$save_LIBS"
  617. LDFLAGS="$save_LDFLAGS"
  618. CPPFLAGS="$save_CPPFLAGS"
  619. dnl Check that libevent is at least at version 2.0.10, the first stable
  620. dnl release of its series
  621. CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent"
  622. AC_MSG_CHECKING([whether Libevent is new enough])
  623. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  624. #include <event2/event.h>
  625. #if !defined(LIBEVENT_VERSION_NUMBER) || LIBEVENT_VERSION_NUMBER < 0x02000a00
  626. #error
  627. int x = y(zz);
  628. #else
  629. int x = 1;
  630. #endif
  631. ])], [ AC_MSG_RESULT([yes]) ],
  632. [ AC_MSG_RESULT([no])
  633. AC_MSG_ERROR([Libevent is not new enough. We require 2.0.10-stable or later]) ] )
  634. LIBS="$save_LIBS"
  635. LDFLAGS="$save_LDFLAGS"
  636. CPPFLAGS="$save_CPPFLAGS"
  637. AC_SUBST(TOR_LIBEVENT_LIBS)
  638. dnl ------------------------------------------------------
  639. dnl Where do you live, libm?
  640. dnl On some platforms (Haiku/BeOS) the math library is
  641. dnl part of libroot. In which case don't link against lm
  642. TOR_LIB_MATH=""
  643. save_LIBS="$LIBS"
  644. AC_SEARCH_LIBS(pow, [m], , AC_MSG_ERROR([Could not find pow in libm or libc.]))
  645. if test "$ac_cv_search_pow" != "none required"; then
  646. TOR_LIB_MATH="$ac_cv_search_pow"
  647. fi
  648. LIBS="$save_LIBS"
  649. AC_SUBST(TOR_LIB_MATH)
  650. dnl ------------------------------------------------------
  651. dnl Where do you live, openssl? And how do we call you?
  652. tor_openssl_pkg_redhat="openssl"
  653. tor_openssl_pkg_debian="libssl-dev"
  654. tor_openssl_devpkg_redhat="openssl-devel"
  655. tor_openssl_devpkg_debian="libssl-dev"
  656. ALT_openssl_WITHVAL=""
  657. AC_ARG_WITH(ssl-dir,
  658. AS_HELP_STRING(--with-ssl-dir=PATH, [obsolete alias for --with-openssl-dir]),
  659. [
  660. if test "x$withval" != "xno" && test "x$withval" != "x"; then
  661. ALT_openssl_WITHVAL="$withval"
  662. fi
  663. ])
  664. AC_MSG_NOTICE([Now, we'll look for OpenSSL >= 1.0.1])
  665. TOR_SEARCH_LIBRARY(openssl, $tryssldir, [-lssl -lcrypto $TOR_LIB_GDI $TOR_LIB_WS32],
  666. [#include <openssl/ssl.h>],
  667. [struct ssl_method_st; const struct ssl_method_st *TLSv1_1_method(void);],
  668. [TLSv1_1_method();], [],
  669. [/usr/local/opt/openssl /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /opt/openssl])
  670. dnl XXXX check for OPENSSL_VERSION_NUMBER == SSLeay()
  671. if test "$enable_static_openssl" = "yes"; then
  672. if test "$tor_cv_library_openssl_dir" = "(system)"; then
  673. AC_MSG_ERROR("You must specify an explicit --with-openssl-dir=x option when using --enable-static-openssl")
  674. else
  675. TOR_OPENSSL_LIBS="$TOR_LIBDIR_openssl/libssl.a $TOR_LIBDIR_openssl/libcrypto.a"
  676. fi
  677. else
  678. TOR_OPENSSL_LIBS="-lssl -lcrypto"
  679. fi
  680. AC_SUBST(TOR_OPENSSL_LIBS)
  681. dnl Now check for particular openssl functions.
  682. save_LIBS="$LIBS"
  683. save_LDFLAGS="$LDFLAGS"
  684. save_CPPFLAGS="$CPPFLAGS"
  685. LIBS="$TOR_OPENSSL_LIBS $LIBS"
  686. LDFLAGS="$TOR_LDFLAGS_openssl $LDFLAGS"
  687. CPPFLAGS="$TOR_CPPFLAGS_openssl $CPPFLAGS"
  688. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  689. #include <openssl/opensslv.h>
  690. #if !defined(LIBRESSL_VERSION_NUMBER) && OPENSSL_VERSION_NUMBER < 0x1000100fL
  691. #error "too old"
  692. #endif
  693. ]], [[]])],
  694. [ : ],
  695. [ AC_MSG_ERROR([OpenSSL is too old. We require 1.0.1 or later. You can specify a path to a newer one with --with-openssl-dir.]) ])
  696. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  697. #include <openssl/opensslv.h>
  698. #include <openssl/evp.h>
  699. #if defined(OPENSSL_NO_EC) || defined(OPENSSL_NO_ECDH) || defined(OPENSSL_NO_ECDSA)
  700. #error "no ECC"
  701. #endif
  702. #if !defined(NID_X9_62_prime256v1) || !defined(NID_secp224r1)
  703. #error "curves unavailable"
  704. #endif
  705. ]], [[]])],
  706. [ : ],
  707. [ AC_MSG_ERROR([OpenSSL is built without full ECC support, including curves P256 and P224. You can specify a path to one with ECC support with --with-openssl-dir.]) ])
  708. AC_CHECK_MEMBERS([struct ssl_method_st.get_cipher_by_char], , ,
  709. [#include <openssl/ssl.h>
  710. ])
  711. AC_CHECK_FUNCS([ \
  712. SSL_SESSION_get_master_key \
  713. SSL_get_server_random \
  714. SSL_get_client_ciphers \
  715. SSL_get_client_random \
  716. SSL_CIPHER_find \
  717. TLS_method
  718. ])
  719. dnl Check if OpenSSL has scrypt implementation.
  720. AC_CHECK_FUNCS([ EVP_PBE_scrypt ])
  721. dnl Check if OpenSSL structures are opaque
  722. AC_CHECK_MEMBERS([SSL.state], , ,
  723. [#include <openssl/ssl.h>
  724. ])
  725. dnl Define the set of checks for KIST scheduler support.
  726. AC_DEFUN([CHECK_KIST_SUPPORT],[
  727. dnl KIST needs struct tcp_info and for certain members to exist.
  728. AC_CHECK_MEMBERS(
  729. [struct tcp_info.tcpi_unacked, struct tcp_info.tcpi_snd_mss],
  730. , ,[[#include <netinet/tcp.h>]])
  731. dnl KIST needs SIOCOUTQNSD to exist for an ioctl call.
  732. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
  733. #include <linux/sockios.h>
  734. #ifndef SIOCOUTQNSD
  735. #error
  736. #endif
  737. ])], have_siocoutqnsd=yes, have_siocoutqnsd=no)
  738. if test "x$have_siocoutqnsd" = "xyes"; then
  739. if test "x$ac_cv_member_struct_tcp_info_tcpi_unacked" = "xyes"; then
  740. if test "x$ac_cv_member_struct_tcp_info_tcpi_snd_mss" = "xyes"; then
  741. have_kist_support=yes
  742. fi
  743. fi
  744. fi
  745. ])
  746. dnl Now, trigger the check.
  747. CHECK_KIST_SUPPORT
  748. AS_IF([test "x$have_kist_support" = "xyes"],
  749. [AC_DEFINE(HAVE_KIST_SUPPORT, 1, [Defined if KIST scheduler is supported
  750. on this system])],
  751. [AC_MSG_NOTICE([KIST scheduler can't be used. Missing support.])])
  752. LIBS="$save_LIBS"
  753. LDFLAGS="$save_LDFLAGS"
  754. CPPFLAGS="$save_CPPFLAGS"
  755. dnl ------------------------------------------------------
  756. dnl Where do you live, zlib? And how do we call you?
  757. tor_zlib_pkg_redhat="zlib"
  758. tor_zlib_pkg_debian="zlib1g"
  759. tor_zlib_devpkg_redhat="zlib-devel"
  760. tor_zlib_devpkg_debian="zlib1g-dev"
  761. TOR_SEARCH_LIBRARY(zlib, $tryzlibdir, [-lz],
  762. [#include <zlib.h>],
  763. [const char * zlibVersion(void);],
  764. [zlibVersion();], [--with-zlib-dir],
  765. [/opt/zlib])
  766. if test "$enable_static_zlib" = "yes"; then
  767. if test "$tor_cv_library_zlib_dir" = "(system)"; then
  768. AC_MSG_ERROR("You must specify an explicit --with-zlib-dir=x option when
  769. using --enable-static-zlib")
  770. else
  771. TOR_ZLIB_LIBS="$TOR_LIBDIR_zlib/libz.a"
  772. fi
  773. else
  774. TOR_ZLIB_LIBS="-lz"
  775. fi
  776. AC_SUBST(TOR_ZLIB_LIBS)
  777. dnl ------------------------------------------------------
  778. dnl Where we do we find lzma?
  779. AC_ARG_ENABLE(lzma,
  780. AS_HELP_STRING(--enable-lzma, [enable support for the LZMA compression scheme.]),
  781. [case "${enableval}" in
  782. "yes") lzma=true ;;
  783. "no") lzma=false ;;
  784. * ) AC_MSG_ERROR(bad value for --enable-lzma) ;;
  785. esac], [lzma=auto])
  786. if test "x$enable_lzma" = "xno"; then
  787. have_lzma=no;
  788. else
  789. PKG_CHECK_MODULES([LZMA],
  790. [liblzma],
  791. have_lzma=yes,
  792. have_lzma=no)
  793. if test "x$have_lzma" = "xno" ; then
  794. AC_MSG_WARN([Unable to find liblzma.])
  795. fi
  796. fi
  797. if test "x$have_lzma" = "xyes"; then
  798. AC_DEFINE(HAVE_LZMA,1,[Have LZMA])
  799. TOR_LZMA_CFLAGS="${LZMA_CFLAGS}"
  800. TOR_LZMA_LIBS="${LZMA_LIBS}"
  801. fi
  802. AC_SUBST(TOR_LZMA_CFLAGS)
  803. AC_SUBST(TOR_LZMA_LIBS)
  804. dnl ------------------------------------------------------
  805. dnl Where we do we find zstd?
  806. AC_ARG_ENABLE(zstd,
  807. AS_HELP_STRING(--enable-zstd, [enable support for the Zstandard compression scheme.]),
  808. [case "${enableval}" in
  809. "yes") zstd=true ;;
  810. "no") zstd=false ;;
  811. * ) AC_MSG_ERROR(bad value for --enable-zstd) ;;
  812. esac], [zstd=auto])
  813. if test "x$enable_zstd" = "xno"; then
  814. have_zstd=no;
  815. else
  816. PKG_CHECK_MODULES([ZSTD],
  817. [libzstd >= 1.1],
  818. have_zstd=yes,
  819. have_zstd=no)
  820. if test "x$have_zstd" = "xno" ; then
  821. AC_MSG_WARN([Unable to find libzstd.])
  822. fi
  823. fi
  824. if test "x$have_zstd" = "xyes"; then
  825. AC_DEFINE(HAVE_ZSTD,1,[Have Zstd])
  826. TOR_ZSTD_CFLAGS="${ZSTD_CFLAGS}"
  827. TOR_ZSTD_LIBS="${ZSTD_LIBS}"
  828. fi
  829. AC_SUBST(TOR_ZSTD_CFLAGS)
  830. AC_SUBST(TOR_ZSTD_LIBS)
  831. dnl ----------------------------------------------------------------------
  832. dnl Check if libcap is available for capabilities.
  833. tor_cap_pkg_debian="libcap2"
  834. tor_cap_pkg_redhat="libcap"
  835. tor_cap_devpkg_debian="libcap-dev"
  836. tor_cap_devpkg_redhat="libcap-devel"
  837. AC_CHECK_LIB([cap], [cap_init], [],
  838. AC_MSG_NOTICE([Libcap was not found. Capabilities will not be usable.])
  839. )
  840. AC_CHECK_FUNCS(cap_set_proc)
  841. dnl ---------------------------------------------------------------------
  842. dnl Now that we know about our major libraries, we can check for compiler
  843. dnl and linker hardening options. We need to do this with the libraries known,
  844. dnl since sometimes the linker will like an option but not be willing to
  845. dnl use it with a build of a library.
  846. all_ldflags_for_check="$TOR_LDFLAGS_zlib $TOR_LDFLAGS_openssl $TOR_LDFLAGS_libevent"
  847. all_libs_for_check="$TOR_ZLIB_LIBS $TOR_LIB_MATH $TOR_LIBEVENT_LIBS $TOR_OPENSSL_LIBS $TOR_SYSTEMD_LIBS $TOR_LIB_WS32 $TOR_LIB_GDI $TOR_LIB_USERENV $TOR_CAP_LIBS"
  848. CFLAGS_FTRAPV=
  849. CFLAGS_FWRAPV=
  850. CFLAGS_ASAN=
  851. CFLAGS_UBSAN=
  852. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
  853. #if !defined(__clang__)
  854. #error
  855. #endif])], have_clang=yes, have_clang=no)
  856. if test "x$enable_gcc_hardening" != "xno"; then
  857. CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=2"
  858. if test "x$have_clang" = "xyes"; then
  859. TOR_CHECK_CFLAGS(-Qunused-arguments)
  860. fi
  861. TOR_CHECK_CFLAGS(-fstack-protector-all, also_link)
  862. AS_VAR_PUSHDEF([can_compile], [tor_cv_cflags_-fstack-protector-all])
  863. AS_VAR_PUSHDEF([can_link], [tor_can_link_-fstack-protector-all])
  864. m4_ifdef([AS_VAR_IF],[
  865. AS_VAR_IF(can_compile, [yes],
  866. AS_VAR_IF(can_link, [yes],
  867. [],
  868. AC_MSG_ERROR([We tried to build with stack protection; it looks like your compiler supports it but your libc does not provide it. Are you missing libssp? (You can --disable-gcc-hardening to ignore this error.)]))
  869. )])
  870. AS_VAR_POPDEF([can_link])
  871. AS_VAR_POPDEF([can_compile])
  872. TOR_CHECK_CFLAGS(-Wstack-protector)
  873. TOR_CHECK_CFLAGS(--param ssp-buffer-size=1)
  874. if test "$bwin32" = "false" && test "$enable_libfuzzer" != "yes" && test "$enable_oss_fuzz" != "yes"; then
  875. TOR_CHECK_CFLAGS(-fPIE)
  876. TOR_CHECK_LDFLAGS(-pie, "$all_ldflags_for_check", "$all_libs_for_check")
  877. fi
  878. TOR_TRY_COMPILE_WITH_CFLAGS(-fwrapv, also_link, CFLAGS_FWRAPV="-fwrapv", true)
  879. fi
  880. if test "$fragile_hardening" = "yes"; then
  881. TOR_TRY_COMPILE_WITH_CFLAGS(-ftrapv, also_link, CFLAGS_FTRAPV="-ftrapv", true)
  882. if test "$tor_cv_cflags__ftrapv" = "yes" && test "$tor_can_link__ftrapv" != "yes"; then
  883. AC_MSG_WARN([The compiler supports -ftrapv, but for some reason I was not able to link with -ftrapv. Are you missing run-time support? Run-time hardening will not work as well as it should.])
  884. fi
  885. if test "$tor_cv_cflags__ftrapv" != "yes"; then
  886. AC_MSG_ERROR([You requested fragile hardening, but the compiler does not seem to support -ftrapv.])
  887. fi
  888. TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=address], also_link, CFLAGS_ASAN="-fsanitize=address", true)
  889. if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
  890. AC_MSG_ERROR([The compiler supports -fsanitize=address, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libubsan.*, and with Clang you need libclang_rt.ubsan*])
  891. fi
  892. TOR_TRY_COMPILE_WITH_CFLAGS([-fsanitize=undefined], also_link, CFLAGS_UBSAN="-fsanitize=undefined", true)
  893. if test "$tor_cv_cflags__fsanitize_address" = "yes" && test "$tor_can_link__fsanitize_address" != "yes"; then
  894. AC_MSG_ERROR([The compiler supports -fsanitize=undefined, but for some reason I was not able to link when using it. Are you missing run-time support? With GCC you need libasan.*, and with Clang you need libclang_rt.ubsan*])
  895. fi
  896. TOR_CHECK_CFLAGS([-fno-omit-frame-pointer])
  897. fi
  898. CFLAGS_BUGTRAP="$CFLAGS_FTRAPV $CFLAGS_ASAN $CFLAGS_UBSAN"
  899. CFLAGS_CONSTTIME="$CFLAGS_FWRAPV"
  900. mulodi_fixes_ftrapv=no
  901. if test "$have_clang" = "yes"; then
  902. saved_CFLAGS="$CFLAGS"
  903. CFLAGS="$CFLAGS $CFLAGS_FTRAPV"
  904. AC_MSG_CHECKING([whether clang -ftrapv can link a 64-bit int multiply])
  905. AC_LINK_IFELSE([
  906. AC_LANG_SOURCE([[
  907. #include <stdint.h>
  908. #include <stdlib.h>
  909. int main(int argc, char **argv)
  910. {
  911. int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
  912. * (int64_t)atoi(argv[3]);
  913. return x == 9;
  914. } ]])],
  915. [ftrapv_can_link=yes; AC_MSG_RESULT([yes])],
  916. [ftrapv_can_link=no; AC_MSG_RESULT([no])])
  917. if test "$ftrapv_can_link" = "no"; then
  918. AC_MSG_CHECKING([whether defining __mulodi4 fixes that])
  919. AC_LINK_IFELSE([
  920. AC_LANG_SOURCE([[
  921. #include <stdint.h>
  922. #include <stdlib.h>
  923. int64_t __mulodi4(int64_t a, int64_t b, int *overflow) {
  924. *overflow=0;
  925. return a;
  926. }
  927. int main(int argc, char **argv)
  928. {
  929. int64_t x = ((int64_t)atoi(argv[1])) * (int64_t)atoi(argv[2])
  930. * (int64_t)atoi(argv[3]);
  931. return x == 9;
  932. } ]])],
  933. [mulodi_fixes_ftrapv=yes; AC_MSG_RESULT([yes])],
  934. [mulodi_fixes_ftrapv=no; AC_MSG_RESULT([no])])
  935. fi
  936. CFLAGS="$saved_CFLAGS"
  937. fi
  938. AM_CONDITIONAL(ADD_MULODI4, test "$mulodi_fixes_ftrapv" = "yes")
  939. dnl These cflags add bunches of branches, and we haven't been able to
  940. dnl persuade ourselves that they're suitable for code that needs to be
  941. dnl constant time.
  942. AC_SUBST(CFLAGS_BUGTRAP)
  943. dnl These cflags are variant ones sutable for code that needs to be
  944. dnl constant-time.
  945. AC_SUBST(CFLAGS_CONSTTIME)
  946. if test "x$enable_linker_hardening" != "xno"; then
  947. TOR_CHECK_LDFLAGS(-z relro -z now, "$all_ldflags_for_check", "$all_libs_for_check")
  948. fi
  949. # For backtrace support
  950. TOR_CHECK_LDFLAGS(-rdynamic)
  951. dnl ------------------------------------------------------
  952. dnl Now see if we have a -fomit-frame-pointer compiler option.
  953. saved_CFLAGS="$CFLAGS"
  954. TOR_CHECK_CFLAGS(-fomit-frame-pointer)
  955. F_OMIT_FRAME_POINTER=''
  956. if test "$saved_CFLAGS" != "$CFLAGS"; then
  957. if test "$fragile_hardening" = "yes"; then
  958. F_OMIT_FRAME_POINTER='-fomit-frame-pointer'
  959. fi
  960. fi
  961. CFLAGS="$saved_CFLAGS"
  962. AC_SUBST(F_OMIT_FRAME_POINTER)
  963. dnl ------------------------------------------------------
  964. dnl If we are adding -fomit-frame-pointer (or if the compiler's doing it
  965. dnl for us, as GCC 4.6 and later do at many optimization levels), then
  966. dnl we should try to add -fasynchronous-unwind-tables so that our backtrace
  967. dnl code will work.
  968. TOR_CHECK_CFLAGS(-fasynchronous-unwind-tables)
  969. dnl ============================================================
  970. dnl Check for libseccomp
  971. if test "x$enable_seccomp" != "xno"; then
  972. AC_CHECK_HEADERS([seccomp.h])
  973. AC_SEARCH_LIBS(seccomp_init, [seccomp])
  974. fi
  975. dnl ============================================================
  976. dnl Check for libscrypt
  977. if test "x$enable_libscrypt" != "xno"; then
  978. AC_CHECK_HEADERS([libscrypt.h])
  979. AC_SEARCH_LIBS(libscrypt_scrypt, [scrypt])
  980. AC_CHECK_FUNCS([libscrypt_scrypt])
  981. fi
  982. dnl ============================================================
  983. dnl We need an implementation of curve25519.
  984. dnl set these defaults.
  985. build_curve25519_donna=no
  986. build_curve25519_donna_c64=no
  987. use_curve25519_donna=no
  988. use_curve25519_nacl=no
  989. CURVE25519_LIBS=
  990. dnl The best choice is using curve25519-donna-c64, but that requires
  991. dnl that we
  992. AC_CACHE_CHECK([whether we can use curve25519-donna-c64],
  993. tor_cv_can_use_curve25519_donna_c64,
  994. [AC_RUN_IFELSE(
  995. [AC_LANG_PROGRAM([dnl
  996. #include <stdint.h>
  997. typedef unsigned uint128_t __attribute__((mode(TI)));
  998. int func(uint64_t a, uint64_t b) {
  999. uint128_t c = ((uint128_t)a) * b;
  1000. int ok = ((uint64_t)(c>>96)) == 522859 &&
  1001. (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
  1002. (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
  1003. (((uint64_t)(c))&0xffffffffL) == 0;
  1004. return ok;
  1005. }
  1006. ], [dnl
  1007. int ok = func( ((uint64_t)2000000000) * 1000000000,
  1008. ((uint64_t)1234567890) << 24);
  1009. return !ok;
  1010. ])],
  1011. [tor_cv_can_use_curve25519_donna_c64=yes],
  1012. [tor_cv_can_use_curve25519_donna_c64=no],
  1013. [AC_LINK_IFELSE(
  1014. [AC_LANG_PROGRAM([dnl
  1015. #include <stdint.h>
  1016. typedef unsigned uint128_t __attribute__((mode(TI)));
  1017. int func(uint64_t a, uint64_t b) {
  1018. uint128_t c = ((uint128_t)a) * b;
  1019. int ok = ((uint64_t)(c>>96)) == 522859 &&
  1020. (((uint64_t)(c>>64))&0xffffffffL) == 3604448702L &&
  1021. (((uint64_t)(c>>32))&0xffffffffL) == 2351960064L &&
  1022. (((uint64_t)(c))&0xffffffffL) == 0;
  1023. return ok;
  1024. }
  1025. ], [dnl
  1026. int ok = func( ((uint64_t)2000000000) * 1000000000,
  1027. ((uint64_t)1234567890) << 24);
  1028. return !ok;
  1029. ])],
  1030. [tor_cv_can_use_curve25519_donna_c64=cross],
  1031. [tor_cv_can_use_curve25519_donna_c64=no])])])
  1032. AC_CHECK_HEADERS([crypto_scalarmult_curve25519.h \
  1033. nacl/crypto_scalarmult_curve25519.h])
  1034. AC_CACHE_CHECK([for nacl compiled with a fast curve25519 implementation],
  1035. tor_cv_can_use_curve25519_nacl,
  1036. [tor_saved_LIBS="$LIBS"
  1037. LIBS="$LIBS -lnacl"
  1038. AC_LINK_IFELSE(
  1039. [AC_LANG_PROGRAM([dnl
  1040. #ifdef HAVE_CRYPTO_SCALARMULT_CURVE25519_H
  1041. #include <crypto_scalarmult_curve25519.h>
  1042. #elif defined(HAVE_NACL_CRYPTO_SCALARMULT_CURVE25519_H)
  1043. #include <nacl/crypto_scalarmult_curve25519.h>
  1044. #endif
  1045. #ifdef crypto_scalarmult_curve25519_ref_BYTES
  1046. #error Hey, this is the reference implementation! That's not fast.
  1047. #endif
  1048. ], [
  1049. unsigned char *a, *b, *c; crypto_scalarmult_curve25519(a,b,c);
  1050. ])], [tor_cv_can_use_curve25519_nacl=yes],
  1051. [tor_cv_can_use_curve25519_nacl=no])
  1052. LIBS="$tor_saved_LIBS" ])
  1053. dnl Okay, now we need to figure out which one to actually use. Fall back
  1054. dnl to curve25519-donna.c
  1055. if test "x$tor_cv_can_use_curve25519_donna_c64" != "xno"; then
  1056. build_curve25519_donna_c64=yes
  1057. use_curve25519_donna=yes
  1058. elif test "x$tor_cv_can_use_curve25519_nacl" = "xyes"; then
  1059. use_curve25519_nacl=yes
  1060. CURVE25519_LIBS=-lnacl
  1061. else
  1062. build_curve25519_donna=yes
  1063. use_curve25519_donna=yes
  1064. fi
  1065. if test "x$use_curve25519_donna" = "xyes"; then
  1066. AC_DEFINE(USE_CURVE25519_DONNA, 1,
  1067. [Defined if we should use an internal curve25519_donna{,_c64} implementation])
  1068. fi
  1069. if test "x$use_curve25519_nacl" = "xyes"; then
  1070. AC_DEFINE(USE_CURVE25519_NACL, 1,
  1071. [Defined if we should use a curve25519 from nacl])
  1072. fi
  1073. AM_CONDITIONAL(BUILD_CURVE25519_DONNA,
  1074. test "x$build_curve25519_donna" = "xyes")
  1075. AM_CONDITIONAL(BUILD_CURVE25519_DONNA_C64,
  1076. test "x$build_curve25519_donna_c64" = "xyes")
  1077. AC_SUBST(CURVE25519_LIBS)
  1078. dnl Make sure to enable support for large off_t if available.
  1079. AC_SYS_LARGEFILE
  1080. AC_CHECK_HEADERS([assert.h \
  1081. errno.h \
  1082. fcntl.h \
  1083. signal.h \
  1084. string.h \
  1085. sys/capability.h \
  1086. sys/fcntl.h \
  1087. sys/stat.h \
  1088. sys/time.h \
  1089. sys/types.h \
  1090. time.h \
  1091. unistd.h \
  1092. arpa/inet.h \
  1093. crt_externs.h \
  1094. execinfo.h \
  1095. gnu/libc-version.h \
  1096. grp.h \
  1097. ifaddrs.h \
  1098. inttypes.h \
  1099. limits.h \
  1100. linux/types.h \
  1101. machine/limits.h \
  1102. malloc.h \
  1103. malloc/malloc.h \
  1104. malloc_np.h \
  1105. netdb.h \
  1106. netinet/in.h \
  1107. netinet/in6.h \
  1108. pwd.h \
  1109. readpassphrase.h \
  1110. stdint.h \
  1111. stdatomic.h \
  1112. sys/eventfd.h \
  1113. sys/file.h \
  1114. sys/ioctl.h \
  1115. sys/limits.h \
  1116. sys/mman.h \
  1117. sys/param.h \
  1118. sys/prctl.h \
  1119. sys/random.h \
  1120. sys/resource.h \
  1121. sys/select.h \
  1122. sys/socket.h \
  1123. sys/statvfs.h \
  1124. sys/syscall.h \
  1125. sys/sysctl.h \
  1126. sys/syslimits.h \
  1127. sys/time.h \
  1128. sys/types.h \
  1129. sys/un.h \
  1130. sys/utime.h \
  1131. sys/wait.h \
  1132. syslog.h \
  1133. utime.h])
  1134. AC_CHECK_HEADERS(sys/param.h)
  1135. AC_CHECK_HEADERS(net/if.h, net_if_found=1, net_if_found=0,
  1136. [#ifdef HAVE_SYS_TYPES_H
  1137. #include <sys/types.h>
  1138. #endif
  1139. #ifdef HAVE_SYS_SOCKET_H
  1140. #include <sys/socket.h>
  1141. #endif])
  1142. AC_CHECK_HEADERS(net/pfvar.h, net_pfvar_found=1, net_pfvar_found=0,
  1143. [#ifdef HAVE_SYS_TYPES_H
  1144. #include <sys/types.h>
  1145. #endif
  1146. #ifdef HAVE_SYS_SOCKET_H
  1147. #include <sys/socket.h>
  1148. #endif
  1149. #ifdef HAVE_NET_IF_H
  1150. #include <net/if.h>
  1151. #endif
  1152. #ifdef HAVE_NETINET_IN_H
  1153. #include <netinet/in.h>
  1154. #endif])
  1155. AC_CHECK_HEADERS(linux/if.h,[],[],
  1156. [
  1157. #ifdef HAVE_SYS_SOCKET_H
  1158. #include <sys/socket.h>
  1159. #endif
  1160. ])
  1161. AC_CHECK_HEADERS(linux/netfilter_ipv4.h,
  1162. linux_netfilter_ipv4=1, linux_netfilter_ipv4=0,
  1163. [#ifdef HAVE_SYS_TYPES_H
  1164. #include <sys/types.h>
  1165. #endif
  1166. #ifdef HAVE_SYS_SOCKET_H
  1167. #include <sys/socket.h>
  1168. #endif
  1169. #ifdef HAVE_LIMITS_H
  1170. #include <limits.h>
  1171. #endif
  1172. #ifdef HAVE_LINUX_TYPES_H
  1173. #include <linux/types.h>
  1174. #endif
  1175. #ifdef HAVE_NETINET_IN6_H
  1176. #include <netinet/in6.h>
  1177. #endif
  1178. #ifdef HAVE_NETINET_IN_H
  1179. #include <netinet/in.h>
  1180. #endif])
  1181. AC_CHECK_HEADERS(linux/netfilter_ipv6/ip6_tables.h,
  1182. linux_netfilter_ipv6_ip6_tables=1, linux_netfilter_ipv6_ip6_tables=0,
  1183. [#ifdef HAVE_SYS_TYPES_H
  1184. #include <sys/types.h>
  1185. #endif
  1186. #ifdef HAVE_SYS_SOCKET_H
  1187. #include <sys/socket.h>
  1188. #endif
  1189. #ifdef HAVE_LIMITS_H
  1190. #include <limits.h>
  1191. #endif
  1192. #ifdef HAVE_LINUX_TYPES_H
  1193. #include <linux/types.h>
  1194. #endif
  1195. #ifdef HAVE_NETINET_IN6_H
  1196. #include <netinet/in6.h>
  1197. #endif
  1198. #ifdef HAVE_NETINET_IN_H
  1199. #include <netinet/in.h>
  1200. #endif
  1201. #ifdef HAVE_LINUX_IF_H
  1202. #include <linux/if.h>
  1203. #endif])
  1204. transparent_ok=0
  1205. if test "x$net_if_found" = "x1" && test "x$net_pfvar_found" = "x1"; then
  1206. transparent_ok=1
  1207. fi
  1208. if test "x$linux_netfilter_ipv4" = "x1"; then
  1209. transparent_ok=1
  1210. fi
  1211. if test "x$linux_netfilter_ipv6_ip6_tables" = "x1"; then
  1212. transparent_ok=1
  1213. fi
  1214. if test "x$transparent_ok" = "x1"; then
  1215. AC_DEFINE(USE_TRANSPARENT, 1, "Define to enable transparent proxy support")
  1216. else
  1217. AC_MSG_NOTICE([Transparent proxy support enabled, but missing headers.])
  1218. fi
  1219. AC_CHECK_MEMBERS([struct timeval.tv_sec], , ,
  1220. [#ifdef HAVE_SYS_TYPES_H
  1221. #include <sys/types.h>
  1222. #endif
  1223. #ifdef HAVE_SYS_TIME_H
  1224. #include <sys/time.h>
  1225. #endif])
  1226. dnl In case we aren't given a working stdint.h, we'll need to grow our own.
  1227. dnl Watch out.
  1228. AC_CHECK_SIZEOF(int8_t)
  1229. AC_CHECK_SIZEOF(int16_t)
  1230. AC_CHECK_SIZEOF(int32_t)
  1231. AC_CHECK_SIZEOF(int64_t)
  1232. AC_CHECK_SIZEOF(uint8_t)
  1233. AC_CHECK_SIZEOF(uint16_t)
  1234. AC_CHECK_SIZEOF(uint32_t)
  1235. AC_CHECK_SIZEOF(uint64_t)
  1236. AC_CHECK_SIZEOF(intptr_t)
  1237. AC_CHECK_SIZEOF(uintptr_t)
  1238. dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
  1239. AC_CHECK_SIZEOF(char)
  1240. AC_CHECK_SIZEOF(short)
  1241. AC_CHECK_SIZEOF(int)
  1242. AC_CHECK_SIZEOF(long)
  1243. AC_CHECK_SIZEOF(long long)
  1244. AC_CHECK_SIZEOF(__int64)
  1245. AC_CHECK_SIZEOF(void *)
  1246. AC_CHECK_SIZEOF(time_t)
  1247. AC_CHECK_SIZEOF(size_t)
  1248. AC_CHECK_SIZEOF(pid_t)
  1249. AC_CHECK_TYPES([uint, u_char, ssize_t])
  1250. AC_PC_FROM_UCONTEXT([:])
  1251. dnl used to include sockaddr_storage, but everybody has that.
  1252. AC_CHECK_TYPES([struct in6_addr, struct sockaddr_in6, sa_family_t], , ,
  1253. [#ifdef HAVE_SYS_TYPES_H
  1254. #include <sys/types.h>
  1255. #endif
  1256. #ifdef HAVE_NETINET_IN_H
  1257. #include <netinet/in.h>
  1258. #endif
  1259. #ifdef HAVE_NETINET_IN6_H
  1260. #include <netinet/in6.h>
  1261. #endif
  1262. #ifdef HAVE_SYS_SOCKET_H
  1263. #include <sys/socket.h>
  1264. #endif
  1265. #ifdef _WIN32
  1266. #define _WIN32_WINNT 0x0501
  1267. #define WIN32_LEAN_AND_MEAN
  1268. #include <winsock2.h>
  1269. #include <ws2tcpip.h>
  1270. #endif
  1271. ])
  1272. AC_CHECK_MEMBERS([struct in6_addr.s6_addr32, struct in6_addr.s6_addr16, struct sockaddr_in.sin_len, struct sockaddr_in6.sin6_len], , ,
  1273. [#ifdef HAVE_SYS_TYPES_H
  1274. #include <sys/types.h>
  1275. #endif
  1276. #ifdef HAVE_NETINET_IN_H
  1277. #include <netinet/in.h>
  1278. #endif
  1279. #ifdef HAVE_NETINET_IN6_H
  1280. #include <netinet/in6.h>
  1281. #endif
  1282. #ifdef HAVE_SYS_SOCKET_H
  1283. #include <sys/socket.h>
  1284. #endif
  1285. #ifdef _WIN32
  1286. #define _WIN32_WINNT 0x0501
  1287. #define WIN32_LEAN_AND_MEAN
  1288. #include <winsock2.h>
  1289. #include <ws2tcpip.h>
  1290. #endif
  1291. ])
  1292. AC_CHECK_TYPES([rlim_t], , ,
  1293. [#ifdef HAVE_SYS_TYPES_H
  1294. #include <sys/types.h>
  1295. #endif
  1296. #ifdef HAVE_SYS_TIME_H
  1297. #include <sys/time.h>
  1298. #endif
  1299. #ifdef HAVE_SYS_RESOURCE_H
  1300. #include <sys/resource.h>
  1301. #endif
  1302. ])
  1303. AX_CHECK_SIGN([time_t],
  1304. [ : ],
  1305. [ : ], [
  1306. #ifdef HAVE_SYS_TYPES_H
  1307. #include <sys/types.h>
  1308. #endif
  1309. #ifdef HAVE_SYS_TIME_H
  1310. #include <sys/time.h>
  1311. #endif
  1312. #ifdef HAVE_TIME_H
  1313. #include <time.h>
  1314. #endif
  1315. ])
  1316. if test "$ax_cv_decl_time_t_signed" = "no"; then
  1317. AC_MSG_ERROR([You have an unsigned time_t; Tor does not support that. Please tell the Tor developers about your interesting platform.])
  1318. fi
  1319. AX_CHECK_SIGN([size_t],
  1320. [ tor_cv_size_t_signed=yes ],
  1321. [ tor_cv_size_t_signed=no ], [
  1322. #ifdef HAVE_SYS_TYPES_H
  1323. #include <sys/types.h>
  1324. #endif
  1325. ])
  1326. if test "$ax_cv_decl_size_t_signed" = "yes"; then
  1327. AC_MSG_ERROR([You have a signed size_t; that's grossly nonconformant.])
  1328. fi
  1329. AX_CHECK_SIGN([enum always],
  1330. [ AC_DEFINE(ENUM_VALS_ARE_SIGNED, 1, [Define if enum is always signed]) ],
  1331. [ : ], [
  1332. enum always { AAA, BBB, CCC };
  1333. ])
  1334. AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
  1335. #ifdef HAVE_SYS_SOCKET_H
  1336. #include <sys/socket.h>
  1337. #endif
  1338. ])
  1339. # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
  1340. AC_CHECK_SIZEOF(cell_t)
  1341. # Now make sure that NULL can be represented as zero bytes.
  1342. AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
  1343. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1344. [[#include <stdlib.h>
  1345. #include <string.h>
  1346. #include <stdio.h>
  1347. #ifdef HAVE_STDDEF_H
  1348. #include <stddef.h>
  1349. #endif
  1350. int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
  1351. return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
  1352. [tor_cv_null_is_zero=yes],
  1353. [tor_cv_null_is_zero=no],
  1354. [tor_cv_null_is_zero=cross])])
  1355. if test "$tor_cv_null_is_zero" = "cross"; then
  1356. # Cross-compiling; let's hope that the target isn't raving mad.
  1357. AC_MSG_NOTICE([Cross-compiling: we'll assume that NULL is represented as a sequence of 0-valued bytes.])
  1358. fi
  1359. if test "$tor_cv_null_is_zero" != "no"; then
  1360. AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
  1361. [Define to 1 iff memset(0) sets pointers to NULL])
  1362. fi
  1363. AC_CACHE_CHECK([whether memset(0) sets doubles to 0.0], tor_cv_dbl0_is_zero,
  1364. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1365. [[#include <stdlib.h>
  1366. #include <string.h>
  1367. #include <stdio.h>
  1368. #ifdef HAVE_STDDEF_H
  1369. #include <stddef.h>
  1370. #endif
  1371. int main () { double d1,d2; d1=0; memset(&d2,0,sizeof(d2));
  1372. return memcmp(&d1,&d2,sizeof(d1))?1:0; }]])],
  1373. [tor_cv_dbl0_is_zero=yes],
  1374. [tor_cv_dbl0_is_zero=no],
  1375. [tor_cv_dbl0_is_zero=cross])])
  1376. if test "$tor_cv_dbl0_is_zero" = "cross"; then
  1377. # Cross-compiling; let's hope that the target isn't raving mad.
  1378. AC_MSG_NOTICE([Cross-compiling: we'll assume that 0.0 can be represented as a sequence of 0-valued bytes.])
  1379. fi
  1380. if test "$tor_cv_dbl0_is_zero" != "no"; then
  1381. AC_DEFINE([DOUBLE_0_REP_IS_ZERO_BYTES], 1,
  1382. [Define to 1 iff memset(0) sets doubles to 0.0])
  1383. fi
  1384. # And what happens when we malloc zero?
  1385. AC_CACHE_CHECK([whether we can malloc(0) safely.], tor_cv_malloc_zero_works,
  1386. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1387. [[#include <stdlib.h>
  1388. #include <string.h>
  1389. #include <stdio.h>
  1390. #ifdef HAVE_STDDEF_H
  1391. #include <stddef.h>
  1392. #endif
  1393. int main () { return malloc(0)?0:1; }]])],
  1394. [tor_cv_malloc_zero_works=yes],
  1395. [tor_cv_malloc_zero_works=no],
  1396. [tor_cv_malloc_zero_works=cross])])
  1397. if test "$tor_cv_malloc_zero_works" = "cross"; then
  1398. # Cross-compiling; let's hope that the target isn't raving mad.
  1399. AC_MSG_NOTICE([Cross-compiling: we'll assume that we need to check malloc() arguments for 0.])
  1400. fi
  1401. if test "$tor_cv_malloc_zero_works" = "yes"; then
  1402. AC_DEFINE([MALLOC_ZERO_WORKS], 1,
  1403. [Define to 1 iff malloc(0) returns a pointer])
  1404. fi
  1405. # whether we seem to be in a 2s-complement world.
  1406. AC_CACHE_CHECK([whether we are using 2s-complement arithmetic], tor_cv_twos_complement,
  1407. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1408. [[int main () { int problem = ((-99) != (~99)+1);
  1409. return problem ? 1 : 0; }]])],
  1410. [tor_cv_twos_complement=yes],
  1411. [tor_cv_twos_complement=no],
  1412. [tor_cv_twos_complement=cross])])
  1413. if test "$tor_cv_twos_complement" = "cross"; then
  1414. # Cross-compiling; let's hope that the target isn't raving mad.
  1415. AC_MSG_NOTICE([Cross-compiling: we'll assume that negative integers are represented with two's complement.])
  1416. fi
  1417. if test "$tor_cv_twos_complement" != "no"; then
  1418. AC_DEFINE([USING_TWOS_COMPLEMENT], 1,
  1419. [Define to 1 iff we represent negative integers with
  1420. two's complement])
  1421. fi
  1422. # What does shifting a negative value do?
  1423. AC_CACHE_CHECK([whether right-shift on negative values does sign-extension], tor_cv_sign_extend,
  1424. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  1425. [[int main () { int okay = (-60 >> 8) == -1; return okay ? 0 : 1; }]])],
  1426. [tor_cv_sign_extend=yes],
  1427. [tor_cv_sign_extend=no],
  1428. [tor_cv_sign_extend=cross])])
  1429. if test "$tor_cv_sign_extend" = "cross"; then
  1430. # Cross-compiling; let's hope that the target isn't raving mad.
  1431. AC_MSG_NOTICE([Cross-compiling: we'll assume that right-shifting negative integers causes sign-extension])
  1432. fi
  1433. if test "$tor_cv_sign_extend" != "no"; then
  1434. AC_DEFINE([RSHIFT_DOES_SIGN_EXTEND], 1,
  1435. [Define to 1 iff right-shifting a negative value performs sign-extension])
  1436. fi
  1437. # Is uint8_t the same type as unsigned char?
  1438. AC_CACHE_CHECK([whether uint8_t is the same type as unsigned char], tor_cv_uint8_uchar,
  1439. [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  1440. #include <stdint.h>
  1441. extern uint8_t c;
  1442. unsigned char c;]])],
  1443. [tor_cv_uint8_uchar=yes],
  1444. [tor_cv_uint8_uchar=no],
  1445. [tor_cv_uint8_uchar=cross])])
  1446. if test "$tor_cv_uint8_uchar" = "cross"; then
  1447. AC_MSG_NOTICE([Cross-compiling: we'll assume that uint8_t is the same type as unsigned char])
  1448. fi
  1449. if test "$tor_cv_uint8_uchar" = "no"; then
  1450. AC_MSG_ERROR([We assume that uint8_t is the same type as unsigned char, but your compiler disagrees.])
  1451. fi
  1452. # Whether we should use the dmalloc memory allocation debugging library.
  1453. AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
  1454. AC_ARG_WITH(dmalloc,
  1455. AS_HELP_STRING(--with-dmalloc, [use debug memory allocation library]),
  1456. [if [[ "$withval" = "yes" ]]; then
  1457. dmalloc=1
  1458. AC_MSG_RESULT(yes)
  1459. else
  1460. dmalloc=1
  1461. AC_MSG_RESULT(no)
  1462. fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
  1463. )
  1464. if [[ $dmalloc -eq 1 ]]; then
  1465. AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
  1466. AC_SEARCH_LIBS(dmalloc_malloc, [dmallocth dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
  1467. AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
  1468. AC_CHECK_FUNCS(dmalloc_strdup dmalloc_strndup)
  1469. fi
  1470. AC_ARG_WITH(tcmalloc,
  1471. AS_HELP_STRING(--with-tcmalloc, [use tcmalloc memory allocation library]),
  1472. [ tcmalloc=yes ], [ tcmalloc=no ])
  1473. if test "x$tcmalloc" = "xyes"; then
  1474. LDFLAGS="-ltcmalloc $LDFLAGS"
  1475. fi
  1476. using_custom_malloc=no
  1477. if test "x$enable_openbsd_malloc" = "xyes"; then
  1478. using_custom_malloc=yes
  1479. fi
  1480. if test "x$tcmalloc" = "xyes"; then
  1481. using_custom_malloc=yes
  1482. fi
  1483. if test "$using_custom_malloc" = "no"; then
  1484. AC_CHECK_FUNCS(mallinfo)
  1485. fi
  1486. # By default, we're going to assume we don't have mlockall()
  1487. # bionic and other platforms have various broken mlockall subsystems.
  1488. # Some systems don't have a working mlockall, some aren't linkable,
  1489. # and some have it but don't declare it.
  1490. AC_CHECK_FUNCS(mlockall)
  1491. AC_CHECK_DECLS([mlockall], , , [
  1492. #ifdef HAVE_SYS_MMAN_H
  1493. #include <sys/mman.h>
  1494. #endif])
  1495. # Some MinGW environments don't have getpagesize in unistd.h. We don't use
  1496. # AC_CHECK_FUNCS(getpagesize), because other environments rename getpagesize
  1497. # using macros
  1498. AC_CHECK_DECLS([getpagesize], , , [
  1499. #ifdef HAVE_UNISTD_H
  1500. #include <unistd.h>
  1501. #endif])
  1502. # Allow user to specify an alternate syslog facility
  1503. AC_ARG_WITH(syslog-facility,
  1504. AS_HELP_STRING(--with-syslog-facility=LOG, [syslog facility to use (default=LOG_DAEMON)]),
  1505. syslog_facility="$withval", syslog_facility="LOG_DAEMON")
  1506. AC_DEFINE_UNQUOTED(LOGFACILITY,$syslog_facility,[name of the syslog facility])
  1507. AC_SUBST(LOGFACILITY)
  1508. # Check if we have getresuid and getresgid
  1509. AC_CHECK_FUNCS(getresuid getresgid)
  1510. # Check for gethostbyname_r in all its glorious incompatible versions.
  1511. # (This logic is based on that in Python's configure.in)
  1512. AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
  1513. [Define this if you have any gethostbyname_r()])
  1514. AC_CHECK_FUNC(gethostbyname_r, [
  1515. AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
  1516. OLD_CFLAGS=$CFLAGS
  1517. CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
  1518. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  1519. #include <netdb.h>
  1520. ]], [[
  1521. char *cp1, *cp2;
  1522. struct hostent *h1, *h2;
  1523. int i1, i2;
  1524. (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
  1525. ]])],[
  1526. AC_DEFINE(HAVE_GETHOSTBYNAME_R)
  1527. AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
  1528. [Define this if gethostbyname_r takes 6 arguments])
  1529. AC_MSG_RESULT(6)
  1530. ], [
  1531. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  1532. #include <netdb.h>
  1533. ]], [[
  1534. char *cp1, *cp2;
  1535. struct hostent *h1;
  1536. int i1, i2;
  1537. (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
  1538. ]])], [
  1539. AC_DEFINE(HAVE_GETHOSTBYNAME_R)
  1540. AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
  1541. [Define this if gethostbyname_r takes 5 arguments])
  1542. AC_MSG_RESULT(5)
  1543. ], [
  1544. AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  1545. #include <netdb.h>
  1546. ]], [[
  1547. char *cp1;
  1548. struct hostent *h1;
  1549. struct hostent_data hd;
  1550. (void) gethostbyname_r(cp1,h1,&hd);
  1551. ]])], [
  1552. AC_DEFINE(HAVE_GETHOSTBYNAME_R)
  1553. AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
  1554. [Define this if gethostbyname_r takes 3 arguments])
  1555. AC_MSG_RESULT(3)
  1556. ], [
  1557. AC_MSG_RESULT(0)
  1558. ])
  1559. ])
  1560. ])
  1561. CFLAGS=$OLD_CFLAGS
  1562. ])
  1563. AC_CACHE_CHECK([whether the C compiler supports __func__],
  1564. tor_cv_have_func_macro,
  1565. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  1566. #include <stdio.h>
  1567. int main(int c, char **v) { puts(__func__); }])],
  1568. tor_cv_have_func_macro=yes,
  1569. tor_cv_have_func_macro=no))
  1570. AC_CACHE_CHECK([whether the C compiler supports __FUNC__],
  1571. tor_cv_have_FUNC_macro,
  1572. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  1573. #include <stdio.h>
  1574. int main(int c, char **v) { puts(__FUNC__); }])],
  1575. tor_cv_have_FUNC_macro=yes,
  1576. tor_cv_have_FUNC_macro=no))
  1577. AC_CACHE_CHECK([whether the C compiler supports __FUNCTION__],
  1578. tor_cv_have_FUNCTION_macro,
  1579. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  1580. #include <stdio.h>
  1581. int main(int c, char **v) { puts(__FUNCTION__); }])],
  1582. tor_cv_have_FUNCTION_macro=yes,
  1583. tor_cv_have_FUNCTION_macro=no))
  1584. AC_CACHE_CHECK([whether we have extern char **environ already declared],
  1585. tor_cv_have_environ_declared,
  1586. AC_COMPILE_IFELSE([AC_LANG_SOURCE([
  1587. #ifdef HAVE_UNISTD_H
  1588. #include <unistd.h>
  1589. #endif
  1590. #include <stdlib.h>
  1591. int main(int c, char **v) { char **t = environ; }])],
  1592. tor_cv_have_environ_declared=yes,
  1593. tor_cv_have_environ_declared=no))
  1594. if test "$tor_cv_have_func_macro" = "yes"; then
  1595. AC_DEFINE(HAVE_MACRO__func__, 1, [Defined if the compiler supports __func__])
  1596. fi
  1597. if test "$tor_cv_have_FUNC_macro" = "yes"; then
  1598. AC_DEFINE(HAVE_MACRO__FUNC__, 1, [Defined if the compiler supports __FUNC__])
  1599. fi
  1600. if test "$tor_cv_have_FUNCTION_macro" = "yes"; then
  1601. AC_DEFINE(HAVE_MACRO__FUNCTION__, 1,
  1602. [Defined if the compiler supports __FUNCTION__])
  1603. fi
  1604. if test "$tor_cv_have_environ_declared" = "yes"; then
  1605. AC_DEFINE(HAVE_EXTERN_ENVIRON_DECLARED, 1,
  1606. [Defined if we have extern char **environ already declared])
  1607. fi
  1608. # $prefix stores the value of the --prefix command line option, or
  1609. # NONE if the option wasn't set. In the case that it wasn't set, make
  1610. # it be the default, so that we can use it to expand directories now.
  1611. if test "x$prefix" = "xNONE"; then
  1612. prefix=$ac_default_prefix
  1613. fi
  1614. # and similarly for $exec_prefix
  1615. if test "x$exec_prefix" = "xNONE"; then
  1616. exec_prefix=$prefix
  1617. fi
  1618. if test "x$BUILDDIR" = "x"; then
  1619. BUILDDIR=`pwd`
  1620. fi
  1621. AC_SUBST(BUILDDIR)
  1622. AH_TEMPLATE([BUILDDIR],[tor's build directory])
  1623. AC_DEFINE_UNQUOTED(BUILDDIR,"$BUILDDIR")
  1624. if test "x$CONFDIR" = "x"; then
  1625. CONFDIR=`eval echo $sysconfdir/tor`
  1626. fi
  1627. AC_SUBST(CONFDIR)
  1628. AH_TEMPLATE([CONFDIR],[tor's configuration directory])
  1629. AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
  1630. BINDIR=`eval echo $bindir`
  1631. AC_SUBST(BINDIR)
  1632. LOCALSTATEDIR=`eval echo $localstatedir`
  1633. AC_SUBST(LOCALSTATEDIR)
  1634. if test "$bwin32" = "true"; then
  1635. # Test if the linker supports the --nxcompat and --dynamicbase options
  1636. # for Windows
  1637. save_LDFLAGS="$LDFLAGS"
  1638. LDFLAGS="-Wl,--nxcompat -Wl,--dynamicbase"
  1639. AC_MSG_CHECKING([whether the linker supports DllCharacteristics])
  1640. AC_LINK_IFELSE([AC_LANG_PROGRAM([])],
  1641. [AC_MSG_RESULT([yes])]
  1642. [save_LDFLAGS="$save_LDFLAGS $LDFLAGS"],
  1643. [AC_MSG_RESULT([no])]
  1644. )
  1645. LDFLAGS="$save_LDFLAGS"
  1646. fi
  1647. # Set CFLAGS _after_ all the above checks, since our warnings are stricter
  1648. # than autoconf's macros like.
  1649. if test "$GCC" = "yes"; then
  1650. # Disable GCC's strict aliasing checks. They are an hours-to-debug
  1651. # accident waiting to happen.
  1652. CFLAGS="$CFLAGS -Wall -fno-strict-aliasing"
  1653. else
  1654. # Override optimization level for non-gcc compilers
  1655. CFLAGS="$CFLAGS -O"
  1656. enable_gcc_warnings=no
  1657. enable_gcc_warnings_advisory=no
  1658. fi
  1659. # Warnings implies advisory-warnings and -Werror.
  1660. if test "$enable_gcc_warnings" = "yes"; then
  1661. enable_gcc_warnings_advisory=yes
  1662. enable_fatal_warnings=yes
  1663. fi
  1664. # OS X Lion started deprecating the system openssl. Let's just disable
  1665. # all deprecation warnings on OS X. Also, to potentially make the binary
  1666. # a little smaller, let's enable dead_strip.
  1667. case "$host_os" in
  1668. darwin*)
  1669. CFLAGS="$CFLAGS -Wno-deprecated-declarations"
  1670. LDFLAGS="$LDFLAGS -dead_strip" ;;
  1671. esac
  1672. # Add some more warnings which we use in development but not in the
  1673. # released versions. (Some relevant gcc versions can't handle these.)
  1674. #
  1675. # Note that we have to do this near the end of the autoconf process, or
  1676. # else we may run into problems when these warnings hit on the testing C
  1677. # programs that autoconf wants to build.
  1678. if test "x$enable_gcc_warnings_advisory" != "xno"; then
  1679. case "$host" in
  1680. *-*-openbsd* | *-*-bitrig*)
  1681. # Some OpenBSD versions (like 4.8) have -Wsystem-headers by default.
  1682. # That's fine, except that the headers don't pass -Wredundant-decls.
  1683. # Therefore, let's disable -Wsystem-headers when we're building
  1684. # with maximal warnings on OpenBSD.
  1685. CFLAGS="$CFLAGS -Wno-system-headers" ;;
  1686. esac
  1687. # GCC4.3 users once report trouble with -Wstrict-overflow=5. GCC5 users
  1688. # have it work better.
  1689. # CFLAGS="$CFLAGS -Wstrict-overflow=1"
  1690. # This warning was added in gcc 4.3, but it appears to generate
  1691. # spurious warnings in gcc 4.4. I don't know if it works in 4.5.
  1692. #CFLAGS="$CFLAGS -Wlogical-op"
  1693. m4_foreach_w([warning_flag], [
  1694. -Waddress
  1695. -Waddress-of-array-temporary
  1696. -Waddress-of-temporary
  1697. -Wambiguous-macro
  1698. -Wanonymous-pack-parens
  1699. -Warc
  1700. -Warc-abi
  1701. -Warc-bridge-casts-disallowed-in-nonarc
  1702. -Warc-maybe-repeated-use-of-weak
  1703. -Warc-performSelector-leaks
  1704. -Warc-repeated-use-of-weak
  1705. -Warray-bounds
  1706. -Warray-bounds-pointer-arithmetic
  1707. -Wasm
  1708. -Wasm-operand-widths
  1709. -Watomic-properties
  1710. -Watomic-property-with-user-defined-accessor
  1711. -Wauto-import
  1712. -Wauto-storage-class
  1713. -Wauto-var-id
  1714. -Wavailability
  1715. -Wbackslash-newline-escape
  1716. -Wbad-array-new-length
  1717. -Wbind-to-temporary-copy
  1718. -Wbitfield-constant-conversion
  1719. -Wbool-conversion
  1720. -Wbool-conversions
  1721. -Wbuiltin-requires-header
  1722. -Wchar-align
  1723. -Wcompare-distinct-pointer-types
  1724. -Wcomplex-component-init
  1725. -Wconditional-type-mismatch
  1726. -Wconfig-macros
  1727. -Wconstant-conversion
  1728. -Wconstant-logical-operand
  1729. -Wconstexpr-not-const
  1730. -Wcustom-atomic-properties
  1731. -Wdangling-field
  1732. -Wdangling-initializer-list
  1733. -Wdate-time
  1734. -Wdelegating-ctor-cycles
  1735. -Wdeprecated-implementations
  1736. -Wdeprecated-register
  1737. -Wdirect-ivar-access
  1738. -Wdiscard-qual
  1739. -Wdistributed-object-modifiers
  1740. -Wdivision-by-zero
  1741. -Wdollar-in-identifier-extension
  1742. -Wdouble-promotion
  1743. -Wduplicate-decl-specifier
  1744. -Wduplicate-enum
  1745. -Wduplicate-method-arg
  1746. -Wduplicate-method-match
  1747. -Wduplicated-cond
  1748. -Wdynamic-class-memaccess
  1749. -Wembedded-directive
  1750. -Wempty-translation-unit
  1751. -Wenum-conversion
  1752. -Wexit-time-destructors
  1753. -Wexplicit-ownership-type
  1754. -Wextern-initializer
  1755. -Wextra
  1756. -Wextra-semi
  1757. -Wextra-tokens
  1758. -Wflexible-array-extensions
  1759. -Wfloat-conversion
  1760. -Wformat-non-iso
  1761. -Wfour-char-constants
  1762. -Wgcc-compat
  1763. -Wglobal-constructors
  1764. -Wgnu-array-member-paren-init
  1765. -Wgnu-designator
  1766. -Wgnu-static-float-init
  1767. -Wheader-guard
  1768. -Wheader-hygiene
  1769. -Widiomatic-parentheses
  1770. -Wignored-attributes
  1771. -Wimplicit-atomic-properties
  1772. -Wimplicit-conversion-floating-point-to-bool
  1773. -Wimplicit-exception-spec-mismatch
  1774. -Wimplicit-fallthrough
  1775. -Wimplicit-fallthrough-per-function
  1776. -Wimplicit-retain-self
  1777. -Wimport-preprocessor-directive-pedantic
  1778. -Wincompatible-library-redeclaration
  1779. -Wincompatible-pointer-types-discards-qualifiers
  1780. -Wincomplete-implementation
  1781. -Wincomplete-module
  1782. -Wincomplete-umbrella
  1783. -Winit-self
  1784. -Wint-conversions
  1785. -Wint-to-void-pointer-cast
  1786. -Winteger-overflow
  1787. -Winvalid-constexpr
  1788. -Winvalid-iboutlet
  1789. -Winvalid-noreturn
  1790. -Winvalid-pp-token
  1791. -Winvalid-source-encoding
  1792. -Winvalid-token-paste
  1793. -Wknr-promoted-parameter
  1794. -Wlarge-by-value-copy
  1795. -Wliteral-conversion
  1796. -Wliteral-range
  1797. -Wlocal-type-template-args
  1798. -Wlogical-op
  1799. -Wloop-analysis
  1800. -Wmain-return-type
  1801. -Wmalformed-warning-check
  1802. -Wmethod-signatures
  1803. -Wmicrosoft
  1804. -Wmicrosoft-exists
  1805. -Wmismatched-parameter-types
  1806. -Wmismatched-return-types
  1807. -Wmissing-field-initializers
  1808. -Wmissing-format-attribute
  1809. -Wmissing-noreturn
  1810. -Wmissing-selector-name
  1811. -Wmissing-sysroot
  1812. -Wmissing-variable-declarations
  1813. -Wmodule-conflict
  1814. -Wnested-anon-types
  1815. -Wnewline-eof
  1816. -Wnon-literal-null-conversion
  1817. -Wnon-pod-varargs
  1818. -Wnonportable-cfstrings
  1819. -Wnormalized=nfkc
  1820. -Wnull-arithmetic
  1821. -Wnull-character
  1822. -Wnull-conversion
  1823. -Wnull-dereference
  1824. -Wout-of-line-declaration
  1825. -Wover-aligned
  1826. -Woverlength-strings
  1827. -Woverride-init
  1828. -Woverriding-method-mismatch
  1829. -Wpointer-type-mismatch
  1830. -Wpredefined-identifier-outside-function
  1831. -Wprotocol-property-synthesis-ambiguity
  1832. -Wreadonly-iboutlet-property
  1833. -Wreadonly-setter-attrs
  1834. -Wreceiver-expr
  1835. -Wreceiver-forward-class
  1836. -Wreceiver-is-weak
  1837. -Wreinterpret-base-class
  1838. -Wrequires-super-attribute
  1839. -Wreserved-user-defined-literal
  1840. -Wreturn-stack-address
  1841. -Wsection
  1842. -Wselector-type-mismatch
  1843. -Wsentinel
  1844. -Wserialized-diagnostics
  1845. -Wshadow
  1846. -Wshift-count-negative
  1847. -Wshift-count-overflow
  1848. -Wshift-negative-value
  1849. -Wshift-overflow=2
  1850. -Wshift-sign-overflow
  1851. -Wshorten-64-to-32
  1852. -Wsizeof-array-argument
  1853. -Wsource-uses-openmp
  1854. -Wstatic-float-init
  1855. -Wstatic-in-inline
  1856. -Wstatic-local-in-inline
  1857. -Wstrict-overflow=1
  1858. -Wstring-compare
  1859. -Wstring-conversion
  1860. -Wstrlcpy-strlcat-size
  1861. -Wstrncat-size
  1862. -Wsuggest-attribute=format
  1863. -Wsuggest-attribute=noreturn
  1864. -Wsuper-class-method-mismatch
  1865. -Wswitch-bool
  1866. -Wsync-nand
  1867. -Wtautological-constant-out-of-range-compare
  1868. -Wtentative-definition-incomplete-type
  1869. -Wtrampolines
  1870. -Wtype-safety
  1871. -Wtypedef-redefinition
  1872. -Wtypename-missing
  1873. -Wundefined-inline
  1874. -Wundefined-internal
  1875. -Wundefined-reinterpret-cast
  1876. -Wunicode
  1877. -Wunicode-whitespace
  1878. -Wunknown-warning-option
  1879. -Wunnamed-type-template-args
  1880. -Wunneeded-member-function
  1881. -Wunsequenced
  1882. -Wunsupported-visibility
  1883. -Wunused-but-set-parameter
  1884. -Wunused-but-set-variable
  1885. -Wunused-command-line-argument
  1886. -Wunused-const-variable=2
  1887. -Wunused-exception-parameter
  1888. -Wunused-local-typedefs
  1889. -Wunused-member-function
  1890. -Wunused-sanitize-argument
  1891. -Wunused-volatile-lvalue
  1892. -Wuser-defined-literals
  1893. -Wvariadic-macros
  1894. -Wvector-conversion
  1895. -Wvector-conversions
  1896. -Wvexing-parse
  1897. -Wvisibility
  1898. -Wvla-extension
  1899. -Wzero-length-array
  1900. ], [ TOR_CHECK_CFLAGS([warning_flag]) ])
  1901. dnl We should re-enable this in some later version. Clang doesn't
  1902. dnl mind, but it causes trouble with GCC.
  1903. dnl -Wstrict-overflow=2
  1904. dnl These seem to require annotations that we don't currently use,
  1905. dnl and they give false positives in our pthreads wrappers. (Clang 4)
  1906. dnl -Wthread-safety
  1907. dnl -Wthread-safety-analysis
  1908. dnl -Wthread-safety-attributes
  1909. dnl -Wthread-safety-beta
  1910. dnl -Wthread-safety-precise
  1911. CFLAGS="$CFLAGS -W -Wfloat-equal -Wundef -Wpointer-arith"
  1912. CFLAGS="$CFLAGS -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings"
  1913. CFLAGS="$CFLAGS -Wredundant-decls -Wchar-subscripts -Wcomment -Wformat=2"
  1914. CFLAGS="$CFLAGS -Wwrite-strings"
  1915. CFLAGS="$CFLAGS -Wnested-externs -Wbad-function-cast -Wswitch-enum"
  1916. CFLAGS="$CFLAGS -Waggregate-return -Wpacked -Wunused"
  1917. CFLAGS="$CFLAGS -Wunused-parameter "
  1918. # These interfere with building main() { return 0; }, which autoconf
  1919. # likes to use as its default program.
  1920. CFLAGS="$CFLAGS -Wold-style-definition -Wmissing-declarations"
  1921. if test "$tor_cv_cflags__Wnull_dereference" = "yes"; then
  1922. AC_DEFINE([HAVE_CFLAG_WNULL_DEREFERENCE], 1, [True if we have -Wnull-dereference])
  1923. fi
  1924. if test "$tor_cv_cflags__Woverlength_strings" = "yes"; then
  1925. AC_DEFINE([HAVE_CFLAG_WOVERLENGTH_STRINGS], 1, [True if we have -Woverlength-strings])
  1926. fi
  1927. if test "x$enable_fatal_warnings" = "xyes"; then
  1928. # I'd like to use TOR_CHECK_CFLAGS here, but I can't, since the
  1929. # default autoconf programs are full of errors.
  1930. CFLAGS="$CFLAGS -Werror"
  1931. fi
  1932. fi
  1933. if test "$enable_coverage" = "yes" && test "$have_clang" = "no"; then
  1934. case "$host_os" in
  1935. darwin*)
  1936. AC_MSG_WARN([Tried to enable coverage on OSX without using the clang compiler. This might not work! If coverage fails, use CC=clang when configuring with --enable-coverage.])
  1937. esac
  1938. fi
  1939. CPPFLAGS="$CPPFLAGS $TOR_CPPFLAGS_libevent $TOR_CPPFLAGS_openssl $TOR_CPPFLAGS_zlib"
  1940. AC_CONFIG_FILES([
  1941. Doxyfile
  1942. Makefile
  1943. contrib/dist/suse/tor.sh
  1944. contrib/operator-tools/tor.logrotate
  1945. contrib/dist/tor.sh
  1946. contrib/dist/torctl
  1947. contrib/dist/tor.service
  1948. src/config/torrc.sample
  1949. src/config/torrc.minimal
  1950. src/rust/.cargo/config
  1951. scripts/maint/checkOptionDocs.pl
  1952. scripts/maint/updateVersions.pl
  1953. ])
  1954. if test "x$asciidoc" = "xtrue" && test "$ASCIIDOC" = "none"; then
  1955. regular_mans="doc/tor doc/tor-gencert doc/tor-resolve doc/torify"
  1956. for file in $regular_mans ; do
  1957. if ! [[ -f "$srcdir/$file.1.in" ]] || ! [[ -f "$srcdir/$file.html.in" ]] ; then
  1958. echo "==================================";
  1959. echo;
  1960. echo "Building Tor has failed since manpages cannot be built.";
  1961. echo;
  1962. echo "You need asciidoc installed to be able to build the manpages.";
  1963. echo "To build without manpages, use the --disable-asciidoc argument";
  1964. echo "when calling configure.";
  1965. echo;
  1966. echo "==================================";
  1967. exit 1;
  1968. fi
  1969. done
  1970. fi
  1971. if test "$fragile_hardening" = "yes"; then
  1972. AC_MSG_WARN([
  1973. ============
  1974. Warning! Building Tor with --enable-fragile-hardening (also known as
  1975. --enable-expensive-hardening) makes some kinds of attacks harder, but makes
  1976. other kinds of attacks easier. A Tor instance build with this option will be
  1977. somewhat less vulnerable to remote code execution, arithmetic overflow, or
  1978. out-of-bounds read/writes... but at the cost of becoming more vulnerable to
  1979. denial of service attacks. For more information, see
  1980. https://trac.torproject.org/projects/tor/wiki/doc/TorFragileHardening
  1981. ============
  1982. ])
  1983. fi
  1984. AC_OUTPUT