configure.in 15 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400401402403404405406407408409410411412413414415416417418419420421422423424425426427428429430431432433434435436437438439440441442443444445446447448449450451452453454455456
  1. dnl $Id$
  2. dnl Copyright 2001-2004 Roger Dingledine
  3. dnl Copyright 2004-2005 Roger Dingledine, Nick Mathewson
  4. dnl See LICENSE for licensing information
  5. AC_INIT
  6. AM_INIT_AUTOMAKE(tor, 0.1.0.6-rc-cvs)
  7. AM_CONFIG_HEADER(orconfig.h)
  8. AC_CANONICAL_HOST
  9. if test -f /etc/redhat-release; then
  10. CFLAGS="$CFLAGS -I/usr/kerberos/include"
  11. fi
  12. AC_ARG_ENABLE(debug,
  13. AC_HELP_STRING(--enable-debug, compile with debugging info),
  14. [if test x$enableval = xyes; then
  15. CFLAGS="$CFLAGS -g"
  16. fi])
  17. AC_ARG_ENABLE(threads,
  18. AC_HELP_STRING(--disable-threads, disable multi-threading support))
  19. if test x$enable_threads = x; then
  20. case $host in
  21. *-*-netbsd*)
  22. # Don't try multithreading on netbsd -- there is no threadsafe DNS
  23. # lookup function there.
  24. enable_threads="no";;
  25. *)
  26. enable_threads="yes";;
  27. esac
  28. fi
  29. if test $enable_threads = "yes"; then
  30. AC_DEFINE(ENABLE_THREADS, 1, [Defined if we will try to use multithreading])
  31. fi
  32. AC_PROG_CC
  33. AC_PROG_MAKE_SET
  34. AC_PROG_RANLIB
  35. # The big search for OpenSSL
  36. # copied from openssh's configure.ac
  37. AC_ARG_WITH(ssl-dir,
  38. [ --with-ssl-dir=PATH Specify path to OpenSSL installation ],
  39. [
  40. if test "x$withval" != "xno" ; then
  41. tryssldir=$withval
  42. fi
  43. ]
  44. )
  45. AC_SEARCH_LIBS(socket, [socket])
  46. AC_SEARCH_LIBS(gethostbyname, [nsl])
  47. AC_SEARCH_LIBS(pthread_create, [pthread])
  48. AC_SEARCH_LIBS(pthread_detach, [pthread])
  49. dnl ------------------------------------------------------
  50. dnl Where do you live, libevent?
  51. AC_SEARCH_LIBS(event_loop, [event], event_found=yes, event_found=no)
  52. if test "$event_found" = no; then
  53. saved_LIBS="$LIBS"
  54. saved_LDFLAGS="$LDFLAGS"
  55. AC_CACHE_CHECK([for libevent in /usr/local/lib], ac_cv_libevent_local, [
  56. LIBS="$LIBS -levent"
  57. LDFLAGS="$LDFLAGS -L/usr/local/lib"
  58. AC_TRY_LINK([], [ void *event_init(void); event_init(); ],
  59. [ libevent_is_in_local=yes ], [ libevent_is_in_local=no ])
  60. echo libevent_is_in_local is $libevent_is_in_local
  61. if test libevent_is_in_local = yes; then
  62. AC_TRY_RUN([
  63. void *event_init(void);
  64. int main(void)
  65. {
  66. if (!event_init())
  67. return -1;
  68. }], , [ ac_cv_libevent_local=unlinked ])
  69. else
  70. ac_cv_libevent_local=no
  71. fi
  72. if test "$GCC" = yes -a $ac_cv_libevent_local = unlinked ; then
  73. LDFLAGS="$LDFLAGS -Wl,-R/usr/local/lib"
  74. AC_TRY_RUN([
  75. void *event_init(void);
  76. int main(void)
  77. {
  78. if (!event_init())
  79. return -1;
  80. }], [ ac_cv_libevent_local=unlinked_gcc_elf ])
  81. fi
  82. LIBS="$saved_LIBS"
  83. CFLAGS="$saved_CFLAGS"
  84. LDFLAGS="$saved_LDFLAGS" ])
  85. if test $ac_cv_libevent_local != no; then
  86. LIBS="$LIBS -levent"
  87. LDFLAGS="$LDFLAGS -L/usr/local/lib"
  88. CPPFLAGS="$CPPFLAGS -I/usr/local/include"
  89. fi
  90. if test $ac_cv_libevent_local = unlinked_gcc_elf; then
  91. LDFLAGS="$LDFLAGS -Wl,-R/usr/local/lib"
  92. fi
  93. if test $ac_cv_libevent_local = unlinked ; then
  94. echo <<EOF
  95. =====================================================
  96. HEY!!!!
  97. Your libevent library is installed in /usr/local/lib,
  98. but your dynamic linker isn't configured to look for
  99. it there.
  100. EOF
  101. if test -f /etc/ld.so.conf; then
  102. echo <<EOF
  103. Maybe you need to add /usr/local/lib to /etc/ld.so.conf,
  104. and then run ldconfig -v ?
  105. EOF
  106. fi
  107. echo <<EOF
  108. =====================================================
  109. EOF
  110. fi
  111. if test $ac_cv_libevent_local = no ; then
  112. echo <<EOF
  113. Tor requires libevent to build. You can download the latest
  114. version of libevent from http://monkey.org/~provos/libevent/
  115. EOF
  116. fi
  117. fi
  118. dnl ------------------------------------------------------
  119. dnl Where do you live, OpenSSL?
  120. saved_LIBS="$LIBS"
  121. saved_LDFLAGS="$LDFLAGS"
  122. saved_CPPFLAGS="$CPPFLAGS"
  123. if test "x$prefix" != "xNONE" ; then
  124. tryssldir="$tryssldir $prefix"
  125. fi
  126. AC_CACHE_CHECK([for OpenSSL directory], ac_cv_openssldir, [
  127. for ssldir in $tryssldir "" /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/athena /usr/pkg /opt /opt/openssl ; do
  128. CPPFLAGS="$saved_CPPFLAGS"
  129. LDFLAGS="$saved_LDFLAGS"
  130. LIBS="$saved_LIBS -lssl -lcrypto"
  131. # Skip directories if they don't exist
  132. if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
  133. continue;
  134. fi
  135. if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
  136. # Try to use $ssldir/lib if it exists, otherwise
  137. # $ssldir
  138. if test -d "$ssldir/lib" ; then
  139. LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
  140. if test ! -z "$need_dash_r" ; then
  141. LDFLAGS="-R$ssldir/lib $LDFLAGS"
  142. fi
  143. else
  144. LDFLAGS="-L$ssldir $saved_LDFLAGS"
  145. if test ! -z "$need_dash_r" ; then
  146. LDFLAGS="-R$ssldir $LDFLAGS"
  147. fi
  148. fi
  149. # Try to use $ssldir/include if it exists, otherwise
  150. # $ssldir
  151. if test -d "$ssldir/include" ; then
  152. CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
  153. else
  154. CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
  155. fi
  156. fi
  157. # Basic test to check for compatible version and correct linking
  158. # *does not* test for RSA - that comes later.
  159. AC_TRY_RUN(
  160. [
  161. #include <string.h>
  162. #include <openssl/rand.h>
  163. int main(void)
  164. {
  165. char a[2048];
  166. memset(a, 0, sizeof(a));
  167. RAND_add(a, sizeof(a), sizeof(a));
  168. return(RAND_status() <= 0);
  169. }
  170. ],
  171. [
  172. found_crypto=1
  173. break;
  174. ], []
  175. )
  176. if test ! -z "$found_crypto" ; then
  177. break;
  178. fi
  179. done
  180. if test -z "$found_crypto" ; then
  181. AC_MSG_ERROR([Could not find working OpenSSL library, please install or check config.log])
  182. fi
  183. if test -z "$ssldir" ; then
  184. ssldir="(system)"
  185. fi
  186. ac_cv_openssldir=$ssldir
  187. ])
  188. if (test ! -z "$ac_cv_openssldir" && test "x$ac_cv_openssldir" != "x(system)") ;
  189. then
  190. dnl Need to recover ssldir - test above runs in subshell
  191. ssldir=$ac_cv_openssldir
  192. if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
  193. # Try to use $ssldir/lib if it exists, otherwise
  194. # $ssldir
  195. if test -d "$ssldir/lib" ; then
  196. LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
  197. if test ! -z "$need_dash_r" ; then
  198. LDFLAGS="-R$ssldir/lib $LDFLAGS"
  199. fi
  200. else
  201. LDFLAGS="-L$ssldir $saved_LDFLAGS"
  202. if test ! -z "$need_dash_r" ; then
  203. LDFLAGS="-R$ssldir $LDFLAGS"
  204. fi
  205. fi
  206. # Try to use $ssldir/include if it exists, otherwise
  207. # $ssldir
  208. if test -d "$ssldir/include" ; then
  209. CPPFLAGS="-I$ssldir/include $saved_CPPFLAGS"
  210. else
  211. CPPFLAGS="-I$ssldir $saved_CPPFLAGS"
  212. fi
  213. fi
  214. fi
  215. LIBS="$saved_LIBS"
  216. AC_SYS_LARGEFILE
  217. dnl The warning message here is no longer strictly accurate.
  218. AC_CHECK_HEADERS(unistd.h string.h signal.h netdb.h ctype.h sys/stat.h sys/types.h fcntl.h sys/fcntl.h sys/ioctl.h sys/socket.h sys/time.h netinet/in.h arpa/inet.h errno.h assert.h time.h pwd.h grp.h, , AC_MSG_WARN(some headers were not found, compilation may fail))
  219. AC_CHECK_HEADERS(event.h, , AC_MSG_ERROR(Libevent header (event.h) not found. Tor requires libevent to build.))
  220. AC_CHECK_HEADERS(zlib.h, , AC_MSG_ERROR(Zlib header (zlib.h) not found. Tor requires zlib to build. You may need to install a zlib development package.))
  221. dnl These headers are not essential
  222. AC_CHECK_HEADERS(stdint.h sys/types.h inttypes.h sys/param.h sys/wait.h sys/limits.h netinet/in.h arpa/inet.h machine/limits.h syslog.h sys/time.h sys/resource.h pthread.h stddef.h inttypes.h)
  223. AC_CHECK_FUNCS(gettimeofday ftime socketpair uname inet_aton strptime getrlimit setrlimit strlcat strlcpy strtoull getpwnam ftello pthread_create getaddrinfo localtime_r gmtime_r event_get_version event_get_method event_set_log_callback)
  224. AC_FUNC_FSEEKO
  225. AC_CHECK_MEMBERS([struct timeval.tv_sec])
  226. dnl In case we aren't given a working stdint.h, we'll need to grow our own.
  227. dnl Watch out.
  228. AC_CHECK_SIZEOF(int8_t)
  229. AC_CHECK_SIZEOF(int16_t)
  230. AC_CHECK_SIZEOF(int32_t)
  231. AC_CHECK_SIZEOF(int64_t)
  232. AC_CHECK_SIZEOF(uint8_t)
  233. AC_CHECK_SIZEOF(uint16_t)
  234. AC_CHECK_SIZEOF(uint32_t)
  235. AC_CHECK_SIZEOF(uint64_t)
  236. AC_CHECK_SIZEOF(intptr_t)
  237. AC_CHECK_SIZEOF(uintptr_t)
  238. dnl AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t, uint8_t, uint16_t, uint32_t, uint64_t, intptr_t, uintptr_t])
  239. AC_CHECK_SIZEOF(char)
  240. AC_CHECK_SIZEOF(short)
  241. AC_CHECK_SIZEOF(int)
  242. AC_CHECK_SIZEOF(long)
  243. AC_CHECK_SIZEOF(long long)
  244. AC_CHECK_SIZEOF(__int64)
  245. AC_CHECK_SIZEOF(void *)
  246. AC_CHECK_SIZEOF(time_t)
  247. AC_CHECK_SIZEOF(socklen_t, , [AC_INCLUDES_DEFAULT()
  248. #ifdef HAVE_SYS_SOCKET_H
  249. #include <sys/socket.h>
  250. #endif
  251. ])
  252. # We want to make sure that we _don't_ have a cell_t defined, like IRIX does.
  253. AC_CHECK_SIZEOF(cell_t)
  254. # Now, let's see about alignment requirements. On some platforms, we override
  255. # the default.
  256. case $host in
  257. ia64-*-* | arm-*-* )
  258. tor_cv_unaligned_ok=no
  259. ;;
  260. *)
  261. AC_CACHE_CHECK([whether unaligned int access is allowed], tor_cv_unaligned_ok,
  262. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  263. [[int main () { char s[] = "A\x00\x00\x00\x00\x00\x00\x00";
  264. return *(int*)(&s[1]); }]])],
  265. [tor_cv_unaligned_ok=yes],
  266. [tor_cv_unaligned_ok=no],
  267. [tor_cv_unaligned_ok=cross])])
  268. esac
  269. if test $tor_cv_unaligned_ok = yes; then
  270. AC_DEFINE([UNALIGNED_INT_ACCESS_OK], 1,
  271. [Define to 1 iff unaligned int access is allowed])
  272. fi
  273. # Now make sure that NULL can be represented as zero bytes.
  274. AC_CACHE_CHECK([whether memset(0) sets pointers to NULL], tor_cv_null_is_zero,
  275. [AC_RUN_IFELSE([AC_LANG_SOURCE(
  276. [[#include <stdlib.h>
  277. #include <string.h>
  278. #include <stdio.h>
  279. #ifdef HAVE_STDDEF_H
  280. #include <stddef.h>
  281. #endif
  282. int main () { char *p1,*p2; p1=NULL; memset(&p2,0,sizeof(p2));
  283. return memcmp(&p1,&p2,sizeof(char*))?1:0; }]])],
  284. [tor_cv_null_is_zero=yes],
  285. [tor_cv_null_is_zero=no],
  286. [tor_cv_null_is_zero=cross])])
  287. if test $tor_cv_null_is_zero = yes; then
  288. AC_DEFINE([NULL_REP_IS_ZERO_BYTES], 1,
  289. [Define to 1 iff memset(0) sets pointers to NULL])
  290. fi
  291. # Whether we should use the dmalloc memory allocation debugging library.
  292. AC_MSG_CHECKING(whether to use dmalloc (debug memory allocation library))
  293. AC_ARG_WITH(dmalloc,
  294. [ --with-dmalloc Use debug memory allocation library. ],
  295. [if [[ "$withval" = "yes" ]]; then
  296. dmalloc=1
  297. AC_MSG_RESULT(yes)
  298. else
  299. dmalloc=1
  300. AC_MSG_RESULT(no)
  301. fi], [ dmalloc=0; AC_MSG_RESULT(no) ]
  302. )
  303. if [[ $dmalloc -eq 1 ]]; then
  304. AC_CHECK_HEADERS(dmalloc.h, , AC_MSG_ERROR(dmalloc header file not found. Do you have the development files for dmalloc installed?))
  305. AC_SEARCH_LIBS(dmalloc_malloc, [dmalloc], , AC_MSG_ERROR(Libdmalloc library not found. If you enable it you better have it installed.))
  306. AC_DEFINE(USE_DMALLOC, 1, [Debug memory allocation library])
  307. AC_DEFINE(DMALLOC_FUNC_CHECK, 1, [Enable dmalloc's malloc function check])
  308. fi
  309. # Check for gethostbyname_r in all its glorious incompatible versions.
  310. # (This logic is based on that in Python's configure.in)
  311. AH_TEMPLATE(HAVE_GETHOSTBYNAME_R,
  312. [Define this if you have any gethostbyname_r()])
  313. AC_CHECK_FUNC(gethostbyname_r, [
  314. AC_MSG_CHECKING([how many arguments gethostbyname_r() wants])
  315. OLD_CFLAGS=$CFLAGS
  316. CFLAGS="$CFLAGS $MY_CPPFLAGS $MY_THREAD_CPPFLAGS $MY_CFLAGS"
  317. AC_TRY_COMPILE([
  318. #include <netdb.h>
  319. ], [
  320. char *cp1, *cp2;
  321. struct hostent *h1, *h2;
  322. int i1, i2;
  323. (void)gethostbyname_r(cp1,h1,cp2,i1,&h2,&i2);
  324. ], [
  325. AC_DEFINE(HAVE_GETHOSTBYNAME_R)
  326. AC_DEFINE(HAVE_GETHOSTBYNAME_R_6_ARG, 1,
  327. [Define this if gethostbyname_r takes 6 arguments])
  328. AC_MSG_RESULT(6)
  329. ], [
  330. AC_TRY_COMPILE([
  331. #include <netdb.h>
  332. ], [
  333. char *cp1, *cp2;
  334. struct hostent *h1;
  335. int i1, i2;
  336. (void)gethostbyname_r(cp1,h1,cp2,i1,&i2);
  337. ], [
  338. AC_DEFINE(HAVE_GETHOSTBYNAME_R)
  339. AC_DEFINE(HAVE_GETHOSTBYNAME_R_5_ARG, 1,
  340. [Define this if gethostbyname_r takes 5 arguments])
  341. AC_MSG_RESULT(5)
  342. ], [
  343. AC_TRY_COMPILE([
  344. #include <netdb.h>
  345. ], [
  346. char *cp1;
  347. struct hostent *h1;
  348. struct hostent_data hd;
  349. (void) gethostbyname_r(cp1,h1,&hd);
  350. ], [
  351. AC_DEFINE(HAVE_GETHOSTBYNAME_R)
  352. AC_DEFINE(HAVE_GETHOSTBYNAME_R_3_ARG, 1,
  353. [Define this if gethostbyname_r takes 3 arguments])
  354. AC_MSG_RESULT(3)
  355. ], [
  356. AC_MSG_RESULT(0)
  357. ])
  358. ])
  359. ])
  360. CFLAGS=$OLD_CFLAGS
  361. ])
  362. # $prefix stores the value of the --prefix command line option, or
  363. # NONE if the option wasn't set. In the case that it wasn't set, make
  364. # it be the default, so that we can use it to expand directories now.
  365. if test "x$prefix" = "xNONE"; then
  366. prefix=$ac_default_prefix
  367. fi
  368. # and similarly for $exec_prefix
  369. if test "x$exec_prefix" = "xNONE"; then
  370. exec_prefix=$prefix
  371. fi
  372. CONFDIR=`eval echo $sysconfdir/tor`
  373. AC_SUBST(CONFDIR)
  374. AC_DEFINE_UNQUOTED(CONFDIR,"$CONFDIR")
  375. AC_DEFINE([CONFDIR], [], [tor's configuration directory])
  376. BINDIR=`eval echo $bindir`
  377. AC_SUBST(BINDIR)
  378. LOCALSTATEDIR=`eval echo $localstatedir`
  379. AC_SUBST(LOCALSTATEDIR)
  380. AC_DEFINE_UNQUOTED(LOCALSTATEDIR,"$LOCALSTATEDIR")
  381. AC_DEFINE([LOCALSTATEDIR], [], [Default location to store state files.])
  382. # Set CFLAGS _after_ all the above checks, since our warnings are stricter
  383. # than autoconf's macros like.
  384. CFLAGS="$CFLAGS -Wall -g -O2"
  385. # Add some more warnings which we use in the cvs version but not in the
  386. # released versions. (Some relevant gcc versions can't handle these.)
  387. #CFLAGS="$CFLAGS -W -Wno-unused-parameter -Wfloat-equal -Wundef -Wpointer-arith -Wstrict-prototypes -Wmissing-prototypes -Wwrite-strings -Wredundant-decls"
  388. # Add these in when you feel like fun.
  389. #CFLAGS="$CFLAGS -Wbad-function-cast -Werror -Wdeclaration-after-statement"
  390. echo "confdir: $CONFDIR"
  391. AC_OUTPUT(Makefile tor.spec contrib/tor.sh contrib/torctl contrib/torify contrib/Makefile contrib/osx/Makefile contrib/osx/TorBundleDesc.plist contrib/osx/TorBundleInfo.plist contrib/osx/TorDesc.plist contrib/osx/TorInfo.plist src/config/torrc.sample doc/tor.1 src/Makefile doc/Makefile doc/design-paper/Makefile src/config/Makefile src/common/Makefile src/or/Makefile src/win32/Makefile src/tools/Makefile)
  392. if test -x /usr/bin/perl && test -x ./contrib/updateVersions.pl ; then
  393. ./contrib/updateVersions.pl
  394. fi